Textové režimy grafických karet SVGA na platformě IBM PC

Obsah

1. Textové režimy grafických karet SVGA na platformě IBM PC

2. Seznam textových režimů

3. Proč vznikly režimy se 132 znaky na řádku?

4. Zjištění, které rozšíření textové režimy jsou grafickou kartou podporovány

5. Test, zda je režim textový nebo grafický

6. První demonstrační příklad: výpis všech rozšířených textových režimů

7. Zjištění podrobnějších informací o vybraném textovém režimu

8. Druhý demonstrační příklad: podrobné informace o vybraném textovém režimu

9. Přepnutí do textového režimu karet SVGA

10. Třetí demonstrační příklad: přepnutí do vybraného textového režimu

11. Text a atributy – standard, který přežil až do dnešní doby

12. Vyplnění části obrazovky přepnuté do textového režimu

13. Čtvrtý demonstrační příklad: vyplnění části obrazové paměti znaky a jejich atributy

14. Pátý demonstrační příklad: tatáž operace, ovšem provedená v odlišném textovém režimu

15. Textový kurzor

16. Řídicí registry čipu MC6845

17. Změna tvaru textového kurzoru modifikací HW registrů

18. Šestý demonstrační příklad: změna tvaru textového kurzoru

19. Repositář s demonstračními příklady

20. Odkazy na Internetu

1. Textové režimy grafických karet SVGA na platformě IBM PC

Jak jsme si již naznačili v perexu dnešního článku, byla tvorba aplikací s grafickým výstupem na platformě IBM PC dosti složitá a v důsledku i neefektivní. V závislosti na době, ve které aplikace vznikala, i na požadavcích na zpětnou kompatibilitu, bylo nutné podporovat grafické karty se zcela různými způsoby organizace grafické (video) paměti. Například grafická karta CGA mapovala (v grafických režimech) video RAM do segmentu 0×B800 a celá její kapacita 16kB byla rozdělena do dvou banků o velikosti 8kB. V prvním banku byly uloženy liché řádky, ve druhém banku řádky sudé. A hodnoty pixelů (1 bit či 2 bity) byly ukládány do jediné bitové roviny.

Naproti tomu karta Hercules mapovala svoji video RAM do segmentu 0×B000 a paměť byla rozdělena nikoli do dvou, ale do čtyřech paměťových banků. Grafická karta EGA zavedla planární grafiku (až čtyři bitové roviny) a mapování video RAM do segmentu 0×A000. Karta VGA tuto techniku rozšířila o další grafické režimy a aby toho nebylo málo, byla zavedena zřetězená grafika používaná v grafickém režimu s rozlišením 320×200 pixelů (jediný příčetný grafický režim v historii IBM PC :-).

Situace se (oproti možná až příliš optimistickému očekávání) nezlepšila ani s příchodem grafických karet SVGA a později i standardu VESA (a rozšíření VBE). Standard VESA totiž konstruktérům grafických karet ponechával velkou volnost v tom, jakým způsobem vlastně budou ukládány hodnoty pixelů v grafických režimech s 15, 16, 24 či 32 bity na pixel. Navíc bylo nutné nějakým způsobem vyřešit mapování obrazové paměti (nyní již o velkých kapacitách 512kB, 1MB nebo dokonce 2MB) do jediného dostupného segmentu 0×A000. Opět bylo k dispozici několik možností, nikoli jeden uznávaný standardní způsob.

Ovšem jedna věc zůstávala po celou dobu existence IBM PC (a to se bavíme o několika desítkách let) prakticky nezměněná – textové režimy. Již grafické karty CGA a MDA podporovaly textový režim s 80 sloupci a 25 textovými řádky, přičemž každému znaku bylo možné přiřadit barvové aj. (blikání, podtržení) atributy. Na grafických kartách EGA a VGA bylo navíc možné zvýšit počet textových řádků na 30, 43 či 60 řádků (i více, ovšem to již bylo poněkud nestandardní). Organizace grafické (textové?) paměti zůstala po celou dobu existence platformy IBM PC stejná a vlastně ji můžeme využívat dodnes.

Další zvýšení počtu textových řádků a/nebo sloupců poskytly až grafické karty SVGA. A právě textovými režimy těchto karet se budeme zabývat v dnešním článku.

2. Seznam textových režimů

V následující tabulce jsou zobrazeny textové režimy dostupné na platformě IBM PC (samozřejmě v závislosti na použité grafické kartě). Obecně platí prakticky stoprocentní zpětná kompatibilita, takže i moderní karty by měly dokázat pracovat ve starodávném režimu 40×25 atd.:

3. Proč vznikly režimy se 132 znaky na řádku?

Při pohledu na tabulku uvedenou v předchozí kapitole vás možná napadne, proč se vlastně v nových textových režimech SVGA používá 132 znaků na řádku, když by hodnota 128 znaků byla „zaokrouhlenější“ a více by odpovídala rozlišením grafických režimů (1024 pixelů / 8 = 128). Tato hodnota má ve skutečnosti za sebou poměrně dlouhý vývoj, který ovšem souvisí s řádkovými tiskárnami vyráběnými společností IBM (od které tuto hodnotu okopírovali i další výrobci). A ještě před těmito tiskárnami (a vůbec před vznikem moderních počítačů) existovaly stroje nazývané tabulating machine, které dokázaly sečíst výsledky voleb, výsledky sčítání lidu atd. Některé z těchto strojů tiskly výsledky na papírový pás o šířce 14 palců a přitom bylo možné zobrazit 10 znaků na palec.

Tyto rozměry převzala společnost IBM a používala je u tiskáren systému IBM 1400 (začátek prodeje se datuje až do roku 1959). Šířka 14 palců a 10 znaků na palec znamená 140 znaků na řádku, ovšem osm znaků bylo rezervováno na perforované okraje (traktorový papír a traktorový podavač). Výsledkem je tedy 132 znaků na řádku.

Jen pro zajímavost se podívejme, jaké modely tiskáren pro systém IBM 1400 (počítač měl číslo 1401, tiskárny 1403) byly k dispozici:

4. Zjištění, které rozšíření textové režimy jsou grafickou kartou podporovány

Ve druhé kapitole jsme si (kromě dalších režimů) vypsali i de facto standardní textové režimy karet SVGA s vyšším počtem textových řádků a popř. s podporou 132 znaků na řádku. Některé grafické karty ovšem umožňovaly zobrazit i vyšší počty znaků – relativně typické byly režimy se 160 znaky na řádku atd. Jak je ovšem možné zjistit, které z těchto režimů jsou podporovány? Budeme postupovat následovně:

1. Zjistíme čísla všech dostupných režimů (ať již grafických či textových)
2. Pro každý z režimů si necháme zjistit jeho základní charakteristiky (typ atd.)
3. Pokud se jedná o textový režim, necháme si tento režim vypsat
4. Skok zpět na 2

Připomeňme si, že informace o grafické kartě vrácené přes VBE vypadají následovně:

vesa_block_info:
        Signature               resb 4
        Version                 resw 1
        OEMNamePtr              resd 1
        Capabilities            resd 1
 
        VideoModesOffset        resw 1
        VideoModesSegment       resw 1
 
        CountOf64KBlocks        resw 1
        OEMSoftwareRevision     resw 1
        OEMVendorNamePtr        resd 1
        OEMProductNamePtr       resd 1
        OEMProductRevisionPtr   resd 1
        Reserved                resb 222
        OEMData                 resb 256

Velmi důležitým údajem, který o sobě grafická karta přes VBE prozrazuje, je tabulka s čísly grafických ale i textových režimů (ovšem bez dalších podrobností). Adresa (ukazatel) na tuto tabulku je uložena ve dvojici VideoModesSegment a VideoModesOffset, přičemž každé číslo režimu je šestnáctibitové. Na konci tabulky je uložena šestnáctibitová hodnota –1 (tedy 0×ffff), kterou budeme hledat, aby bylo možné ukončit smyčku, která čísla všech grafických režimů vypíše:

        mov es, [VideoModesSegment] ; tabulka s cisly grafickych rezimu
        mov bx, [VideoModesOffset]
 
next_mode:
        xor eax, eax
        mov ax, es:[bx]            ; nacteni cisla rezimu
        cmp ax, -1                 ; jde o posledni zaznam?
        je  last_mode              ; ano -> koncime
        print_dec eax              ; tisk cisla rezimu
        inc bx                     ; offset pro dalsi rezim
        inc bx
        jmp next_mode              ; pokracujeme
last_mode:

5. Test, zda je režim textový nebo grafický

