Praktické použití textových režimů nabízených čipem ANTIC
Co se dozvíte v článku
- Praktické použití textových režimů nabízených čipem ANTIC
- Struktura video RAM ve standardním textovém režimu
- Demonstrační příklad: tisk znaků ve standardním textovém režimu
- Volba znakové sady ve standardním textovém režimu
- Demonstrační příklad: volba mezinárodní znakové sady
- Demonstrační příklad: volba „náhodné“ stránky se znakovou sadou
- Struktura video RAM v textových režimech GR.1 a GR.2
- Demonstrační příklad: tisk 64 znaků ve čtyřech barvách
- Které 64 znaky se budou tisknout a jak se určuje jejich barva?
- Demonstrační příklad: výběr části ATASCII s malými znaky pro grafický režim GR.1
- Struktura video RAM v textových režimech GR.12 a GR.13
- Demonstrační příklad: tisk znaků v textovém režimu GR.12
- Způsob výběru barvy pixelů v textových režimech GR.12 a GR.13
- Definice vlastní znakové sady (naivní implementace)
- Demonstrační příklad: zobrazení vlastních znaků v textovém režimu GR.12
- Od textových režimů k režimům grafickým
- Nejjednodušší případ: dvoubarevný grafický režim s rozlišením 80×48 pixelů
- Příloha: Makefile pro překlad všech demonstračních příkladů
- Repositář s demonstračními příklady
- Odkazy na Internetu
Na úvodní článek s představením základních vlastností čipu ANTIC dnes navážeme. Popíšeme si základní vlastností textových režimů podporovaných osmibitovými počítači Atari. Připomeňme si, že se jedná o celkem šest režimů:
| ANTIC | BASIC | Znaků/řádek | Počet řádků | Počet barev | Spotřeba RAM |
|---|---|---|---|---|---|
| 2 | 0 | 40 | 24 | 2 | 960 |
| 3 | – | 40 | -- | 2 | -- |
| 4 | 12 | 40 | 24 | 4/5 | 960 |
| 5 | 13 | 40 | 12 | 4/5 | 480 |
| 6 | 1 | 20 | 24 | 5 | 480 |
| 7 | 2 | 20 | 12 | 5 | 240 |
Na základě společných vlastností je možné tyto režimy rozdělit do tří podskupin (vždy po dvojicích):
- V první podskupině je standardní textový režim GR.0 (ANTIC 2) a režim ANTIC 3. V těchto režimech se zobrazují monochromatické znaky o výše osmi resp. deseti obrazových řádků. Barva pozadí a popředí znaků má vždy stejný odstín, liší se jen intenzita. Režim GR.0 bude popsán ve druhé až šesté kapitole, protože se budeme zabývat i problematikou znakové sady.
- Ve druhé podskupině jsou režimy GR.1 a GR.2 (ANTIC 6 a 7). Horizontální počet znaků je snížen na polovinu (stejně jako rozlišení) a zobrazit je možné jen 64 znaků (nikoli 128). Nejvyšší dva bity znaků určují jejich barvu, pátá je barva pozadí (implicitně černá). Těmito režimy se budeme zabývat v kapitole sedmé až desáté.
- Režimy GR.12 a GR.13 (ANTIC 4 a 5) leží na pomezí mezi čistě textovými režimy a režimy grafickými. Znaky mají poloviční horizontální rozlišení a vždy dva bity v bitmapě znaku určují barvu pixelu. Tím lze rozlišit čtyři barvy; pátá barva je vybrána sedmým bitem kódu znaku. Výsledkem jsou „divné“ (špatně čitelné) znaky, ovšem modifikací znakové sady lze docílit mnoha zajímavých efektů. Režimy GR.12 a GR.13 se začneme zabývat v kapitole jedenácté.
Připomeňme si, že pro nastavení nějakého režimu musíme vytvořit takzvaný display list, který je interpretován čipem ANTIC. Display list umožňuje specifikovat pro každý logický řádek nějaký textový či grafický režim. Prozatím budeme pro celou obrazovku používat vždy ten samý režim.
Příkladem je nastavení display listu tak, aby se zobrazilo dvanáct řádků v textovém režimu GR.2:
.include "atari.inc"
.CODE
.proc main
lda #<dlist ; nižší byte adresy display listu
sta SDLSTL
lda #>dlist ; vyšší byte adresy display listu
sta SDLSTH
ldy #0 ; počitadlo zápisů
lda #0 ; kód vypisovaného znaku
clear:
sta screen, y ; tisk znaku na zvolené místo na obrazovce
clc
adc #1
iny ; zvětšit hodnotu počitadla a offsetu
cpy #20*12 ; test na koncovou hodnotu počitadla
bne clear ; skok, pokud Y>20x12
loop: jmp loop
.endproc
dlist:
.byte DL_BLK8, DL_BLK8, DL_BLK8 ; 3x8=24 prázdných obrazových řádků
.byte DL_LMS+DL_CHR20x16x2 ; určení počáteční adresy obrazové paměti + jeden řádek režimu 7
.byte <screen, >screen ; počáteční adresa obrazové paměti
.byte DL_CHR20x16x2 ; jeden řádek textového režimu 7 (GR.2)
.byte DL_CHR20x16x2 ; jeden řádek textového režimu 7 (GR.2)
.byte DL_CHR20x16x2 ; jeden řádek textového režimu 7 (GR.2)
.byte DL_CHR20x16x2 ; jeden řádek textového režimu 7 (GR.2)
.byte DL_CHR20x16x2 ; jeden řádek textového režimu 7 (GR.2)
.byte DL_CHR20x16x2 ; jeden řádek textového režimu 7 (GR.2)
.byte DL_CHR20x16x2 ; jeden řádek textového režimu 7 (GR.2)
.byte DL_CHR20x16x2 ; jeden řádek textového režimu 7 (GR.2)
.byte DL_CHR20x16x2 ; jeden řádek textového režimu 7 (GR.2)
.byte DL_CHR20x16x2 ; jeden řádek textového režimu 7 (GR.2)
.byte DL_CHR20x16x2 ; jeden řádek textového režimu 7 (GR.2)
.byte DL_JVB, <dlist, >dlist ; skok na začátek display listu
end:
.BSS
screen: .res 20*24
.segment "EXEHDR"
.word $ffff ; uvodni sekvence bajtu v souboru XEX
.word main ; zacatek kodoveho segmentu
.word end - 1 ; konec kodoveho segmentu
.segment "AUTOSTRT" ; segment s pocatecni adresou
.word RUNAD ; naplni se pouze adresy RUNAD a RUNAD+1
.word RUNAD+1
.word main ; adresa vstupniho bodu do programu
; finito
Výsledek:
Obrázek 1: V grafickém režimu GR.2 lze současně zobrazit jen 64 různých znaků, nikoli 128.
Struktura video RAM ve standardním textovém režimu
Popis textových režimů začneme režimem, do kterého se osmibitové počítače Atari typicky přepnou po zapnutí (pokud ovšem uživatel neovlivní inicializační fázi). Tento režim je použit jak Atari BASICem, tak i dalšími vývojovými nástroji, například Atari Macroassemblerem atd.:
Obrázek 2: Atari Assembler využívá standardní textový režim GR.0, pouze nastavuje odlišnou barvu popředí i pozadí (je to vždy stejná barva, jen s odlišnou intenzitou).
V tomto režimu se zobrazuje 40 znaků na řádku a počet textových řádků je standardně nastaven na 24. Celkem je tedy možné zobrazit 40×24=960 bajtů. Každý znak je uložen v jednom bajtu, takže velikost video RAM je taktéž 960 bajtů (a v BASICu bývá namapována na adresy 40000 až 40960, což se dobře pamatuje).
Znaková sada osmibitových Atari obsahuje 128 znaků. Pokud do video RAM zapíšeme znak s kódem vyšším než 128, je znak zobrazen inverzně, tj. nejvyšší bit znaku určuje způsob zobrazení a nikoli tvar znaku. Textový režim je monochromatický – pozadí i znaky mají stejný odstín barvy, ovšem odlišnou intenzitu. Ve výchozím nastavení se používá modrý odstín, ale může se jednat o libovolný jiný odstín z nabídky šestnácti barev. Barva se nastavuje registrem COLOR2, například:
.include "atari.inc"
.CODE
.proc main
lda #18 ; kod barvy
sta COLOR2 ; ulozit do registru COLOR2
loop: jmp loop
end:
.endproc
.segment "EXEHDR"
.word $ffff ; uvodni sekvence bajtu v souboru XEX
.word main ; zacatek kodoveho segmentu
.word main::end - 1 ; konec kodoveho segmentu
.segment "AUTOSTRT" ; segment s pocatecni adresou
.word RUNAD ; naplni se pouze adresy RUNAD a RUNAD+1
.word RUNAD+1
.word main ; adresa vstupniho bodu do programu
; finito
S výsledkem:
Obrázek 3: Nastavení odlišného barevného odstínu v režimu GR.0.
Popř. při nastavení černé barvy:
Obrázek 4: Nastavení odlišného barevného odstínu v režimu GR.0. Pozadí má nyní stejnou barvu jako okraj obrazovky.
Demonstrační příklad: tisk znaků ve standardním textovém režimu
V dnešním prvním demonstračním příkladu je explicitně nastaven display list tak, aby zobrazil standardní textový režim GR.0, ovšem pro zajímavost s menším počtem textových řádků. Display list tedy obsahuje všechny čtyři nezbytné části:
- Několik prázdných řádků na začátku obrazovky
- Nastavení počátku video RAM + nastavení prvního textového řádku
- Dále nastavíme dalších 11 řádků (ne 23) do textového režimu
- Skok na začátek display listu
Dále se do video RAM zapíšou hodnoty 0 až 255 odpovídající 128 dostupným znakům v neinvertujícím i invertujícím zobrazení:
Obrázek 5: Výpis 128 znaků v přímé podobě a dalších 128 znaků v podobě inverzní.
Následuje úplný zdrojový kód tohoto demonstračního příkladu:
.include "atari.inc"
.CODE
.proc main
lda #<dlist ; nižší byte adresy display listu
sta SDLSTL
lda #>dlist ; vyšší byte adresy display listu
sta SDLSTH
ldy #0 ; počitadlo zápisů
clear:
tya ; kód vypisovaného znaku
sta screen, y ; tisk znaku na zvolené místo na obrazovce
iny ; zvětšit hodnotu počitadla a offsetu
bne clear ; skok
loop: jmp loop
.endproc
dlist:
.byte DL_BLK8, DL_BLK8, DL_BLK8 ; 3x8=24 prázdných obrazových řádků
.byte DL_LMS+DL_CHR40x8x1 ; určení počáteční adresy obrazové paměti + jeden řádek režimu 2 (GR.0)
.byte <screen, >screen ; počáteční adresa obrazové paměti
.byte DL_CHR40x8x1 ; jeden řádek textového režimu 2 (GR.0)
.byte DL_CHR40x8x1 ; jeden řádek textového režimu 2 (GR.0)
.byte DL_CHR40x8x1 ; jeden řádek textového režimu 2 (GR.0)
.byte DL_CHR40x8x1 ; jeden řádek textového režimu 2 (GR.0)
.byte DL_CHR40x8x1 ; jeden řádek textového režimu 2 (GR.0)
.byte DL_CHR40x8x1 ; jeden řádek textového režimu 2 (GR.0)
.byte DL_CHR40x8x1 ; jeden řádek textového režimu 2 (GR.0)
.byte DL_CHR40x8x1 ; jeden řádek textového režimu 2 (GR.0)
.byte DL_CHR40x8x1 ; jeden řádek textového režimu 2 (GR.0)
.byte DL_CHR40x8x1 ; jeden řádek textového režimu 2 (GR.0)
.byte DL_CHR40x8x1 ; jeden řádek textového režimu 2 (GR.0)
.byte DL_JVB, <dlist, >dlist ; skok na začátek display listu
end:
.BSS
screen: .res 40*24
.segment "EXEHDR"
.word $ffff ; uvodni sekvence bajtu v souboru XEX
.word main ; zacatek kodoveho segmentu
.word end - 1 ; konec kodoveho segmentu
.segment "AUTOSTRT" ; segment s pocatecni adresou
.word RUNAD ; naplni se pouze adresy RUNAD a RUNAD+1
.word RUNAD+1
.word main ; adresa vstupniho bodu do programu
; finito
Volba znakové sady ve standardním textovém režimu
Jednou z důležitých vlastností čipu ANTIC je fakt, že (kromě patnácti řídicích registrů) načítá všechna ostatní data ze standardního adresního prostoru počítačů Atari, tedy buď z ROM nebo z RAM. Platí to i pro znakovou sadu. Připomeňme si, že znaková sada obsahuje bitmapy 128 znaků, přičemž každý znak je reprezentován maticí 8×8 pixelů. To tedy znamená, že celková velikost znakové sady je 128×8=1 kB. A umístění tohoto jednokilobajtového bloku je plně programovatelné. Konkrétně se číslo paměťové stránky, na které znaková sada začíná, zapisuje do řídicího registru CHBAS. Teoreticky by mělo být možné zvolit libovolnou stránku v rozsahu 0 až 255, ovšem existuje zde jedno omezení – stránka musí být sudá, tj. začátek znakové sady se musí nacházet na adrese dělitelné hodnotou 512. Umístění znakové sady lze snadno měnit, a to jak pro každý snímek, tak teoreticky pro každý textový řádek, což umožňuje realizaci různých triků.
Demonstrační příklad: volba mezinárodní znakové sady
V dalším demonstračním příkladu změníme adresu stránky uloženou v registru CHBAS. Nastavíme ji na hodnotu 204, protože na adrese 204×256=52224 je namapována ROM obsahující upravenou znakovou sadu, konkrétně takovou sadu, která namísto pseudografických znaků obsahuje znaky s nabodeníčky (přehlasování atd.). Ostatně nejlepší bude podívat se na výsledek – ten se odlišuje od předchozího screenshotu, ovšem pouze u některých znaků:
Obrázek 6: Mezinárodní znaková sada vypsaná v textovém režimu GR.0.
Zdrojový kód takto upraveného příkladu:
.include "atari.inc"
.CODE
.proc main
lda #204 ; adresa se stránkou znakové sady
sta CHBAS ; uložit do řídicího registru ANTICu
lda #<dlist ; nižší byte adresy display listu
sta SDLSTL
lda #>dlist ; vyšší byte adresy display listu
sta SDLSTH
ldy #0 ; počitadlo zápisů
clear:
tya ; kód vypisovaného znaku
sta screen, y ; tisk znaku na zvolené místo na obrazovce
iny ; zvětšit hodnotu počitadla a offsetu
bne clear ; skok
loop: jmp loop
.endproc
dlist:
.byte DL_BLK8, DL_BLK8, DL_BLK8 ; 3x8=24 prázdných obrazových řádků
.byte DL_LMS+DL_CHR40x8x1 ; určení počáteční adresy obrazové paměti + jeden řádek režimu 2 (GR.0)
.byte <screen, >screen ; počáteční adresa obrazové paměti
.byte DL_CHR40x8x1 ; jeden řádek textového režimu 2 (GR.0)
.byte DL_CHR40x8x1 ; jeden řádek textového režimu 2 (GR.0)
.byte DL_CHR40x8x1 ; jeden řádek textového režimu 2 (GR.0)
.byte DL_CHR40x8x1 ; jeden řádek textového režimu 2 (GR.0)
.byte DL_CHR40x8x1 ; jeden řádek textového režimu 2 (GR.0)
.byte DL_CHR40x8x1 ; jeden řádek textového režimu 2 (GR.0)
.byte DL_CHR40x8x1 ; jeden řádek textového režimu 2 (GR.0)
.byte DL_CHR40x8x1 ; jeden řádek textového režimu 2 (GR.0)
.byte DL_CHR40x8x1 ; jeden řádek textového režimu 2 (GR.0)
.byte DL_CHR40x8x1 ; jeden řádek textového režimu 2 (GR.0)
.byte DL_CHR40x8x1 ; jeden řádek textového režimu 2 (GR.0)
.byte DL_JVB, <dlist, >dlist ; skok na začátek display listu
end:
.BSS
screen: .res 40*24
.segment "EXEHDR"
.word $ffff ; uvodni sekvence bajtu v souboru XEX
.word main ; zacatek kodoveho segmentu
.word end - 1 ; konec kodoveho segmentu
.segment "AUTOSTRT" ; segment s pocatecni adresou
.word RUNAD ; naplni se pouze adresy RUNAD a RUNAD+1
.word RUNAD+1
.word main ; adresa vstupniho bodu do programu
; finito
Demonstrační příklad: volba „náhodné“ stránky se znakovou sadou
Nic nám ovšem nezabrání v tom nastavit stránku v registru CHBAS na libovolnou sudou hodnotu. Můžeme například chtít, aby se tvary znaků četly z ROM, z řídicích registrů dalších čipů atd. V dalším demonstračním příkladu je zvolena „náhodné“ stránka, která ovšem neobsahuje pouze nulové bajty:
Obrázek 7: Tvary znaků jsou nyní čteny z odlišné paměťové stránky.
Opět si pro úplnost uvedeme úplný zdrojový kód tohoto demonstračního příkladu:
.include "atari.inc"
.CODE
.proc main
lda #$d000/256 ; adresa se stránkou znakové sady
sta CHBAS ; uložit do řídicího registru ANTICu
lda #<dlist ; nižší byte adresy display listu
sta SDLSTL
lda #>dlist ; vyšší byte adresy display listu
sta SDLSTH
ldy #0 ; počitadlo zápisů
clear:
tya ; kód vypisovaného znaku
sta screen, y ; tisk znaku na zvolené místo na obrazovce
iny ; zvětšit hodnotu počitadla a offsetu
bne clear ; skok
loop: jmp loop
.endproc
dlist:
.byte DL_BLK8, DL_BLK8, DL_BLK8 ; 3x8=24 prázdných obrazových řádků
.byte DL_LMS+DL_CHR40x8x1 ; určení počáteční adresy obrazové paměti + jeden řádek režimu 2 (GR.0)
.byte <screen, >screen ; počáteční adresa obrazové paměti
.byte DL_CHR40x8x1 ; jeden řádek textového režimu 2 (GR.0)
.byte DL_CHR40x8x1 ; jeden řádek textového režimu 2 (GR.0)
.byte DL_CHR40x8x1 ; jeden řádek textového režimu 2 (GR.0)
.byte DL_CHR40x8x1 ; jeden řádek textového režimu 2 (GR.0)
.byte DL_CHR40x8x1 ; jeden řádek textového režimu 2 (GR.0)
.byte DL_CHR40x8x1 ; jeden řádek textového režimu 2 (GR.0)
.byte DL_CHR40x8x1 ; jeden řádek textového režimu 2 (GR.0)
.byte DL_CHR40x8x1 ; jeden řádek textového režimu 2 (GR.0)
.byte DL_CHR40x8x1 ; jeden řádek textového režimu 2 (GR.0)
.byte DL_CHR40x8x1 ; jeden řádek textového režimu 2 (GR.0)
.byte DL_CHR40x8x1 ; jeden řádek textového režimu 2 (GR.0)
.byte DL_JVB, <dlist, >dlist ; skok na začátek display listu
end:
.BSS
screen: .res 40*24
.segment "EXEHDR"
.word $ffff ; uvodni sekvence bajtu v souboru XEX
.word main ; zacatek kodoveho segmentu
.word end - 1 ; konec kodoveho segmentu
.segment "AUTOSTRT" ; segment s pocatecni adresou
.word RUNAD ; naplni se pouze adresy RUNAD a RUNAD+1
.word RUNAD+1
.word main ; adresa vstupniho bodu do programu
; finito
Struktura video RAM v textových režimech GR.1 a GR.2
Struktura video paměti se v textových režimech GR.1 a GR.2 odlišuje od textového režimu GR.0. Na řádcích se zobrazuje jen dvacet znaků (ne čtyřicet) a každý znak je stále uložen v jediném bajtu. To znamená, že i spotřeba RAM je nižší. Pro GR.1 je to 20×24=480 bajtů a pro GR.2 dokonce jen 20×12=240 bajtů (tedy necelá jedna paměťová stránka). Ovšem pro každý znak je možné si vybrat jeho barvu. Zatímco v režimu GR.0 se nejvyšším bitem kódu znaku určovalo, jestli bude znak zobrazen inverzně či nikoli, v GR.1 a GR.2 mají význam nejvyšší dva bity kódu znaku (což ovšem snižuje počet dostupných znaků ze 128 na 64):
| Bit 7 a 6 | Barva |
|---|---|
| 00 | 0 |
| 01 | 1 |
| 10 | 2 |
| 11 | 3 |
Barvy znaků se nastavují přes registry COLOR0, COLOR1, COLOR2 a COLOR3 (v tomto pořadí). Barva pozadí znaků se nastavuje v registru COLOR4 (to je opět novinka, která v GR.0 nebyla implementována z důvodů, ke kterým se ještě vrátíme).
Díky možnosti nastavování barev i tvarů znaků byly i tyto režimy použity u některých starších her:
Obrázek 8: Hra Up Up and Away využívá textový režim GR.1 a navíc i spritovou grafiku.
Demonstrační příklad: tisk 64 znaků ve čtyřech barvách
V dalším demonstračním příkladu provedeme nastavení display listu tak, aby se zobrazilo 14 řádků v textovém režimu GR.1 (ovšem počet řádků můžete rozšířit až na 24 nebo 25). Poté se do video RAM zapíšou hodnotu 0 až 255, tedy všechny možné kódy znaků. Výsledek by měl vypadat takto:
Obrázek 9: 256 znaků vypsaných v textovém režimu GR.1. Ve skutečnosti se vypíše 64 různých znaků, ovšem ve čtyřech barvách.
Úplný zdrojový kód tohoto demonstračního příkladu vypadá následovně:
.include "atari.inc"
.CODE
.proc main
lda #<dlist ; nižší byte adresy display listu
sta SDLSTL
lda #>dlist ; vyšší byte adresy display listu
sta SDLSTH
ldy #0 ; počitadlo zápisů
clear:
tya ; kód vypisovaného znaku
sta screen, y ; tisk znaku na zvolené místo na obrazovce
iny ; zvětšit hodnotu počitadla a offsetu
bne clear ; skok
loop: jmp loop
.endproc
dlist:
.byte DL_BLK8, DL_BLK8, DL_BLK8 ; 3x8=24 prázdných obrazových řádků
.byte DL_LMS+DL_CHR20x8x2 ; určení počáteční adresy obrazové paměti + jeden řádek režimu 2 (GR.0)
.byte <screen, >screen ; počáteční adresa obrazové paměti
.byte DL_CHR20x8x2 ; jeden řádek textového režimu 6 (GR.1)
.byte DL_CHR20x8x2 ; jeden řádek textového režimu 6 (GR.1)
.byte DL_CHR20x8x2 ; jeden řádek textového režimu 6 (GR.1)
.byte DL_CHR20x8x2 ; jeden řádek textového režimu 6 (GR.1)
.byte DL_CHR20x8x2 ; jeden řádek textového režimu 6 (GR.1)
.byte DL_CHR20x8x2 ; jeden řádek textového režimu 6 (GR.1)
.byte DL_CHR20x8x2 ; jeden řádek textového režimu 6 (GR.1)
.byte DL_CHR20x8x2 ; jeden řádek textového režimu 6 (GR.1)
.byte DL_CHR20x8x2 ; jeden řádek textového režimu 6 (GR.1)
.byte DL_CHR20x8x2 ; jeden řádek textového režimu 6 (GR.1)
.byte DL_CHR20x8x2 ; jeden řádek textového režimu 6 (GR.1)
.byte DL_CHR20x8x2 ; jeden řádek textového režimu 6 (GR.1)
.byte DL_CHR20x8x2 ; jeden řádek textového režimu 6 (GR.1)
.byte DL_JVB, <dlist, >dlist ; skok na začátek display listu
end:
.BSS
screen: .res 20*24
.segment "EXEHDR"
.word $ffff ; uvodni sekvence bajtu v souboru XEX
.word main ; zacatek kodoveho segmentu
.word end - 1 ; konec kodoveho segmentu
.segment "AUTOSTRT" ; segment s pocatecni adresou
.word RUNAD ; naplni se pouze adresy RUNAD a RUNAD+1
.word RUNAD+1
.word main ; adresa vstupniho bodu do programu
; finito
Které 64 znaky se budou tisknout a jak se určuje jejich barva?
Připomeňme si, že znaková sada osmibitových mikropočítačů Atari obsahuje definice 128 znaků, ovšem v režimech GR.1 a GR.2 je možné zobrazit pouze 64 znaků. Je tedy nutné nějakým způsobem určit, která polovina znakové sady se použije, zda prvních 64 znaků nebo naopak druhých 64 znaků. To se opět provádí přes řídicí registr CHBAS, do kterého se zapisuje první stránka znakové sady. Zápisem stránky 226 se vlastně posune ukazatel na definici prvního znaku a začnou se vypisovat odlišné znaky (původní hodnota je rovna 224, což odpovídá prvním 512 bajtům definic znaků; zápisem 226 jsme se přepnuli na definici druhé poloviny znakové sady):
Obrázek 10: Nyní se sice vypisují minusky, ovšem namísto mezery se vykresluje znak srdíčka.
Demonstrační příklad: výběr části ATASCII s malými znaky pro grafický režim GR.1
V dalším demonstračním příkladu se zápisem do registru CHBAS změní sada vykreslovaných znaků. Namísto verzálek (a dalších znaků) se nyní budou vykreslovat minusky. Ovšem do této druhé skupiny znaků již nespadá mezera. Namísto ní se vypisuje srdíčko (má kód roven nule):
.include "atari.inc"
.CODE
.proc main
lda #226 ; adresa se stránkou znakové sady
sta CHBAS ; uložit do řídicího registru ANTICu
lda #<dlist ; nižší byte adresy display listu
sta SDLSTL
lda #>dlist ; vyšší byte adresy display listu
sta SDLSTH
ldy #0 ; počitadlo zápisů
clear:
tya ; kód vypisovaného znaku
sta screen, y ; tisk znaku na zvolené místo na obrazovce
iny ; zvětšit hodnotu počitadla a offsetu
bne clear ; skok
loop: jmp loop
.endproc
dlist:
.byte DL_BLK8, DL_BLK8, DL_BLK8 ; 3x8=24 prázdných obrazových řádků
.byte DL_LMS+DL_CHR20x8x2 ; určení počáteční adresy obrazové paměti + jeden řádek režimu 2 (GR.0)
.byte <screen, >screen ; počáteční adresa obrazové paměti
.byte DL_CHR20x8x2 ; jeden řádek textového režimu 6 (GR.1)
.byte DL_CHR20x8x2 ; jeden řádek textového režimu 6 (GR.1)
.byte DL_CHR20x8x2 ; jeden řádek textového režimu 6 (GR.1)
.byte DL_CHR20x8x2 ; jeden řádek textového režimu 6 (GR.1)
.byte DL_CHR20x8x2 ; jeden řádek textového režimu 6 (GR.1)
.byte DL_CHR20x8x2 ; jeden řádek textového režimu 6 (GR.1)
.byte DL_CHR20x8x2 ; jeden řádek textového režimu 6 (GR.1)
.byte DL_CHR20x8x2 ; jeden řádek textového režimu 6 (GR.1)
.byte DL_CHR20x8x2 ; jeden řádek textového režimu 6 (GR.1)
.byte DL_CHR20x8x2 ; jeden řádek textového režimu 6 (GR.1)
.byte DL_CHR20x8x2 ; jeden řádek textového režimu 6 (GR.1)
.byte DL_CHR20x8x2 ; jeden řádek textového režimu 6 (GR.1)
.byte DL_CHR20x8x2 ; jeden řádek textového režimu 6 (GR.1)
.byte DL_JVB, <dlist, >dlist ; skok na začátek display listu
end:
.BSS
screen: .res 20*24
.segment "EXEHDR"
.word $ffff ; uvodni sekvence bajtu v souboru XEX
.word main ; zacatek kodoveho segmentu
.word end - 1 ; konec kodoveho segmentu
.segment "AUTOSTRT" ; segment s pocatecni adresou
.word RUNAD ; naplni se pouze adresy RUNAD a RUNAD+1
.word RUNAD+1
.word main ; adresa vstupniho bodu do programu
; finito
Struktura video RAM v textových režimech GR.12 a GR.13
Mezi nejužitečnější režimy nabízené osmibitovými počítači Atari patří režimy GR.12 a GR.13. Jedná se o textové režimy, ovšem tvary znaků jsou interpretovány takovým způsobem, že je možné zobrazit čtyřbarevné znaky a celkově je umožněno (bez dalších triků) zobrazit pět barev. Navíc je velikost video RAM velmi malá: 960 či dokonce jen 480 bajtů, takže překreslování herní scény je snadné, protože to mikroprocesor „ustíhá“ (na rozdíl od některých čistě rastrových grafických režimů).
Možnost zobrazení vícebarevných znaků zkombinovaná s definicí jejich tvaru, je ukázána v následujícím videu: https://youtu.be/h7N9EYSyCkw?t=220 (je to jen několik sekund záznamu s přepnutím mezi režimem GR.0 a režimem GR.12. Tyto vlastnosti byly využity doslova ve stovkách her pro osmibitová Atari:
Obrázek 11: Známá hra Rally Speedway plně využívá možností textového režimu GR.12 a GR.13.
Obrázek 12: 3D grafika? Ani ne, opět se využívá textový režim GR.12.
Nicméně se vraťme s organizaci video RAM u těchto režimů. Je to relativně snadné: vždy se zobrazí 40 znaků na řádku přičemž počet textových řádků je buď 24 (GR.12) nebo 12 (GR.13). Ve druhém případě jsou znaky zobrazeny s dvojnásobnou výškou. Zobrazit je možné všech 128 znaků, ovšem způsob zobrazení se v mnohém odlišuje od předchozích textových režimů. Nejdříve si ukážeme krátké demo s GR.12 a poté si způsob zobrazení znaků podrobněji vysvětlíme.
Demonstrační příklad: tisk znaků v textovém režimu GR.12
Organizace video RAM u režimů GR.0 a GR.12 je (až na odlišnou interpretaci tvarů znaků) naprosto stejná, takže v dalším demonstračním příkladu nejdříve nastavíme display list takovým způsobem, aby se zobrazovalo dvanáct textových řádků v režimu GR.12 (jejich počet si můžete zvýšit až na 24 či 25):
.byte DL_BLK8, DL_BLK8, DL_BLK8 ; 3x8=24 prázdných obrazových řádků .byte DL_LMS+DL_CHR40x8x4 ; určení počáteční adresy obrazové paměti + jeden řádek režimu 4 (GR.12) .byte <screen, >screen ; počáteční adresa obrazové paměti .byte DL_CHR40x8x4 ; jeden řádek textového režimu 4 (GR.12) .byte DL_CHR40x8x4 ; jeden řádek textového režimu 4 (GR.12) .byte DL_CHR40x8x4 ; jeden řádek textového režimu 4 (GR.12) .byte DL_CHR40x8x4 ; jeden řádek textového režimu 4 (GR.12) .byte DL_CHR40x8x4 ; jeden řádek textového režimu 4 (GR.12) .byte DL_CHR40x8x4 ; jeden řádek textového režimu 4 (GR.12) .byte DL_CHR40x8x4 ; jeden řádek textového režimu 4 (GR.12) .byte DL_CHR40x8x4 ; jeden řádek textového režimu 4 (GR.12) .byte DL_CHR40x8x4 ; jeden řádek textového režimu 4 (GR.12) .byte DL_CHR40x8x4 ; jeden řádek textového režimu 4 (GR.12) .byte DL_CHR40x8x4 ; jeden řádek textového režimu 4 (GR.12) .byte DL_JVB, <dlist, >dlist ; skok na začátek display listu
Dále vyplníme prvních 256 bajtů video RAM hodnotami 0 až 255:
ldy #0 ; počitadlo zápisů
clear:
tya ; kód vypisovaného znaku
sta screen, y ; tisk znaku na zvolené místo na obrazovce
iny ; zvětšit hodnotu počitadla a offsetu
bne clear ; skok
Výsledkem bude 256 zobrazených znaků (128 tvarů, další tvary se sice opakují, ale mají odlišné barvy). Jak je z obrázku patrné, nejsou znaky příliš čitelné, protože mají šířku jen 4 pixely a nikoli osm pixelů:
Obrázek 13: Výpis 256 znaků ukazuje, jak se interpretují masky znaků v textovém režimu GR.12.
Úplný zdrojový kód tohoto příkladu vypadá následovně:
.include "atari.inc"
.CODE
.proc main
lda #<dlist ; nižší byte adresy display listu
sta SDLSTL
lda #>dlist ; vyšší byte adresy display listu
sta SDLSTH
ldy #0 ; počitadlo zápisů
clear:
tya ; kód vypisovaného znaku
sta screen, y ; tisk znaku na zvolené místo na obrazovce
iny ; zvětšit hodnotu počitadla a offsetu
bne clear ; skok
loop: jmp loop
.endproc
dlist:
.byte DL_BLK8, DL_BLK8, DL_BLK8 ; 3x8=24 prázdných obrazových řádků
.byte DL_LMS+DL_CHR40x8x4 ; určení počáteční adresy obrazové paměti + jeden řádek režimu 4 (GR.12)
.byte <screen, >screen ; počáteční adresa obrazové paměti
.byte DL_CHR40x8x4 ; jeden řádek textového režimu 4 (GR.12)
.byte DL_CHR40x8x4 ; jeden řádek textového režimu 4 (GR.12)
.byte DL_CHR40x8x4 ; jeden řádek textového režimu 4 (GR.12)
.byte DL_CHR40x8x4 ; jeden řádek textového režimu 4 (GR.12)
.byte DL_CHR40x8x4 ; jeden řádek textového režimu 4 (GR.12)
.byte DL_CHR40x8x4 ; jeden řádek textového režimu 4 (GR.12)
.byte DL_CHR40x8x4 ; jeden řádek textového režimu 4 (GR.12)
.byte DL_CHR40x8x4 ; jeden řádek textového režimu 4 (GR.12)
.byte DL_CHR40x8x4 ; jeden řádek textového režimu 4 (GR.12)
.byte DL_CHR40x8x4 ; jeden řádek textového režimu 4 (GR.12)
.byte DL_CHR40x8x4 ; jeden řádek textového režimu 4 (GR.12)
.byte DL_JVB, <dlist, >dlist ; skok na začátek display listu
end:
.BSS
screen: .res 40*24
.segment "EXEHDR"
.word $ffff ; uvodni sekvence bajtu v souboru XEX
.word main ; zacatek kodoveho segmentu
.word end - 1 ; konec kodoveho segmentu
.segment "AUTOSTRT" ; segment s pocatecni adresou
.word RUNAD ; naplni se pouze adresy RUNAD a RUNAD+1
.word RUNAD+1
.word main ; adresa vstupniho bodu do programu
; finito
Způsob výběru barvy pixelů v textových režimech GR.12 a GR.13
Textové režimy GR.12 i GR.13 stále využívají znakovou sadu, ve které je definováno 128 znaků, přičemž pro každý znak je rezervováno osm bajtů (celkem má tedy znaková sada velikost 1024 bajtů, to se nemění). Znaky jsou vysoké osm obrazových řádků, přičemž v režimu GR.13 je výška řádku dvojnásobná oproti režimu GR.12 (celkem 96 obrazových řádků a nikoli 192 obrazových řádků). Až do této chvíle se tedy režim GR.12 podobá standardnímu textovému režimu GR.0. Ovšem je zde jeden podstatný rozdíl: barva pixelů je určena nikoli jediným bitem, ale hned dvěma bity definice znaku. A nejenom to – navíc (někdy!) záleží i na tom, zda je kód znaku menší než 128 nebo naopak větší než 127 (tedy jinými slovy: zda je nastaven jeho nejvyšší bit).
Celý způsob určení barvy pixelu je shrnut (doufám, že přehledně) do následující tabulky:
| Bitový pár v masce znaku | 7. bit znaku | Barva | Jméno registru s barvou | Adresa registru |
|---|---|---|---|---|
| 00 | ? | BAK | COLOR4 | 712 |
| 01 | ? | PF0 | COLOR0 | 708 |
| 10 | ? | PF1 | COLOR1 | 709 |
| 11 | 0 | PF2 | COLOR2 | 710 |
| 11 | 1 | PF3 | COLOR3 | 711 |
A jak to vypadá v praxi? Jako příklad si vezměme znak s kódem (řekněme) 100, jehož první bajt definice (masky) vypadá následovně:
00011011
Tyto bity jsou pro účely zobrazení pixelů na obrazovce rozděleny do dvojic:
00 01 10 11
Což při pohledu do tabulky znamená, že na obrazovce uvidíme čtyři pixely v barvách:
BAK PF0 PF1 PF2
Pokud bude mít znak kód 200 a stejnou bitovou masku, budou barvy čtyř pixelů nepatrně odlišné (zde se konkrétně bude lišit barva posledního pixelu):
BAK PF0 PF1 PF3
Grafické režimy GR.12 a GR.13 tedy skutečně dokážou zobrazit pět barev, ovšem s několika více či méně závažnými omezeními. Do jaké míry jsou tato omezení skutečně limitující, záleží na konkrétní hře nebo programu, který tyto režimy využívá.
Definice vlastní znakové sady (naivní implementace)
Režimy GR.12 a GR.13 jsou reálně využitelné jen tehdy, pokud vývojář navrhne vlastní znakovou sadu, která bude například obsahovat tvary objektů ve hře atd. K dispozici je 128 znaků, každý s reálným rozlišením 4×8 pixelů, přičemž pro každý pixel můžeme vybrat jednu ze čtyř barev (resp. pěti barev, v závislosti na kódu znaku). Pokusme se prozatím pro zajímavost nadefinovat pouze několik znaků. První znak bude celý zobrazen barvou pozadí (výchozí barva pozadí je černá):
font_source: .byte %00000000 .byte %00000000 .byte %00000000 .byte %00000000 .byte %00000000 .byte %00000000 .byte %00000000 .byte %00000000
Další tři znaky obsahují pouze jedinou svislou úsečku. V prvním případě bude mít tato úsečka barvu PF0 (červená), ve druhém případě PF1 (zelená) a v případě třetím buď PF2 (modrá) nebo PF3 (fialová):
.byte %01000000 .byte %01000000 .byte %01000000 .byte %01000000 .byte %01000000 .byte %01000000 .byte %01000000 .byte %01000000 .byte %10000000 .byte %10000000 .byte %10000000 .byte %10000000 .byte %10000000 .byte %10000000 .byte %10000000 .byte %10000000 .byte %11000000 .byte %11000000 .byte %11000000 .byte %11000000 .byte %11000000 .byte %11000000 .byte %11000000 .byte %11000000
A konečně další tři znaky budou zobrazeny jako jednobarevné bloky: první blok bude černý, druhý červený, třetí zelený a čtvrtý buď modrý nebo fialový (podle toho, jestli vypíšeme znak s původním kódem nebo kódem zvětšeným o 128):
.byte %00000000 .byte %00000000 .byte %00000000 .byte %00000000 .byte %00000000 .byte %00000000 .byte %00000000 .byte %00000000 .byte %01010101 .byte %01010101 .byte %01010101 .byte %01010101 .byte %01010101 .byte %01010101 .byte %01010101 .byte %01010101 .byte %10101010 .byte %10101010 .byte %10101010 .byte %10101010 .byte %10101010 .byte %10101010 .byte %10101010 .byte %10101010 .byte %11111111 .byte %11111111 .byte %11111111 .byte %11111111 .byte %11111111 .byte %11111111 .byte %11111111 .byte %11111111
Nastavení vlastní znakové sady je provedeno zápisem do paměťové stránky 152 (ta je volná):
font_page = 152 font_target = 152 * 256
Specifikace pro čip ANTIC, kde se znaková sada nachází:
lda #font_page ; vyšší bajt adresy fontu = číslo stránky
sta CHBAS
A konečně kopie tvarů prvních osmi znaků:
define_font:
ldx #8*8 ; počitadlo smyčky
next_line:
lda font_source, x ; načíst byte
sta font_target, x ; uložit byte
dex ; snížit offset + nastavit příznaky
bne next_line ; další byte spritu
Výsledek skutečně odpovídá našim znakům:
Obrázek 14: Osmice znaků. U prvních čtyř znaků je vyplněn jediný sloupec, u dalších čtyř znaků všechny čtyři sloupce. Další osmice znaků má nastaven sedmý bit na jedničku.
Demonstrační příklad: zobrazení vlastních znaků v textovém režimu GR.12
Výše uvedený postup je ukázán v dalším – dnes již předposledním – demonstračním příkladu, jehož úplný zdrojový kód vypadá následovně:
.include "atari.inc"
.CODE
font_page = 152
font_target = 152 * 256
.proc main
lda #font_page ; vyšší bajt adresy fontu = číslo stránky
sta CHBAS
lda #<dlist ; nižší byte adresy display listu
sta SDLSTL
lda #>dlist ; vyšší byte adresy display listu
sta SDLSTH
ldy #0 ; počitadlo zápisů
fill_screen:
tya ; kód vypisovaného znaku
sta screen, y ; tisk znaku na zvolené místo na obrazovce
iny ; zvětšit hodnotu počitadla a offsetu
bne fill_screen ; skok
define_font:
ldx #8*8 ; počitadlo smyčky
next_line:
lda font_source, x ; načíst byte
sta font_target, x ; uložit byte
dex ; snížit offset + nastavit příznaky
bne next_line ; další byte spritu
loop: jmp loop
.endproc
dlist:
.byte DL_BLK8, DL_BLK8, DL_BLK8 ; 3x8=24 prázdných obrazových řádků
.byte DL_LMS+DL_CHR40x8x4 ; určení počáteční adresy obrazové paměti + jeden řádek režimu 4 (GR.12)
.byte <screen, >screen ; počáteční adresa obrazové paměti
.byte DL_CHR40x8x4 ; jeden řádek textového režimu 4 (GR.12)
.byte DL_CHR40x8x4 ; jeden řádek textového režimu 4 (GR.12)
.byte DL_CHR40x8x4 ; jeden řádek textového režimu 4 (GR.12)
.byte DL_CHR40x8x4 ; jeden řádek textového režimu 4 (GR.12)
.byte DL_CHR40x8x4 ; jeden řádek textového režimu 4 (GR.12)
.byte DL_CHR40x8x4 ; jeden řádek textového režimu 4 (GR.12)
.byte DL_CHR40x8x4 ; jeden řádek textového režimu 4 (GR.12)
.byte DL_CHR40x8x4 ; jeden řádek textového režimu 4 (GR.12)
.byte DL_CHR40x8x4 ; jeden řádek textového režimu 4 (GR.12)
.byte DL_CHR40x8x4 ; jeden řádek textového režimu 4 (GR.12)
.byte DL_CHR40x8x4 ; jeden řádek textového režimu 4 (GR.12)
.byte DL_JVB, <dlist, >dlist ; skok na začátek display listu
font_source:
.byte %00000000
.byte %00000000
.byte %00000000
.byte %00000000
.byte %00000000
.byte %00000000
.byte %00000000
.byte %00000000
.byte %01000000
.byte %01000000
.byte %01000000
.byte %01000000
.byte %01000000
.byte %01000000
.byte %01000000
.byte %01000000
.byte %10000000
.byte %10000000
.byte %10000000
.byte %10000000
.byte %10000000
.byte %10000000
.byte %10000000
.byte %10000000
.byte %11000000
.byte %11000000
.byte %11000000
.byte %11000000
.byte %11000000
.byte %11000000
.byte %11000000
.byte %11000000
.byte %00000000
.byte %00000000
.byte %00000000
.byte %00000000
.byte %00000000
.byte %00000000
.byte %00000000
.byte %00000000
.byte %01010101
.byte %01010101
.byte %01010101
.byte %01010101
.byte %01010101
.byte %01010101
.byte %01010101
.byte %01010101
.byte %10101010
.byte %10101010
.byte %10101010
.byte %10101010
.byte %10101010
.byte %10101010
.byte %10101010
.byte %10101010
.byte %11111111
.byte %11111111
.byte %11111111
.byte %11111111
.byte %11111111
.byte %11111111
.byte %11111111
.byte %11111111
end:
.BSS
screen: .res 40*24
.segment "EXEHDR"
.word $ffff ; uvodni sekvence bajtu v souboru XEX
.word main ; zacatek kodoveho segmentu
.word end - 1 ; konec kodoveho segmentu
.segment "AUTOSTRT" ; segment s pocatecni adresou
.word RUNAD ; naplni se pouze adresy RUNAD a RUNAD+1
.word RUNAD+1
.word main ; adresa vstupniho bodu do programu
; finito
Od textových režimů k režimům grafickým
Všechny textové režimy, které jsme si popsali, se na osmibitových Atari velmi často používají, a to pro různé účely. Editory, databáze, tabulkové procesory atd. typicky využívaly standardní textový režim GR.0. Režimy GR.1 a GR.2 byly použity méně často, většinou jen na několika řádcích pro zobrazení skóre, nebo na úvodních obrazovkách. Mnohem častěji se bylo možné setkat s režimy GR.12 a někdy i GR.13, které kombinovaly relativně vysoké rozlišení, opět relativně vysoký počet barev a navíc i nízkou spotřebu paměti (a tím pádem i rychlost). Ovšem Atari dokáže využít i grafické (rastrové režimy). Jejich velkou výhodou je velmi jednoduchá struktura video paměti, čímž se Atari odlišuje jak od svých osmibitových konkurentů, tak i například od IBM PC s jeho plejádou navzájem zcela odlišných grafických režimů.
Grafickými režimy se budeme zabývat příště, ale již dnes si ukážeme ten nejjednodušší rastrový režim, který osmibitové Atari nabízí. Jedná se o režim s rozlišením 80×48 s pouhými dvěma barvami. Každý pixel je reprezentován jediným bitem a tedy spotřeba video RAM je: 80×48/8=480 bajtů. Barvy pixelů jsou uloženy přirozeně za sebou (po řádcích); Atari nepoužívá žádné prokládání ani blokovou strukturu.
Obrázek 15: Grafický režim s rozlišením 80×48 pixelů, navíc ještě ve dvoubarevném provedení. To samozřejmě není zdaleka vše, co Atari nabízí.
Nejjednodušší případ: dvoubarevný grafický režim s rozlišením 80×48 pixelů
V rastrovém grafickém režimu 80×48×2 barvy je nutné rezervovat 480 bajtů pro obrazovou paměť. Pixely s bitem nastaveným na jedničku budou mít takovou barvu, jaká bude zapsána do registru COLOR0. A pixely s nulovým bitem budou mít barvu získanou z registru COLOR4. Dnešní poslední demonstrační příklad do video RAM zapíše 256 hodnot, což odpovídá 256×8=2048 pixelům. Výsledek byl ukázán na patnáctém obrázku (z něhož je mj. patrné, že v osmici sousedních pixelů je bit s nejvyšším indexem vykreslen jako první):
.include "atari.inc"
.CODE
.proc main
lda #<dlist ; nižší byte adresy display listu
sta SDLSTL
lda #>dlist ; vyšší byte adresy display listu
sta SDLSTH
ldy #0 ; počitadlo zápisů
clear:
tya ; kód tištěných pixelů
sta screen, y ; tisk pixelu na zvolené místo na obrazovce
iny ; zvětšit hodnotu počitadla a offsetu
bne clear ; skok
loop: jmp loop
.endproc
dlist:
.byte DL_BLK8, DL_BLK8, DL_BLK8 ; 3x8=24 prázdných obrazových řádků
.byte DL_LMS+DL_MAP80x4x2 ; určení počáteční adresy obrazové paměti + jeden řádek režimu 9 (GR.4)
.byte <screen, >screen ; počáteční adresa obrazové paměti
.byte DL_MAP80x4x2 ; jeden řádek grafického režimu 9 (GR.4)
.byte DL_MAP80x4x2 ; jeden řádek grafického režimu 9 (GR.4)
.byte DL_MAP80x4x2 ; jeden řádek grafického režimu 9 (GR.4)
.byte DL_MAP80x4x2 ; jeden řádek grafického režimu 9 (GR.4)
.byte DL_MAP80x4x2 ; jeden řádek grafického režimu 9 (GR.4)
.byte DL_MAP80x4x2 ; jeden řádek grafického režimu 9 (GR.4)
.byte DL_MAP80x4x2 ; jeden řádek grafického režimu 9 (GR.4)
.byte DL_MAP80x4x2 ; jeden řádek grafického režimu 9 (GR.4)
.byte DL_MAP80x4x2 ; jeden řádek grafického režimu 9 (GR.4)
.byte DL_MAP80x4x2 ; jeden řádek grafického režimu 9 (GR.4)
.byte DL_MAP80x4x2 ; jeden řádek grafického režimu 9 (GR.4)
.byte DL_MAP80x4x2 ; jeden řádek grafického režimu 9 (GR.4)
.byte DL_MAP80x4x2 ; jeden řádek grafického režimu 9 (GR.4)
.byte DL_MAP80x4x2 ; jeden řádek grafického režimu 9 (GR.4)
.byte DL_MAP80x4x2 ; jeden řádek grafického režimu 9 (GR.4)
.byte DL_MAP80x4x2 ; jeden řádek grafického režimu 9 (GR.4)
.byte DL_MAP80x4x2 ; jeden řádek grafického režimu 9 (GR.4)
.byte DL_MAP80x4x2 ; jeden řádek grafického režimu 9 (GR.4)
.byte DL_MAP80x4x2 ; jeden řádek grafického režimu 9 (GR.4)
.byte DL_MAP80x4x2 ; jeden řádek grafického režimu 9 (GR.4)
.byte DL_MAP80x4x2 ; jeden řádek grafického režimu 9 (GR.4)
.byte DL_MAP80x4x2 ; jeden řádek grafického režimu 9 (GR.4)
.byte DL_MAP80x4x2 ; jeden řádek grafického režimu 9 (GR.4)
.byte DL_MAP80x4x2 ; jeden řádek grafického režimu 9 (GR.4)
.byte DL_JVB, <dlist, >dlist ; skok na začátek display listu
end:
.BSS
screen: .res 10*48
.segment "EXEHDR"
.word $ffff ; uvodni sekvence bajtu v souboru XEX
.word main ; zacatek kodoveho segmentu
.word end - 1 ; konec kodoveho segmentu
.segment "AUTOSTRT" ; segment s pocatecni adresou
.word RUNAD ; naplni se pouze adresy RUNAD a RUNAD+1
.word RUNAD+1
.word main ; adresa vstupniho bodu do programu
; finito
Příloha: Makefile pro překlad všech demonstračních příkladů
Všechny minule i dnes popsané demonstrační příklady, pro jejichž překlad je zapotřebí použít assembler ca65 a linker ld65, je možné přeložit s využitím souboru Makefile, jehož obsah je vypsán pod tímto odstavcem:
execs := dummy.xex print_a.xex \
background_color_1.xex background_color_2.xex \
color_computation_1.xex color_computation_2.xex \
subroutine_1.xex subroutine_2.xex \
hex_number_1.xex hex_number_2.xex \
hex_number_3.xex hex_number_4.xex \
hex_number_5.xex hex_number_6.xex \
hex_number_7.xex hex_number_8.xex \
hex_number_9.xex \
fill_block_1.xex fill_block_2.xex \
fill_block_3.xex fill_block_4.xex \
fill_block_5.xex \
pmg_01.xex pmg_02.xex \
pmg_03.xex pmg_04.xex \
pmg_05.xex pmg_06.xex \
pmg_07.xex pmg_08.xex \
pmg_09.xex pmg_10.xex \
pmg_11.xex pmg_12.xex \
pmg_13.xex pmg_14.xex \
pmg_15.xex pong.xex \
pmg_stick_1.xex pmg_stick_2.xex \
pmg_stick_3.xex pmg_stick_4.xex \
pmg_stick_5.xex pmg_stick_6.xex \
pmg_collisions_1.xex pmg_collisions_2.xex \
pmg_collisions_3.xex pmg_collisions_4.xex \
antic_1.xex antic_2.xex \
antic_3.xex antic_4.xex \
antic_5.xex antic_6.xex \
antic_7.xex antic_8.xex \
antic_9.xex antic_A.xex \
antic_B.xex
all: $(execs)
clean:
rm -f *.o
rm -f *.xex
.PHONY: all clean
%.o: %.asm
ca65 $< -t atari -o $@ -l $(basename $<)_list.asm --list-bytes 100
%.xex: %.o
ld65 -C linker.cfg $< -o $@ -m $(basename $<).map
Výsledkem překladu jsou soubory s koncovkou .xex, které je možné přímo spustit v emulátoru osmibitových počítačů Atari.
Repositář s demonstračními příklady
Všechny demonstrační příklady, s nimiž jsme se v předchozích článcích i v článku dnešním seznámili a které jsou určeny pro překlad s využitím assembleru ca65, jsou dostupné, jak je zvykem, na GitHubu. V tabulce níže jsou uvedeny odkazy na jednotlivé zdrojové kódy příkladů psané v assembleru i „listingy“ vygenerované samotným assemblerem, ze kterých je patrné, jakým způsobem se jednotlivé příklady přeložily do výsledného XEX souboru:
Odkazy na Internetu
- MOS 6502 instruction set
http://www.6502.org/users/obelisk/6502/instructions.html - EXE File Format Description
https://gury.atari8.info/refs/file_formats_exe.php - XEX Filter – A toolkit to analyze and manipulate Atari binary files
https://www.vitoco.cl/atari/xex-filter/index.html - chkxex.py
https://raw.githubusercontent.com/seban-slt/tcx_tools/refs/heads/master/chkxex.py - ca65 Users Guide
https://cc65.github.io/doc/ca65.html - cc65 Users Guide
https://cc65.github.io/doc/cc65.html - ld65 Users Guide
https://cc65.github.io/doc/ld65.html - da65 Users Guide
https://cc65.github.io/doc/da65.html - Překladače jazyka C pro historické osmibitové mikroprocesory
https://www.root.cz/clanky/prekladace-jazyka-c-pro-historicke-osmibitove-mikroprocesory/ - Překladače programovacího jazyka C pro historické osmibitové mikroprocesory (2)
https://www.root.cz/clanky/prekladace-programovaciho-jazyka-c-pro-historicke-osmibitove-mikroprocesory-2/ - Getting Started Programming in C: Coding a Retro Game with C Part 2
https://retrogamecoders.com/getting-started-with-c-cc65/ - NES game development in 6502 assembly – Part 1
https://kibrit.tech/en/blog/nes-game-development-part-1 - NES 6502 Programming Tutorial – Part 1: Getting Started
https://dev.xenforo.relay.cool/index.php?threads/nes-6502-programming-tutorial-part-1-getting-started.858389/ - Minimal NES example using ca65
https://github.com/bbbradsmith/NES-ca65-example - List of 6502-based Computers and Consoles
https://www.retrocompute.co.uk/list-of-6502-based-computers-and-consoles/ - 6502 – the first RISC µP
http://ericclever.com/6500/ - 3 Generations of Game Machine Architecture
http://www.atariarchives.org/dev/CGEXPO99.html - “Hello, world” from scratch on a 6502 — Part 1
https://www.youtube.com/watch?v=LnzuMJLZRdU - A Tour of 6502 Cross-Assemblers
https://bumbershootsoft.wordpress.com/2016/01/31/a-tour-of-6502-cross-assemblers/ - Adventures with ca65
https://atariage.com/forums/topic/312451-adventures-with-ca65/ - example ca65 startup code
https://atariage.com/forums/topic/209776-example-ca65-startup-code/ - 6502 PRIMER: Building your own 6502 computer
http://wilsonminesco.com/6502primer/ - 6502 Instruction Set
https://www.masswerk.at/6502/6502_instruction_set.html - Chip Hall of Fame: MOS Technology 6502 Microprocessor
https://spectrum.ieee.org/tech-history/silicon-revolution/chip-hall-of-fame-mos-technology-6502-microprocessor - Single-board computer
https://en.wikipedia.org/wiki/Single-board_computer - www.6502.org
http://www.6502.org/ - 6502 PRIMER: Building your own 6502 computer – clock generator
http://wilsonminesco.com/6502primer/ClkGen.html - Great Microprocessors of the Past and Present (V 13.4.0)
http://www.cpushack.com/CPU/cpu.html - Jak se zrodil procesor?
https://www.root.cz/clanky/jak-se-zrodil-procesor/ - Osmibitové mikroprocesory a mikrořadiče firmy Motorola (1)
https://www.root.cz/clanky/osmibitove-mikroprocesory-a-mikroradice-firmy-motorola-1/ - Mikrořadiče a jejich použití v jednoduchých mikropočítačích
https://www.root.cz/clanky/mikroradice-a-jejich-pouziti-v-jednoduchych-mikropocitacich/ - Mikrořadiče a jejich aplikace v jednoduchých mikropočítačích (2)
https://www.root.cz/clanky/mikroradice-a-jejich-aplikace-v-jednoduchych-mikropocitacich-2/ - 25 Microchips That Shook the World
https://spectrum.ieee.org/tech-history/silicon-revolution/25-microchips-that-shook-the-world - Comparison of instruction set architectures
https://en.wikipedia.org/wiki/Comparison_of_instruction_set_architectures - How To Start Learning Atari 8 Bit Assembly For Free
https://forums.atariage.com/topic/300732-how-to-start-learning-atari-8-bit-assembly-for-free/ - WUDSN (Demo Group)
https://www.wudsn.com/ - Machine Language For Beginners
https://www.atariarchives.org/mlb/ - Assembly language: all about I/O
https://www.atarimagazines.com/v3n8/AllAbout_IO.html - Sedmdesátiny assemblerů: lidsky čitelný strojový kód
https://www.root.cz/clanky/sedmdesatiny-assembleru-lidsky-citelny-strojovy-kod/ - Color names
https://atariwiki.org/wiki/Wiki.jsp?page=Color%20names - ATASCII
https://en.wikipedia.org/wiki/ATASCII - Put characters in display ram isn't ATASCII?
https://forums.atariage.com/topic/359973-put-characters-in-display-ram-isnt-atascii/ - ATASCII And Internal Character Code Values
https://www.atariarchives.org/mapping/appendix10.php - Reading ATASCII from the keyboard in assembly
https://forums.atariage.com/topic/361733-reading-atascii-from-the-keyboard-in-assembly/ - Why does the 6502 JSR instruction only increment the return address by 2 bytes?
https://retrocomputing.stackexchange.com/questions/19543/why-does-the-6502-jsr-instruction-only-increment-the-return-address-by-2-bytes - Pushing return address to stack off by 1 byte
https://forums.atariage.com/topic/378206-pushing-return-address-to-stack-off-by-1-byte/ - Intel x86 documentation has more pages than the 6502 has transistors
https://www.righto.com/2013/09/intel-x86-documentation-has-more-pages.html - Clearing a Section of Memory
http://www.6502.org/source/general/clearmem.htm - Practical Memory Move Routines by Bruce Clark
http://www.6502.org/source/general/memory_move.html - 6502 Assembly Programming Guide
https://neumont-gamedev.github.io/posts/retrogamedev-6502-guide/ - Off-by-one error
https://en.wikipedia.org/wiki/Off-by-one_error - 6502 cycle times
https://www.nesdev.org/wiki/6502_cycle_times - Atari TIA
http://www.atarihq.com/danb/tia.shtml - TIA Playfield
http://www.atarihq.com/danb/TIA/Playfield.shtml - Atari Inc.:
ANTIC C012296 (NTSC) Revision D
Atari Incorporated, Sunnyvale CA, 1982 - Atari Inc.:
GTIA C014805 (NTSC) Revision A
Atari Incorporated, Sunnyvale CA, 1982 - Atari 5200
http://www.atariage.com/software_search.html?SystemID=5200 - Atari 5200 Hardware and Accessories
http://www.atariage.com/5200/archives/hardware.html - Atari 5200 Screenshots
http://www.atariage.com/system_items.html?SystemID=5200&ItemTypeID=SCREENSHOT - History of video game consoles (second generation): Wikipedia
http://en.wikipedia.org/wiki/History_of_video_game_consoles_(second_generation) - Atari 5200: Wikipedia
http://en.wikipedia.org/wiki/Atari_5200 - Player-Missile Graphics
https://www.atariarchives.org/agagd/chapter5.php - Sprite (computer graphics)
https://en.wikipedia.org/wiki/Sprite_(computer_graphics) - Atari Graphics Demonstrations by Underground Software, 1985 | Atari 8 bit Demo
https://www.youtube.com/watch?v=h7N9EYSyCkw
ČLÁNKY DO MAILU