To, zda je nějaký režim textový nebo grafický, se pozná z pátého bitu (s indexem 4) v prvku ModeAttributes získaného ze struktury graphics_mode_block_info. Pokud se jedná o textový režim, bude jeho rozlišení specifikováno ve znacích (nikoli v pixelech) a současně prvky XCharSize a YCharSize budou obsahovat velikost masky znaků (tentokrát pochopitelně v pixelech). Typické hodnoty jsou 8×8 a 8×16 (zmizel tedy devátý sloupec). Test na textový režim a výpis jeho základních informací lze realizovat relativně snadno (kód není optimalizován):

print_mode_info:
        pushad                     ; uschovat pracovni registry
        push es                    ; pro pozdejsi obnovu na konci subrutiny
        push ds
        pop  es                    ; nastaveni CS=DS=ES
        mov  dx, ax
 
        clc                        ; ziskani zakladnich informaci o grafickem rezimu
        mov  di, graphics_mode_block_info
        mov  cx, ax                ; cislo rezimu
        mov  ax, 0x4f01
        int      0x10
 
        cmp ax, 0x004f             ; test, zda bylo volani funkce BIOSu uspesne
        jne     not_text_mode
 
        mov ax, [ModeAttributes]   ; bit cislo 4 je u textovych rezimu nastaven na hodnotu 0
        and ax, 16                 ; test bitu cislo 4
        jnz  not_text_mode
 
        ; je to textovy rezim!
        mov ax, dx                 ; tisk cisla rezimu
        print_dec_16
 
        mov ax, [XResolution]      ; horizontalni rozliseni ve znacich
        print_dec_16
 
        mov ax, [YResolution]      ; vertikalni rozliseni ve znacich
        print_dec_16
 
        mov ax, [XCharSize]        ; sirka znaku v pixelech
        print_dec_8
 
        mov ax, [YCharSize]        ; vyska znaku v pixelech
        print_dec_8
 
        print_string eoln          ; na konci odradkovat
 
not_text_mode:
        pop es                     ; obnoveni vsech relevantnich registru
        popad
        ret                        ; a navrat ze subrutiny

6. První demonstrační příklad: výpis všech rozšířených textových režimů

V dnešním prvním demonstračním příkladu si necháme vypsat všechny textové režimy podporované SVGA kartou. U každého režimu se vypíše jeho rozlišení (ve znacích) i velikost masek znaků (typicky 8×8 nebo 8×16 pixelů):

;-----------------------------------------------------------------------------
org  0x100        ; zacatek kodu pro programy typu COM (vzdy se zacina na 256)
 
start:
        jmp main                   ; skok na zacatek kodu
 
%include "io.asm"                  ; nacist symboly, makra a podprogramy
%include "print.asm"               ; nacist symboly, makra a podprogramy
 
main:
        mov  byte [dec_message+10], ' '  ; trik -> nechceme odradkovat po tisku hodnoty
        mov  byte [dec_message+11], ' '
 
        push ds
        pop  es                    ; nastaveni CS=DS=ES
 
        clc                        ; ziskani zakladnich informaci o VESA rezimech
        mov  di, vesa_block_info
        mov ax, 0x4f00
        int     0x10
 
        cmp ax, 0x004f             ; test, zda bylo volani funkce BIOSu uspesne
        jne     failed
 
        mov es, [VideoModesSegment] ; tabulka s cisly grafickych rezimu
        mov bx, [VideoModesOffset]
 
next_mode:
        xor eax, eax
        mov ax, es:[bx]            ; nacteni cisla rezimu
        cmp ax, -1                 ; jde o posledni zaznam?
        je  last_mode              ; ano -> koncime
        inc bx                     ; offset pro dalsi rezim
        inc bx
 
        mov ax, es:[bx]            ; znovu nacist cislo rezimu
        call print_mode_info       ; a vypsat podrobejsi informace o nem
 
        jmp next_mode              ; pokracujeme
last_mode:
        jmp     finish
 
failed:
        print_string failed_msg
 
finish:
        wait_key                   ; cekani na klavesu
        exit                       ; navrat do DOSu
 
 
print_mode_info:
        pushad                     ; uschovat pracovni registry
        push es                    ; pro pozdejsi obnovu na konci subrutiny
        push ds
        pop  es                    ; nastaveni CS=DS=ES
        mov  dx, ax
 
        clc                        ; ziskani zakladnich informaci o grafickem rezimu
        mov  di, graphics_mode_block_info
        mov  cx, ax                ; cislo rezimu
        mov  ax, 0x4f01
        int      0x10
 
        cmp ax, 0x004f             ; test, zda bylo volani funkce BIOSu uspesne
        jne     not_text_mode
 
        mov ax, [ModeAttributes]   ; bit cislo 4 je u textovych rezimu nastaven na hodnotu 0
        and ax, 16                 ; test bitu cislo 4
        jnz  not_text_mode
 
        ; je to textovy rezim!
        mov ax, dx                 ; tisk cisla rezimu
        print_dec_16
 
        mov ax, [XResolution]      ; horizontalni rozliseni ve znacich
        print_dec_16
 
        mov ax, [YResolution]      ; vertikalni rozliseni ve znacich
        print_dec_16
 
        mov ax, [XCharSize]        ; sirka znaku v pixelech
        print_dec_8
 
        mov ax, [YCharSize]        ; vyska znaku v pixelech
        print_dec_8
 
        print_string eoln          ; na konci odradkovat
 
not_text_mode:
        pop es                     ; obnoveni vsech relevantnich registru
        popad
        ret                        ; a navrat ze subrutiny
 
 
 
; datova cast
section .data
 
success_msg:     db "Success", 0x0a, 0x0d, "$"
failed_msg:      db "Failed", 0x0a, 0x0d, "$"
eoln:            db 0x0a, 0x0d, "$"
 
section .bss
vesa_block_info:
        Signature               resb 4
        Version                 resw 1
        OEMNamePtr              resd 1
        Capabilities            resd 1
 
        VideoModesOffset        resw 1
        VideoModesSegment       resw 1
 
        CountOf64KBlocks        resw 1
        OEMSoftwareRevision     resw 1
        OEMVendorNamePtr        resd 1
        OEMProductNamePtr       resd 1
        OEMProductRevisionPtr   resd 1
        Reserved                resb 222
        OEMData                 resb 256
 
graphics_mode_block_info:
        ModeAttributes      resw 1 ; mode attributes
        WinAAttributes      resb 1 ; window A attributes
        WinBAttributes      resb 1 ; window B attributes
        WinGranularity      resw 1 ; window granularity
        WinSize             resw 1 ; window size
        WinASegment         resw 1 ; window A start segment
        WinBSegment         resw 1 ; window B start segment
        WinFuncPtr          resd 1 ; pointer to windor function
        BytesPerScanLine    resw 1 ; bytes per scan line
 
        XResolution         resw 1 ; horizontal resolution
        YResolution         resw 1 ; vertical resolution
        XCharSize           resb 1 ; character cell width
        YCharSize           resb 1 ; character cell height
        NumberOfPlanes      resb 1 ; number of memory planes
        BitsPerPixel        resb 1 ; bits per pixel
        NumberOfBanks       resb 1 ; number of banks
        MemoryModel         resb 1 ; memory model type
        BankSize            resb 1 ; bank size in kb
        NumberOfImagePages  resb 1 ; number of images
        Reserved1           resb 1 ; reserved for page function
 
        RedMaskSize         resb 1 ; size of direct color red mask in bits
        RedFieldPosition    resb 1 ; bit position of LSB of red mask
        GreenMaskSize       resb 1 ; size of direct color green mask in bits
        GreenFieldPosition  resb 1 ; bit position of LSB of green mask
        BlueMaskSize        resb 1 ; size of direct color blue mask in bits
        BlueFieldPosition   resb 1 ; bit position of LSB of blue mask
        RsvdMaskSize        resb 1 ; size of direct color reserved mask in bits
        DirectColorModeInfo resb 1 ; Direct Color mode attributes
        Reserved2           resb 216 ; remainder of ModeInfoBlock

Výsledky by mohly vypadat následovně:

0000000264  0000000080  0000000060  0000000008  0000000008
0000000265  0000000132  0000000025  0000000008  0000000016
0000000266  0000000132  0000000043  0000000008  0000000008
0000000267  0000000132  0000000050  0000000008  0000000008
0000000268  0000000132  0000000060  0000000008  0000000008

Což snadno převedeme do čitelné tabulky:

Režim Znaků Řádků Šířka Výška (pixely)
======================================
264     80    60     8    8
265    132    25     8   16
266    132    43     8    8
267    132    50     8    8
268    132    60     8    8

7. Zjištění podrobnějších informací o vybraném textovém režimu

Z předchozích částí tohoto seriálu již víme, že podrobné informace o jednom vybraném textovém nebo grafickém režimu musíme zjistit službou číslo 0×4F a podslužbou 1. Do registru CX je nutné zadat číslo režimu, který potřebujeme prozkoumat a v registrovém páru ES:DI musí být předán ukazatel na buffer o délce 256 bajtů, do kterého se uloží podrobné informace o zvoleném režimu:

Vstup:  AH = 4Fh        Služby SVGA
        AL = 01h        Získání informací o zvoleném grafickém režimu
        CX = číslo režimu
        ES:DI = ukazatel na buffer (256 bajtů)
 
Výstup: AL = 4Fh pokud je služba podporována, jinak odlišná hodnota
        AH = 00h pokud je volání úspěšné, jinak hodnota 01h

Blok o délce 256 bajtů, který je vyplněn, má tuto strukturu:

graphics_mode_block_info:
        ModeAttributes      resw 1 ; mode attributes
        WinAAttributes      resb 1 ; window A attributes
        WinBAttributes      resb 1 ; window B attributes
        WinGranularity      resw 1 ; window granularity
        WinSize             resw 1 ; window size
        WinASegment         resw 1 ; window A start segment
        WinBSegment         resw 1 ; window B start segment
        WinFuncPtr          resd 1 ; pointer to windor function
        BytesPerScanLine    resw 1 ; bytes per scan line
 
        XResolution         resw 1 ; horizontal resolution
        YResolution         resw 1 ; vertical resolution
        XCharSize           resb 1 ; character cell width
        YCharSize           resb 1 ; character cell height
        NumberOfPlanes      resb 1 ; number of memory planes
        BitsPerPixel        resb 1 ; bits per pixel
        NumberOfBanks       resb 1 ; number of banks
        MemoryModel         resb 1 ; memory model type
        BankSize            resb 1 ; bank size in kb
        NumberOfImagePages  resb 1 ; number of images
        Reserved1           resb 1 ; reserved for page function
 
        RedMaskSize         resb 1 ; size of direct color red mask in bits
        RedFieldPosition    resb 1 ; bit position of LSB of red mask
        GreenMaskSize       resb 1 ; size of direct color green mask in bits
        GreenFieldPosition  resb 1 ; bit position of LSB of green mask
        BlueMaskSize        resb 1 ; size of direct color blue mask in bits
        BlueFieldPosition   resb 1 ; bit position of LSB of blue mask
        RsvdMaskSize        resb 1 ; size of direct color reserved mask in bits
        DirectColorModeInfo resb 1 ; Direct Color mode attributes
        Reserved2           resb 216 ; remainder of ModeInfoBlock

Mnohé atributy postrádají v případě textových režimů význam (například bitové masky a velikosti), ovšem minimálně tyto atributy jsou velmi důležité:

        ModeAttributes      resw 1 ; atributy režimu, včetně rozlišení text/grafika
        WinAAttributes      resb 1 ; zajímá nás jen, jestli okno existuje
        WinASegment         resw 1 ; segment pro okno A (měl by být 0xB800)
        BytesPerScanLine    resw 1 ; počet bajtů, tentokrát na textový řádek (počet znaků*2)
 
        XResolution         resw 1 ; počet znaků na textovém řádku
        YResolution         resw 1 ; počet textových řádků
        XCharSize           resb 1 ; šířka znaku v pixelech
        YCharSize           resb 1 ; výška znaku v pixelech

8. Druhý demonstrační příklad: podrobné informace o vybraném textovém režimu

V dnešním druhém demonstračním příkladu si ukážeme, jakým způsobem lze získat a zobrazit podrobnější informace o vybraném textovém režimu. Konkrétně budeme zjišťovat informace o režimu s číslem 0×108. Tyto informace se přečtou a následně zobrazí na terminálu:

;-----------------------------------------------------------------------------
org  0x100        ; zacatek kodu pro programy typu COM (vzdy se zacina na 256)
 
start:
        jmp main                   ; skok na zacatek kodu
 
%include "io.asm"                  ; nacist symboly, makra a podprogramy
%include "print.asm"               ; nacist symboly, makra a podprogramy
 
main:
        push ds
        pop  es                    ; nastaveni CS=DS=ES
 
        clc                        ; ziskani zakladnich informaci o grafickem rezimu
        mov  di, graphics_mode_block_info
        mov  cx, 0x108             ; cislo rezimu
        mov  ax, 0x4f01
        int      0x10
 
        cmp ax, 0x004f             ; test, zda bylo volani funkce BIOSu uspesne
        jne     failed
 
success:
        print_string success_msg
 
        mov ax, [XResolution]
        print_dec_16
 
        mov ax, [YResolution]
        print_dec_16
 
        mov ax, [BytesPerScanLine]
        print_dec_16
 
        mov al, [BitsPerPixel]
        print_dec_8
 
        mov al, [NumberOfPlanes]
        print_dec_8
 
        mov ax, [XCharSize]
        print_dec_8
 
        mov ax, [YCharSize]
        print_dec_8
 
        xor eax, eax
        mov al, [WinAAttributes]
        print_hex eax
 
        xor eax, eax
        mov al, [WinBAttributes]
        print_hex eax
 
        xor eax, eax
        mov ax, [WinGranularity]
        print_dec_16
 
        xor eax, eax
        mov ax, [WinSize]
        print_dec_16
 
        xor eax, eax
        mov ax, [WinASegment]
        print_hex eax
 
        xor eax, eax
        mov ax, [WinBSegment]
        print_hex eax
 
        jmp     finish
 
failed:
        print_string failed_msg
 
finish:
        wait_key            ; cekani na klavesu
        exit                ; navrat do DOSu
 
 
; datova cast
section .data
 
success_msg:     db "Success", 0x0a, 0x0d, "$"
failed_msg:      db "Failed", 0x0a, 0x0d, "$"
 
section .bss
graphics_mode_block_info:
        ModeAttributes      resw 1 ; mode attributes
        WinAAttributes      resb 1 ; window A attributes
        WinBAttributes      resb 1 ; window B attributes
        WinGranularity      resw 1 ; window granularity
        WinSize             resw 1 ; window size
        WinASegment         resw 1 ; window A start segment
        WinBSegment         resw 1 ; window B start segment
        WinFuncPtr          resd 1 ; pointer to windor function
        BytesPerScanLine    resw 1 ; bytes per scan line
 
        XResolution         resw 1 ; horizontal resolution
        YResolution         resw 1 ; vertical resolution
        XCharSize           resb 1 ; character cell width
        YCharSize           resb 1 ; character cell height
        NumberOfPlanes      resb 1 ; number of memory planes
        BitsPerPixel        resb 1 ; bits per pixel
        NumberOfBanks       resb 1 ; number of banks
        MemoryModel         resb 1 ; memory model type
        BankSize            resb 1 ; bank size in kb
        NumberOfImagePages  resb 1 ; number of images
        Reserved1           resb 1 ; reserved for page function
 
        RedMaskSize         resb 1 ; size of direct color red mask in bits
        RedFieldPosition    resb 1 ; bit position of LSB of red mask
        GreenMaskSize       resb 1 ; size of direct color green mask in bits
        GreenFieldPosition  resb 1 ; bit position of LSB of green mask
        BlueMaskSize        resb 1 ; size of direct color blue mask in bits
        BlueFieldPosition   resb 1 ; bit position of LSB of blue mask
        RsvdMaskSize        resb 1 ; size of direct color reserved mask in bits
        DirectColorModeInfo resb 1 ; Direct Color mode attributes
        Reserved2           resb 216 ; remainder of ModeInfoBlock

Podívejme se nyní, jaké informace se vypsaly:

Success
0000000080
0000000060
0000000160
0000000004
0000000004
0000000008
0000000008
00000007
00000000
0000000032
0000000032
0000B800
00000000

Rozklíčovat je můžeme následujícím způsobem:

Počet znaků na řádku:   80
Počet textových řádků:  60
Počet bajtů na řádek:  160 (80×2)
Bitů na pixel:           4 (postrádá přímý význam)
Počet rovin:             4 (postrádá přímý význam)
Šířka znaku v pixelech:  8
Výška znaku v pixelech:  8
Atributy okna A:         7 (lze měnit)
Atributy okna B:         0 (neexistuje)
Granularita oken:       32 kB (prakticky postrádá význam)
Velikost oken:          32 kB (prakticky taktéž postrádá význam)
Segment okna A:         B800 (naprostý standard pro textové režimy)
Segment okna B:         0000 (okno B neexistuje)

9. Přepnutí do textového režimu karet SVGA

Textový režim SVGA se nastavuje naprosto stejným způsobem, jako režim grafický. Pouze musíme zavolat službu 02 rozšíření VBE a v registru BX jí předat číslo požadovaného režimu. A – podobně jako u dalších volání VBE – se v pracovním registru AX vrátí hodnota 0×004f v případě, že byl režim korektně nastaven:

Vstup:  AH = 4Fh        Služby SVGA
        AL = 02h        Podslužba pro nastavení grafického nebo textového režimu
        BX = číslo režimu (nejvyšší bit řídí, zda se má video paměť vymazat či nikoli)
 
Výstup: AL = 4Fh pokud je služba podporována, jinak odlišná hodnota
        AH = 00h pokud je volání úspěšné, jinak hodnota 01h

V praxi tedy může nastavení textového režimu číslo 0×108 (80×60 znaků) vypadat následovně:

        mov  bx, 0x108             ; cislo rezimu
        mov  ax, 0x4f02            ; nastaveni grafickeho rezimu
        int      0x10
 
        cmp ax, 0x004f             ; test, zda bylo volani funkce BIOSu uspesne
        jne     failed
 
success:
        ; v pořádku
failed:
        ; nějaká chyba

10. Třetí demonstrační příklad: přepnutí do vybraného textového režimu

V dnešním třetím demonstračním příkladu se pokusíme o přepnutí grafické karty SVGA (prakticky jakékoli karty podporované rozšířením BIOSu VBE) do vybraného textového režimu. Konkrétně se bude jednat o režim číslo 0×108, což je v oblasti SVGA de facto standardní textový režim s osmdesáti znaky na řádku a šedesáti textovými řádky. Následně použijeme službu DOSu (tedy vlastně vysokoúrovňovou službu) pro tisk zprávy, abychom si ověřili, že vše pracuje podle očekávání:

;-----------------------------------------------------------------------------
org  0x100        ; zacatek kodu pro programy typu COM (vzdy se zacina na 256)
 
start:
        jmp main                   ; skok na zacatek kodu
 
%include "io.asm"                  ; nacist symboly, makra a podprogramy
%include "print.asm"               ; nacist symboly, makra a podprogramy
 
 
 
main:
        push ds
        pop  es                    ; nastaveni CS=DS=ES
 
        mov  bx, 0x108             ; cislo rezimu
        mov  ax, 0x4f02            ; nastaveni grafickeho rezimu
        int      0x10
 
        cmp ax, 0x004f             ; test, zda bylo volani funkce BIOSu uspesne
        jne     failed
 
 
success:
        print_string success_msg
        jmp     finish
 
failed:
        print_string failed_msg
 
finish:
        wait_key            ; cekani na klavesu
        exit                ; navrat do DOSu
 
 
; datova cast
section .data
 
success_msg:     db "Success", 0x0a, 0x0d, "$"
failed_msg:      db "Failed", 0x0a, 0x0d, "$"

Výsledek by mohl vypadat následovně:

Po přiblížení zjistíme, jak vypadají masky jednotlivých znaků na obrazovce:

11. Text a atributy – standard, který přežil až do dnešní doby

Již u pradávných karet CGA a MDA byl stanoven standard pro to, jak je organizována video paměť v textových režimech. V sudém bajtu (číslujeme od nuly) je uložen ASCII kód zobrazovaného znaku a v bajtu lichém jeho atribut. Struktura video paměti v textových režimech tedy vypadá takto (ukázka pro režim 80×25 znaků):

      0   1 ║ 2   3 ║ 4   5 ║ ... ║158 159
    ┌───┼───╫───┼───╫───┼───╫─────╫───┼───╖
   0│chr│atr║chr│atr║chr│atr║ ... ║chr│atr║ řádek 0
    ├───┼───╫───┼───╫───┼───╫─────╫───┼───╢
 160│chr│atr║chr│atr║chr│atr║ ... ║chr│atr║ řádek 1
    ├───┼───╫───┼───╫───┼───╫─────╫───┼───╢
 320│chr│atr║chr│atr║chr│atr║ ... ║chr│atr║ řádek 2
    ├───┼───╫───┼───╫───┼───╫─────╫───┼───╢
 480│chr│atr║chr│atr║chr│atr║ ... ║chr│atr║
    ├───┼───╫───┼───╫───┼───╫─────╫───┼───╢
    .                                     .
    ├───┼───╫───┼───╫───┼───╫─────╫───┼───╢
3840│chr│atr║chr│atr║chr│atr║ ... ║chr│atr║ řádek 24
    └───┴───╨───┴───╨───┴───╨─────╨───┴───╜

Samotný atributový bajt (samostatný pro každý znak) má tuto strukturu:

 ╓7┬6┬5┬4┬3┬2┬1┬0╖
 ║ │bkgnd│ frgnd ║
 ╙─┴─┴─┴─┴─┴─┴─┴─╜ bity
  ║ ╚═╦═╝ ╚═════╩═► 0-3:  barva popředí 0-15
  ║   ╚═══════════► 4-6:  barva pozadí 0-7
  ╚═══════════════►   7:  povolení blikání

Pokud je blikání vypnuto (viz další text), význam se nepatrně změní:

 ╓7┬6┬5┬4┬3┬2┬1┬0╖
 ║ bkgnd │ frgnd ║
 ╙─┴─┴─┴─┴─┴─┴─┴─╜ bity
  ╚══╦══╝ ╚═════╩═► 0-3:  barva popředí 0-15
     ╚════════════► 4-6:  barva pozadí 0-15

Tento způsob organizace video paměti v textových režimech zůstal zachován až do doby grafických karet SVGA. Došlo pouze k rozšíření celkového počtu znaků na obrazovce a taktéž nově existuje možnost mapovat barvy přes DAC (barvovou paletu), takže se nutně nemusí používat základní sada šestnácti barev.

12. Vyplnění části obrazovky přepnuté do textového režimu

Ukažme si nyní, jak vypadá obrazovka nějakého textového režimu. Obrazovku vyplníme různými kombinacemi atributů a znaků. Pokud bude atribut pozadí vyšší než hodnota 7, bude text blikat (což známe například ze ZX Spectra atd.):

13. Čtvrtý demonstrační příklad: vyplnění části obrazové paměti znaky a jejich atributy

Vyzkoušejme si nyní, jak bude vypadat obsah obrazovky (ať již reálné nebo emulované) v případě, že vyplníme její část (konkrétně blok 40×25×2 bajtů) nějakým obsahem. Výše zmíněný počet bajtů nebyl zvolen náhodně, protože přesně odpovídá původnímu textovému režimu grafické karty CGA, konkrétně textovému režimu zobrazujícího na monitoru 40×25 znaků se dvěma bajty na znak (kód znaku+atribut). Opět nejdříve vyzkoušíme režim číslo 0×108, tedy textový režim s osmdesáti znaky na řádku a šedesáti textovými řádky:

;-----------------------------------------------------------------------------
org  0x100        ; zacatek kodu pro programy typu COM (vzdy se zacina na 256)
 
start:
        jmp main                   ; skok na zacatek kodu
 
%include "io.asm"                  ; nacist symboly, makra a podprogramy
%include "print.asm"               ; nacist symboly, makra a podprogramy
 
 
 
main:
        push ds
        pop  es                    ; nastaveni CS=DS=ES
 
        mov  bx, 0x108             ; cislo rezimu
        mov  ax, 0x4f02            ; nastaveni grafickeho rezimu
        int      0x10
 
        cmp ax, 0x004f             ; test, zda bylo volani funkce BIOSu uspesne
        jne     failed
 
 
success:
        mov ax, 0xb800
        mov es, ax
        mov di, 0       ; nyni ES:DI obsahuje adresu prvniho znaku ve video RAM
 
        mov cx, 40*25   ; pocet zapisovanych znaku
        mov al, 0       ; kod zapisovaneho znaku
opak:
        stosb           ; zapis znaku + atributu
        stosb
        inc al          ; dalsi znak/atribut
        loop opak       ; opakujeme CX-krat
        jmp     finish
 
failed:
        print_string failed_msg
 
finish:
        wait_key            ; cekani na klavesu
        exit                ; navrat do DOSu
 
 
; datova cast
section .data
 
success_msg:     db "Success", 0x0a, 0x0d, "$"
failed_msg:      db "Failed", 0x0a, 0x0d, "$"

Výsledek by měl vypadat následovně:

14. Pátý demonstrační příklad: tatáž operace, ovšem provedená v odlišném textovém režimu

Největší počet znaků je možné zobrazit v textovém režimu s číslem 0×10c, který nabízí šedesát textových řádků a celých 132 znaků na řádku (tedy skoro osm tisíc znaků!) Vyzkoušejme si tedy, jakým způsobem se změní obsah obrazovky po přepnutí do tohoto textového režimu a nastavení prvních 40×25 znaků i jejich atributů:

;-----------------------------------------------------------------------------
org  0x100        ; zacatek kodu pro programy typu COM (vzdy se zacina na 256)
 
start:
        jmp main                   ; skok na zacatek kodu
 
%include "io.asm"                  ; nacist symboly, makra a podprogramy
%include "print.asm"               ; nacist symboly, makra a podprogramy
 
 
 
main:
        push ds
        pop  es                    ; nastaveni CS=DS=ES
 
        mov  bx, 0x10c             ; cislo rezimu
        mov  ax, 0x4f02            ; nastaveni grafickeho rezimu
        int      0x10
 
        cmp ax, 0x004f             ; test, zda bylo volani funkce BIOSu uspesne
        jne     failed
 
 
success:
        mov ax, 0xb800
        mov es, ax
        mov di, 0       ; nyni ES:DI obsahuje adresu prvniho znaku ve video RAM
 
        mov cx, 40*25   ; pocet zapisovanych znaku
        mov al, 0       ; kod zapisovaneho znaku
opak:
        stosb           ; zapis znaku + atributu
        stosb
        inc al          ; dalsi znak/atribut
        loop opak       ; opakujeme CX-krat
        jmp     finish
 
failed:
        print_string failed_msg
 
finish:
        wait_key            ; cekani na klavesu
        exit                ; navrat do DOSu
 
 
; datova cast
section .data
 
success_msg:     db "Success", 0x0a, 0x0d, "$"
failed_msg:      db "Failed", 0x0a, 0x0d, "$"

Nyní by obrazovka měla vypadat takto:

15. Textový kurzor

Všechny skutečné (nikoli emulované) textové režimy mají na platformě IBM PC společné vlastnosti:

• První stránka textového režimu ve výchozím nastavení začíná na segmentu B800
• Každá pozice znaku je uložena ve dvou bajtech; jeden bajt obsahuje kód znaku, druhý bajt jeho atributy
• Textový kurzor je řízen hardwarem (nemusí se například vykreslovat jako inverzní znak, pouze se nastavuje jeho pozice)
• Blikání kurzoru je řízeno hardwarem (kurzor bude blikat, i když se CPU zcela „zasekne“)
• Tvar kurzoru je řízen hardwarem (lze ovlivnit jen začátek a konec kurzoru ve vertikálním směru)

Zaměřme se nyní na způsob řízení tvaru textového kurzoru. Většina SVGA karet se v tomto ohledu snaží o plnohodnotnou kompatibilitu s původní grafickou kartou CGA(!) a MDA. A připomeňme si, že srdcem grafické karty CGA (ale i mnoha dalších grafických video subsystémů té doby) je čip Motorola 6845, zkráceně MC6845. SVGA karty se tedy snaží o emulaci činnosti tohoto čipu, aby bylo možné textové režimy ovládat stále stejným způsobem. A tato vlastnost platí i pro nové textové režimy s větším počtem textových řádků a/nebo sloupců.

16. Řídicí registry čipu MC6845

Nastavení resp. přesněji řečeno konfigurace grafického řadiče MC6845 se provádělo přes celkem osmnáct osmibitových řídicích registrů. Některé z těchto registrů byly určeny pro zápis (například registr s počtem znaků na řádek atd.), jiné zase pro čtení (pozice světelného pera). Číselné hodnoty, které mohly být větší než 2⁸ (což je počáteční adresa obrazové paměti, adresa kurzoru a adresa světelného pera), se musely ukládat do dvou sousedních osmibitových registrů.

Registry byly programátorům přístupné nepřímo, konkrétně přes dvojici adres – zápis do první adresy vybíral příslušný řídicí registr, čtení či zápis do druhé adresy (o jedničku vyšší) již vedl ke čtení či zápisu do příslušného řídicího registru. Díky tomu bylo možné MC6845 použít v prakticky jakémkoli počítačovém systému, a to i v případě, kdy je počet I/O portů zásadně omezen (teoreticky lze tak zkombinovat MC6845 například s osmibitovým mikrořadičem 8051). O které adresy oněch dvou registrů se konkrétně jedná záleželo na zapojení konkrétní grafické karty. Například u grafické karty CGA se jedná o I/O porty na adresách 0×3d4 a 0×3d5 a u grafické karty Hercules (taktéž IBM PC) se naopak jednalo o I/O porty 0×3b4 a 0×3b5. Moderní SVGA karty emulují CGA.

Význam jednotlivých řídicích registrů čipu 6845 je uveden v následující tabulce. Povšimněte si, že jednotkami při udávání horizontálních velikostí jsou vždy znaky a nikoli pixely – přesné časování je odvozeno od externího hodinového signálu řízeného krystalem:

17. Změna tvaru textového kurzoru modifikací HW registrů

Čip 6845, který je srdcem grafické karty MDA, CGA i Herculesu (a je emulován moderními SVGA), dokáže posílat signál o tom, že se má zobrazit textový kurzor. Toto je velmi zajímavá a možná i unikátní funkce, která je ovšem interně řešena velmi jednoduše. Adresu znaku, na kterém je textový kurzor, je nutné zapsat do dvou řídicích registrů, konkrétně do registrů R14 a R15. Dále se v registrech R10 a R11 nachází číslo mikrořádku (v rámci textového řádku), na kterém se má kurzor zobrazit – ten je totiž tvořen obdélníkem, který začíná (v rámci znaku) právě na řádku v R10 a končí na řádku uloženého v R11 (řekneme, že se jedná o hodnoty 12 a 14 pro znaky vysoké šestnáct mikrořádků).

Podívejme se nyní na způsob, jakým lze modifikovat tvar textového kurzoru. Nastavit lze počáteční obrazový řádek (v rámci výšky znaku, takže typicky v rozsahu 0 až 7 nebo 0 až 15) a koncový obrazový řádek. Oficiálně platí, že pokud je počáteční řádek větší, než řádek koncový, není kurzor zobrazen, ovšem existují neoficiální klony CGA, které v tomto případě zobrazí rozpůlený kurzor (první polovina začíná na řádku 0, druhá polovina končí na posledním znakovém řádku). Nastavení kurzoru bude vypadat následovně:

        mov dx, 0x3d4
        mov al, 0x0a    ; registr s ovladanim tvaru textoveho kurzoru
        out dx, al
        mov dx, 0x3d5
        mov al, 0       ; scanline, kde kurzor zacina 
        out dx, al
 
        mov dx, 0x3d4
        mov al, 0x0b    ; registr s ovladanim tvaru textoveho kurzoru
        out dx, al
        mov dx, 0x3d5
        mov al, 5       ; scanline, kde kurzor konci
        out dx, al

18. Šestý demonstrační příklad: změna tvaru textového kurzoru

V dnešním posledním demonstračním příkladu je ukázáno, jakým způsobem je možné přímou modifikací registrů (dnes již emulovaného) čipu MC6845 dosáhnout změny tvaru textového kurzoru. Nejdříve je provedeno přepnutí do textového režimu s vyšším počtem znaků, počká se na stisk klávesy, a posléze se tvar kurzoru změní:

;-----------------------------------------------------------------------------
org  0x100        ; zacatek kodu pro programy typu COM (vzdy se zacina na 256)
 
start:
        jmp main                   ; skok na zacatek kodu
 
%include "io.asm"                  ; nacist symboly, makra a podprogramy
%include "print.asm"               ; nacist symboly, makra a podprogramy
 
 
 
main:
        push ds
        pop  es                    ; nastaveni CS=DS=ES
 
        mov  bx, 0x108             ; cislo rezimu
        mov  ax, 0x4f02            ; nastaveni grafickeho rezimu
        int      0x10
 
        cmp ax, 0x004f             ; test, zda bylo volani funkce BIOSu uspesne
        jne     failed
 
 
success:
        print_string success_msg
 
        wait_key
 
        mov dx, 0x3d4
        mov al, 0x0a    ; registr s ovladanim tvaru textoveho kurzoru
        out dx, al
        mov dx, 0x3d5
        mov al, 0       ; scanline, kde kurzor zacina 
        out dx, al
 
        mov dx, 0x3d4
        mov al, 0x0b    ; registr s ovladanim tvaru textoveho kurzoru
        out dx, al
        mov dx, 0x3d5
        mov al, 5       ; scanline, kde kurzor konci
        out dx, al
        jmp     finish
 
failed:
        print_string failed_msg
 
finish:
        wait_key            ; cekani na klavesu
        exit                ; navrat do DOSu
 
 
; datova cast
section .data
 
success_msg:     db "Success", 0x0a, 0x0d, "$"
failed_msg:      db "Failed", 0x0a, 0x0d, "$"

Screenshoty pořízené před změnou textového kurzoru a po této změně:

19. Repositář s demonstračními příklady

Demonstrační příklady napsané v assembleru, které jsou určené pro překlad s využitím assembleru NASM, byly uloženy do Git repositáře, který je dostupný na adrese https://github.com/tisnik/8bit-fame. Jednotlivé demonstrační příklady si můžete v případě potřeby stáhnout i jednotlivě bez nutnosti klonovat celý (dnes již poměrně rozsáhlý) repositář:

20. Odkazy na Internetu

1. VESA BIOS Extensions
   https://en.wikipedia.org/wi­ki/VESA_BIOS_Extensions
2. Video Electronics Standards Association
   https://en.wikipedia.org/wi­ki/Video_Electronics_Stan­dards_Association
3. DJGPP (Wikipedia)
   https://cs.wikipedia.org/wiki/DJGPP
4. DJGPP home page
   http://www.delorie.com/djgpp/
5. DJGPP Zip File Picker
   http://www.delorie.com/djgpp/zip-picker.html
6. The Intel 8088 Architecture and Instruction Set
   https://people.ece.ubc.ca/~ed­c/464/lectures/lec4.pdf
7. x86 Opcode Structure and Instruction Overview
   https://pnx.tf/files/x86_op­code_structure_and_instruc­tion_overview.pdf
8. x86 instruction listings (Wikipedia)
   https://en.wikipedia.org/wi­ki/X86_instruction_listin­gs
9. x86 assembly language (Wikipedia)
   https://en.wikipedia.org/wi­ki/X86_assembly_language
10. Intel Assembler (Cheat sheet)
    http://www.jegerlehner.ch/in­tel/IntelCodeTable.pdf
11. 25 Microchips That Shook the World
    https://spectrum.ieee.org/tech-history/silicon-revolution/25-microchips-that-shook-the-world
12. Chip Hall of Fame: MOS Technology 6502 Microprocessor
    https://spectrum.ieee.org/tech-history/silicon-revolution/chip-hall-of-fame-mos-technology-6502-microprocessor
13. Chip Hall of Fame: Intel 8088 Microprocessor
    https://spectrum.ieee.org/tech-history/silicon-revolution/chip-hall-of-fame-intel-8088-microprocessor
14. Jak se zrodil procesor?
    https://www.root.cz/clanky/jak-se-zrodil-procesor/
15. Apple II History Home
    http://apple2history.org/
16. The 8086/8088 Primer
    https://www.stevemorse.or­g/8086/index.html
17. flat assembler: Assembly language resources
    https://flatassembler.net/
18. FASM na Wikipedii
    https://en.wikipedia.org/wiki/FASM
19. Fresh IDE FASM inside
    https://fresh.flatassembler.net/
20. MS-DOS Version 4.0 Programmer's Reference
    https://www.pcjs.org/docu­ments/books/mspl13/msdos/dos­ref40/
21. DOS API (Wikipedia)
    https://en.wikipedia.org/wiki/DOS_API
22. Bit banging
    https://en.wikipedia.org/wi­ki/Bit_banging
23. IBM Basic assembly language and successors (Wikipedia)
    https://en.wikipedia.org/wi­ki/IBM_Basic_assembly_lan­guage_and_successors
24. X86 Assembly/Bootloaders
    https://en.wikibooks.org/wi­ki/X86_Assembly/Bootloaders
25. Počátky grafiky na PC: grafické karty CGA a Hercules
    https://www.root.cz/clanky/pocatky-grafiky-na-pc-graficke-karty-cga-a-hercules/
26. Co mají společného Commodore PET/4000, BBC Micro, Amstrad CPC i grafické karty MDA, CGA a Hercules?
    https://www.root.cz/clanky/co-maji-spolecneho-commodore-pet-4000-bbc-micro-amstrad-cpc-i-graficke-karty-mda-cga-a-hercules/
27. Karta EGA: první použitelná barevná grafika na PC
    https://www.root.cz/clanky/karta-ega-prvni-pouzitelna-barevna-grafika-na-pc/
28. RGB Classic Games
    https://www.classicdosgames.com/
29. Turbo Assembler (Wikipedia)
    https://en.wikipedia.org/wi­ki/Turbo_Assembler
30. Microsoft Macro Assembler
    https://en.wikipedia.org/wi­ki/Microsoft_Macro_Assembler
31. IBM Personal Computer (Wikipedia)
    https://en.wikipedia.org/wi­ki/IBM_Personal_Computer
32. Intel 8251
    https://en.wikipedia.org/wi­ki/Intel_8251
33. Intel 8253
    https://en.wikipedia.org/wi­ki/Intel_8253
34. Intel 8255
    https://en.wikipedia.org/wi­ki/Intel_8255
35. Intel 8257
    https://en.wikipedia.org/wi­ki/Intel_8257
36. Intel 8259
    https://en.wikipedia.org/wi­ki/Intel_8259
37. Support/peripheral/other chips – 6800 family
    http://www.cpu-world.com/Support/6800.html
38. Motorola 6845
    http://en.wikipedia.org/wi­ki/Motorola_6845
39. The 6845 Cathode Ray Tube Controller (CRTC)
    http://www.tinyvga.com/6845
40. CRTC operation
    http://www.6502.org/users/an­dre/hwinfo/crtc/crtc.html
41. The 6845 Cathode Ray Tube Controller (CRTC)
    http://www.tinyvga.com/6845
42. Motorola 6845 and bitwise graphics
    https://retrocomputing.stac­kexchange.com/questions/10996/mo­torola-6845-and-bitwise-graphics
43. IBM Monochrome Display Adapter
    http://en.wikipedia.org/wi­ki/Monochrome_Display_Adap­ter
44. Color Graphics Adapter
    http://en.wikipedia.org/wi­ki/Color_Graphics_Adapter
45. Color Graphics Adapter and the Brown color in IBM 5153 Color Display
    https://www.aceinnova.com/en/e­lectronics/cga-and-the-brown-color-in-ibm-5153-color-display/
46. The Modern Retrocomputer: An Arduino Driven 6845 CRT Controller
    https://hackaday.com/2017/05/14/the-modern-retrocomputer-an-arduino-driven-6845-crt-controller/
47. flat assembler: Assembly language resources
    https://flatassembler.net/
48. FASM na Wikipedii
    https://en.wikipedia.org/wiki/FASM
49. Fresh IDE FASM inside
    https://fresh.flatassembler.net/
50. MS-DOS Version 4.0 Programmer's Reference
    https://www.pcjs.org/docu­ments/books/mspl13/msdos/dos­ref40/
51. DOS API (Wikipedia)
    https://en.wikipedia.org/wiki/DOS_API
52. IBM Basic assembly language and successors (Wikipedia)
    https://en.wikipedia.org/wi­ki/IBM_Basic_assembly_lan­guage_and_successors
53. X86 Assembly/Arithmetic
    https://en.wikibooks.org/wi­ki/X86_Assembly/Arithmetic
54. Art of Assembly – Arithmetic Instructions
    http://oopweb.com/Assembly/Do­cuments/ArtOfAssembly/Volu­me/Chapter₆/CH06–2.html
55. ASM Flags
    http://www.cavestory.org/gu­ides/csasm/guide/asm_flag­s.html
56. Status Register
    https://en.wikipedia.org/wi­ki/Status_register
57. Linux assemblers: A comparison of GAS and NASM
    http://www.ibm.com/develo­perworks/library/l-gas-nasm/index.html
58. Programovani v assembleru na OS Linux
    http://www.cs.vsb.cz/gryga­rek/asm/asmlinux.html
59. Is it worthwhile to learn x86 assembly language today?
    https://www.quora.com/Is-it-worthwhile-to-learn-x86-assembly-language-today?share=1
60. Why Learn Assembly Language?
    http://www.codeproject.com/Ar­ticles/89460/Why-Learn-Assembly-Language
61. Is Assembly still relevant?
    http://programmers.stackex­change.com/questions/95836/is-assembly-still-relevant
62. Why Learning Assembly Language Is Still a Good Idea
    http://www.onlamp.com/pub/a/on­lamp/2004/05/06/writegreat­code.html
63. Assembly language today
    http://beust.com/weblog/2004/06/23/as­sembly-language-today/
64. Assembler: Význam assembleru dnes
    http://www.builder.cz/rubri­ky/assembler/vyznam-assembleru-dnes-155960cz
65. Programming from the Ground Up Book – Summary
    http://savannah.nongnu.or­g/projects/pgubook/
66. DOSBox
    https://www.dosbox.com/
67. The C Programming Language
    https://en.wikipedia.org/wi­ki/The_C_Programming_Langu­age
68. Hercules Graphics Card (HCG)
    https://en.wikipedia.org/wi­ki/Hercules_Graphics_Card
69. Complete 8086 instruction set
    https://content.ctcd.edu/cou­rses/cosc2325/m22/docs/emu8086in­s.pdf
70. Complete 8086 instruction set
    https://yassinebridi.github.io/asm-docs/8086_instruction_set.html
71. 8088 MPH by Hornet + CRTC + DESiRE (final version)
    https://www.youtube.com/wat­ch?v=hNRO7lno_DM
72. Area 5150 by CRTC & Hornet (Party Version) / IBM PC+CGA Demo, Hardware Capture
    https://www.youtube.com/wat­ch?v=fWDxdoRTZPc
73. 80×86 Integer Instruction Set Timings (8088 – Pentium)
    http://aturing.umcs.maine­.edu/~meadow/courses/cos335/80×86-Integer-Instruction-Set-Clocks.pdf
74. Colour Graphics Adapter: Notes
    https://www.seasip.info/Vin­tagePC/cga.html
75. Restoring A Vintage CGA Card With Homebrew HASL
    https://hackaday.com/2024/06/12/res­toring-a-vintage-cga-card-with-homebrew-hasl/
76. Demoing An 8088
    https://hackaday.com/2015/04/10/de­moing-an-8088/
77. Video Memory Layouts
    http://www.techhelpmanual.com/89-video_memory_layouts.html
78. Screen Attributes
    http://www.techhelpmanual.com/87-screen_attributes.html
79. IBM PC Family – BIOS Video Modes
    https://www.minuszerodegre­es.net/video/bios_video_mo­des.htm
80. EGA Functions
    https://cosmodoc.org/topics/ega-functions/#the-hierarchy-of-the-ega
81. Why the EGA can only use 16 of its 64 colours in 200-line modes
    https://www.reenigne.org/blog/why-the-ega-can-only-use-16-of-its-64-colours-in-200-line-modes/
82. How 16 colors saved PC gaming – the story of EGA graphics
    https://www.custompc.com/retro-tech/ega-graphics
83. List of 16-bit computer color palettes
    https://en.wikipedia.org/wi­ki/List_of₁₆-bit_computer_color_palettes
84. Why were those colors chosen to be the default palette for 256-color VGA?
    https://retrocomputing.stac­kexchange.com/questions/27994/why-were-those-colors-chosen-to-be-the-default-palette-for-256-color-vga
85. VGA Color Palettes
    https://www.fountainware.com/EX­PL/vga_color_palettes.htm
86. Hardware Level VGA and SVGA Video Programming Information Page
    http://www.osdever.net/Fre­eVGA/vga/vga.htm
87. Hardware Level VGA and SVGA Video Programming Information Page – sequencer
    http://www.osdever.net/Fre­eVGA/vga/seqreg.htm
88. VGA Basics
    http://www.brackeen.com/vga/ba­sics.html
89. Introduction to VGA Mode ‚X‘
    https://web.archive.org/web/20160414072210/htt­p://fly.srk.fer.hr/GDM/ar­ticles/vgamodex/vgamx1.html
90. VGA Mode-X
    https://web.archive.org/web/20070123192523/htt­p://www.gamedev.net/referen­ce/articles/article356.asp
91. Mode-X: 256-Color VGA Magic
    https://downloads.gamedev­.net/pdf/gpbb/gpbb47.pdf
92. Instruction Format in 8086 Microprocessor
    https://www.includehelp.com/embedded-system/instruction-format-in-8086-microprocessor.aspx
93. How to use „AND,“ „OR,“ and „XOR“ modes for VGA Drawing
    https://retrocomputing.stac­kexchange.com/questions/21936/how-to-use-and-or-and-xor-modes-for-vga-drawing
94. VGA Hardware
    https://wiki.osdev.org/VGA_Hardware
95. Programmer's Guide to Yamaha YMF 262/OPL3 FM Music Synthesizer
    https://moddingwiki.shika­di.net/wiki/OPL_chip
96. Does anybody understand how OPL2 percussion mode works?
    https://forum.vcfed.org/in­dex.php?threads/does-anybody-understand-how-opl2-percussion-mode-works.60925/
97. Yamaha YMF262 OPL3 music – MoonDriver for OPL3 DEMO [Oscilloscope View]
    https://www.youtube.com/watch?v=a7I-QmrkAak
98. Yamaha OPL vs OPL2 vs OPL3 comparison
    https://www.youtube.com/wat­ch?v=5knetge5Gs0
99. OPL3 Music Crockett's Theme
    https://www.youtube.com/wat­ch?v=HXS008pkgSQ
100. Bad Apple (Adlib Tracker – OPL3)
     https://www.youtube.com/wat­ch?v=2lEPH6Y3Luo
101. FM Synthesis Chips, Codecs and DACs
     https://www.dosdays.co.uk/to­pics/fm_synthesizers.php
102. The Zen Challenge – YMF262 OPL3 Original (For an upcoming game)
     https://www.youtube.com/wat­ch?v=6JlFIFz1CFY
103. [adlib tracker II techno music – opl3] orbit around alpha andromedae I
     https://www.youtube.com/wat­ch?v=YqxJCu_WFuA
104. [adlib tracker 2 music – opl3 techno] hybridisation process on procyon-ii
     https://www.youtube.com/wat­ch?v=daSV5mN0sJ4
105. Hyper Duel – Black Rain (YMF262 OPL3 Cover)
     https://www.youtube.com/wat­ch?v=pu_mzRRq8Ho
106. IBM 5155–5160 Technical Reference
     https://www.minuszerodegre­es.net/manuals/IBM/IBM_5155_5160_Techni­cal_Reference_6280089_MAR86­.pdf
107. a ymf262/opl3+pc speaker thing i made
     https://www.youtube.com/watch?v=E-Mx0lEmnZ0
108. [OPL3] Like a Thunder
     https://www.youtube.com/wat­ch?v=MHf06AGr8SU
109. (PC SPEAKER) bad apple
     https://www.youtube.com/wat­ch?v=LezmKIIHyUg
110. Powering devices from PC parallel port
     http://www.epanorama.net/cir­cuits/lptpower.html
111. Magic Mushroom (demo pro PC s DOSem)
     http://www.crossfire-designs.de/download/articles/sou­ndcards//mushroom.rar
112. Píseň Magic Mushroom – originál
     http://www.crossfire-designs.de/download/articles/sou­ndcards/speaker_mushroom_con­verted.mp3
113. Píseň Magic Mushroom – hráno na PC Speakeru
     http://www.crossfire-designs.de/download/articles/sou­ndcards/speaker_mushroom_spe­aker.mp3
114. Pulse Width Modulation (PWM) Simulation Example
     http://decibel.ni.com/content/docs/DOC-4599
115. Resistor/Pulse Width Modulation DAC
     http://www.k9spud.com/trax­mod/pwmdac.php
116. Class D Amplifier
     http://en.wikipedia.org/wi­ki/Electronic_amplifier#Clas­s_D
117. Covox Speech Thing / Disney Sound Source (1986)
     http://www.crossfire-designs.de/index.php?lang=en&what=ar­ticles&name=showarticle.htm&ar­ticle=soundcards/&page=5
118. Covox Digital-Analog Converter (Rusky, obsahuje schémata)
     http://phantom.sannata.ru/kon­kurs/netskater002.shtml
119. PC-GPE on the Web
     http://bespin.org/~qz/pc-gpe/
120. Keyboard Synthesizer
     http://www.solarnavigator­.net/music/instruments/ke­yboards.htm
121. FMS – Fully Modular Synthesizer
     http://fmsynth.sourceforge.net/
122. Javasynth
     http://javasynth.sourceforge.net/
123. Software Sound Synthesis & Music Composition Packages
     http://www.linux-sound.org/swss.html
124. Mx44.1 Download Page (software synthesizer for linux)
     http://hem.passagen.se/ja_linux/
125. Software synthesizer
     http://en.wikipedia.org/wi­ki/Software_synthesizer
126. Frequency modulation synthesis
     http://en.wikipedia.org/wi­ki/Frequency_modulation_syn­thesis
127. Yamaha DX7
     http://en.wikipedia.org/wi­ki/Yamaha_DX7
128. Wave of the Future
     http://www.wired.com/wired/ar­chive/2.03/waveguides_pr.html
129. Analog synthesizer
     http://en.wikipedia.org/wi­ki/Analog_synthesizer
130. Minimoog
     http://en.wikipedia.org/wiki/Minimoog
131. Moog synthesizer
     http://en.wikipedia.org/wi­ki/Moog_synthesizer
132. Tutorial for Frequency Modulation Synthesis
     http://www.sfu.ca/~truax/fmtut.html
133. An Introduction To FM
     http://ccrma.stanford.edu/sof­tware/snd/snd/fm.html
134. John Chowning
     http://en.wikipedia.org/wi­ki/John_Chowning
135. I'm Impressed, Adlib Music is AMAZING!
     https://www.youtube.com/wat­ch?v=PJNjQYp1ras
136. Milinda- Diode Milliampere ( OPL3 )
     https://www.youtube.com/wat­ch?v=oNhazT5HG0E
137. Dune 2 – Roland MT-32 Soundtrack
     https://www.youtube.com/wat­ch?v=kQADZeB-z8M
138. Interrupts
     https://wiki.osdev.org/In­terrupts#Types_of_Interrup­ts
139. Assembly8086SoundBlasterDma­SingleCycleMode
     https://github.com/leonardo-ono/Assembly8086SoundBlas­terDmaSingleCycleMode/blob/mas­ter/sbsc.asm
140. Interrupts in 8086 microprocessor
     https://www.geeksforgeeks­.org/interrupts-in-8086-microprocessor/
141. Interrupt Structure of 8086
     https://www.eeeguide.com/interrupt-structure-of-8086/
142. A20 line
     https://en.wikipedia.org/wi­ki/A20_line
143. Extended memory
     https://en.wikipedia.org/wi­ki/Extended_memory#eXtended_Me­mory_Specification_(XMS)
144. Expanded memory
     https://en.wikipedia.org/wi­ki/Expanded_memory
145. Protected mode
     https://en.wikipedia.org/wi­ki/Protected_mode
146. Virtual 8086 mode
     https://en.wikipedia.org/wi­ki/Virtual_8086_mode
147. Unreal mode
     https://en.wikipedia.org/wi­ki/Unreal_mode
148. DOS memory management
     https://en.wikipedia.org/wi­ki/DOS_memory_management
149. Upper memory area
     https://en.wikipedia.org/wi­ki/Upper_memory_area
150. Removing the Mystery from SEGMENT : OFFSET Addressing
     https://thestarman.pcminis­try.com/asm/debug/Segments­.html
151. Segment descriptor
     https://en.wikipedia.org/wi­ki/Segment_descriptor
152. When using a 32-bit register to address memory in the real mode, contents of the register must never exceed 0000FFFFH. Why?
     https://stackoverflow.com/qu­estions/45094696/when-using-a-32-bit-register-to-address-memory-in-the-real-mode-contents-of-the
153. A Brief History of Unreal Mode
     https://www.os2museum.com/wp/a-brief-history-of-unreal-mode/
154. Segment Limits
     https://wiki.osdev.org/Segment_Limits
155. How do 32 bit addresses in real mode work?
     https://forum.osdev.org/vi­ewtopic.php?t=30642
156. The LOADALL Instruction by Robert Collins
     https://www.rcollins.org/ar­ticles/loadall/tspec_a3_doc­.html
157. How do you put a 286 in Protected Mode?
     https://retrocomputing.stac­kexchange.com/questions/7683/how-do-you-put-a-286-in-protected-mode
158. Control register
     https://en.wikipedia.org/wi­ki/Control_register
159. CPU Registers x86
     https://wiki.osdev.org/CPU_Re­gisters_x86
160. x86 Assembly/Protected Mode
     https://en.wikibooks.org/wi­ki/X86_Assembly/Protected_Mo­de
161. MSW: Machine Status Word
     https://web.itu.edu.tr/kes­gin/mul06/intel/intel_msw­.html
162. 80×87 Floating Point Opcodes
     http://www.techhelpmanual.com/876–80×87_floating_point_opcodes.html
163. Page Translation
     https://pdos.csail.mit.edu/6­.828/2005/readings/i386/s05_02­.htm
164. 80386 Paging and Segmenation
     https://stackoverflow.com/qu­estions/38229741/80386-paging-and-segmenation
165. 80386 Memory Management
     https://tldp.org/LDP/khg/Hy­perNews/get/memory/80386mm­.html
166. DOSEMU
     http://www.dosemu.org/
167. Intel 80386, a revolutionary CPU
     https://www.xtof.info/intel80386.html
168. PAI Unit 3 Paging in 80386 Microporcessor
     https://www.slideshare.net/Kan­chanPatil34/pai-unit-3-paging-in-80386-microporcessor
169. 64 Terabytes of virtual memory for 32-bit x86 using segmentation: how?
     https://stackoverflow.com/qu­estions/5444984/64-terabytes-of-virtual-memory-for-32-bit-x86-using-segmentation-how
170. Pi in the Pentium: reverse-engineering the constants in its floating-point unit
     http://www.righto.com/2025/01/pentium-floating-point-ROM.html
171. Simply FPU
     http://www.website.masmfo­rum.com/tutorials/fptute/
172. Art of Assembly language programming: The 80×87 Floating Point Coprocessors
     https://courses.engr.illi­nois.edu/ece390/books/arto­fasm/CH14/CH14–3.html
173. Art of Assembly language programming: The FPU Instruction Set
     https://courses.engr.illi­nois.edu/ece390/books/arto­fasm/CH14/CH14–4.html
174. INTEL 80387 PROGRAMMER'S REFERENCE MANUAL
     http://www.ragestorm.net/dow­nloads/387intel.txt
175. x86 Instruction Set Reference: FLD
     http://x86.renejeschke.de/html/fi­le_module_x86_id₁₀₀.html
176. x86 Instruction Set Reference: FLD1/FLDL2T/FLDL2E/FLDPI/­FLDLG2/FLDLN2/FLDZ
     http://x86.renejeschke.de/html/fi­le_module_x86_id₁₀₁.html
177. X86 Assembly/Arithmetic
     https://en.wikibooks.org/wi­ki/X86_Assembly/Arithmetic
178. 8087 Numeric Data Processor
     https://www.eeeguide.com/8087-numeric-data-processor/
179. Data Types and Instruction Set of 8087 co-processor
     https://www.eeeguide.com/data-types-and-instruction-set-of-8087-co-processor/
180. 8087 instruction set and examples
     https://studylib.net/doc/5625221/8087-instruction-set-and-examples
181. GCC documentation: Extensions to the C Language Family
     https://gcc.gnu.org/onlinedocs/gcc/C-Extensions.html#C-Extensions
182. GCC documentation: Using Vector Instructions through Built-in Functions
     https://gcc.gnu.org/online­docs/gcc/Vector-Extensions.html
183. SSE (Streaming SIMD Extentions)
     http://www.songho.ca/misc/sse/sse­.html
184. Timothy A. Chagnon: SSE and SSE2
     http://www.cs.drexel.edu/~tc365/mpi-wht/sse.pdf
185. Intel corporation: Extending the Worldr's Most Popular Processor Architecture
     http://download.intel.com/techno­logy/architecture/new-instructions-paper.pdf
186. SIMD architectures:
     http://arstechnica.com/ol­d/content/2000/03/simd.ar­s/
187. Tour of the Black Holes of Computing!: Floating Point
     http://www.cs.hmc.edu/~ge­off/classes/hmc.cs105…/sli­des/class02_floats.ppt
188. 3Dnow! Technology Manual
     AMD Inc., 2000
189. Intel MMX^TM Technology Overview
     Intel corporation, 1996
190. MultiMedia eXtensions
     http://softpixel.com/~cwrig­ht/programming/simd/mmx.phpi
191. AMD K5 („K5“ / „5k86“)
     http://www.pcguide.com/ref/cpu/fam/g5K5-c.html
192. Sixth Generation Processors
     http://www.pcguide.com/ref/cpu/fam/g6­.htm
193. Great Microprocessors of the Past and Present
     http://www.cpushack.com/CPU/cpu1.html
194. Very long instruction word (Wikipedia)
     http://en.wikipedia.org/wi­ki/Very_long_instruction_word
195. CPU design (Wikipedia)
     http://en.wikipedia.org/wi­ki/CPU_design
196. Grafické karty a grafické akcelerátory (14)
     https://www.root.cz/clanky/graficke-karty-a-graficke-akceleratory-14/
197. Grafické karty a grafické akcelerátory (15)
     https://www.root.cz/clanky/graficke-karty-a-graficke-akceleratory-15/
198. Grafické karty a grafické akcelerátory (16)
     https://www.root.cz/clanky/graficke-karty-a-graficke-akceleratory-16/
199. VESA Video Modes
     https://wiki.osdev.org/VE­SA_Video_Modes
200. Introduction to VESA programming
     http://www.monstersoft.com/tu­torial1/VESA_intro.html
201. Guide: VBE 2.0 graphics modes
     https://delorie.com/djgpp/doc/ug/grap­hics/vbe20.html
202. NASM instruction list
     https://userpages.cs.umbc­.edu/chang/cs313/nasmdoc/html/nas­mdocb.html
203. BitBlt function (wingdi.h)
     https://learn.microsoft.com/en-us/windows/win32/api/wingdi/nf-wingdi-bitblt
204. SetDIBitsToDevice function (wingdi.h)
     https://learn.microsoft.com/en-us/windows/win32/api/wingdi/nf-wingdi-setdibitstodevice
205. Why did line printers have 132 columns?
     https://retrocomputing.stac­kexchange.com/questions/7838/why-did-line-printers-have-132-columns
206. Tabulating machine
     https://en.wikipedia.org/wi­ki/Tabulating_machine
207. Why do printers print 132 columns on 14 7/8″ paper? It’s history
     https://blog.adafruit.com/2019/01/22/why-do-printers-print-132-columns-on-14–7–8-paper-its-history-vintagecomputing-kenshirriff-ibm/
208. IBM 1403 (Wikipedia)
     https://en.wikipedia.org/wi­ki/IBM_1403