Další tipy a triky při práci s čipem GTIA a využití joysticku

2. 4. 2026

Doba čtení: 45 minut

Líbí se vám článek?
Podpořte redakci

V šestém článku o vývoji programů pro osmibitové počítače Atari si popíšeme další možnosti čipu GTIA. Nejprve postavičky na obrazovce rozhýbeme, potom je začneme ovládat joystickem a nakonec vytvoříme pátého hráče.

Horizontální posun spritů po ploše obrazovky

Co se dozvíte v článku

Horizontální posun spritů po ploše obrazovky
Automatický pohyb prvního hráče, koncept čekací smyčky
Úplný zdrojový kód dnešního prvního demonstračního příkladu
Čekání na konec vykreslování snímku
Úplný zdrojový kód dnešního druhého demonstračního příkladu
Posun hráče pomocí joysticku
Nové užitečné instrukce: přesuny dat mezi registry
Korektní realizace posunu hráče pomocí joysticku
Úplný zdrojový kód dnešního třetího demonstračního příkladu
Zobrazení všech čtyř střel společně s hráči
Úplný zdrojový kód dnešního čtvrtého demonstračního příkladu
Čtyři střely nebo pátý hráč?
Úplný zdrojový kód dnešního pátého demonstračního příkladu
Povolení pátého hráče
Úplný zdrojový kód dnešního šestého demonstračního příkladu
Detekce stisku tlačítka joysticku, reakce na stisk tlačítka
Příloha A: Seznam všech doposud popsaných instrukcí mikroprocesoru MOS 6502
Příloha B: Makefile pro překlad všech demonstračních příkladů
Repositář s demonstračními příklady
Odkazy na Internetu

Připomeňme si, že čip GTIA umožňuje horizontální posun spritů po ploše obrazovky. Pro tento účel se používá osm registrů vypsaných v následující tabulce:

Registr	Režim	Význam
HPOSP0	W	horizontální pozice hráče číslo 0
HPOSP1	W	horizontální pozice hráče číslo 1
HPOSP2	W	horizontální pozice hráče číslo 2
HPOSP3	W	horizontální pozice hráče číslo 3
HPOSM0	W	horizontální pozice střely číslo 0
HPOSM1	W	horizontální pozice střely číslo 1
HPOSM2	W	horizontální pozice střely číslo 2
HPOSM3	W	horizontální pozice střely číslo 3

Každý z těchto registrů obsahuje osmibitovou hodnotu, což znamená rozsah 0 až 255. Ovšem okolo herního pole jsou okraje a samotné herní pole má šířku 320 pixelů (v nejvyšším rozlišení). Jak se tedy mapuje horizontální pozice spritu a pozice pixelu herního pole? Používá se tento vzoreček:

x_screen = (x_sprite - 48) * 2

Pro grafické režimy se 160 pixely na řádku je to ještě jednodušší:

x_screen = x_sprite - 48

Automatický pohyb prvního hráče, koncept čekací smyčky

V dnešním prvním demonstračním příkladu je realizován horizontální posun prvního hráče. Hráč se neustále pohybuje doprava (s přetečením na levý okraj), což lze programově realizovat velmi snadno pomocí nekonečné smyčky, ve které je horizontální pozice hráče uložena v akumulátoru:

        lda #80                 ; výchozí pozice prvního hráče
loop:
        jsr wait                ; počkáme určitou dobu
        sec
        adc #0
        sta HPOSP0              ; změna pozice prvního hráče
        jmp loop

Poznámka: bylo by ovšem možné použít i jiný registr, kde je snadnější přičítání jedničky operací INX nebo INY. Tuto optimalizaci nyní ponechám na váženém čtenáři.

Zajímavá je realizace podprogramu pro pozastavení výpočtů, který je nazvaný wait. Ten je naprogramován formou vnořené čekací smyčky, protože osmibitové pracovní registry mají nedostatečný rozsah pro čekání s využitím smyčky jediné (doba čekání je totiž velmi krátká). Proto je použita vnější smyčka s počitadlem Y a vnitřní smyčka, která je zopakována 256× (začínáme nulou, ta se ovšem ihned zmenšuje na 255):

.proc wait
        ldy #50
wait1:                          ; vnější čekací smyčka
        ldx #0
wait2:                          ; vnitřní čekací smyčka
        dex                     ; počitadlo vnitřní smyčky
        bne wait2
        dey                     ; počitadlo vnější smyčky
        bne wait1
        rts                     ; návrat ze subrutiny
.endproc

Poznámka: tento podprogram „ničí“ oba index registry X a Y, na což je zapotřebí myslet při jeho volání.

Úplný zdrojový kód dnešního prvního demonstračního příkladu

Obě techniky popsané v předchozí kapitole byly použity v dnešním prvním demonstračním příkladu. Příklad vykreslí všechny čtyři hráče a poté začne postupně měnit horizontální pozici hráče prvního:

Úplný zdrojový kód tohoto příkladu vypadá následovně:

; ---------------------------------------------------------------------
; Initializace PMG, povolení PMG, nastavení pozice, bitmapy a barvy všech
; objektů.
; ---------------------------------------------------------------------
 
.include "atari.inc"
 
.CODE
 
PLAYER_0_OFFSET = 512
PLAYER_1_OFFSET = PLAYER_0_OFFSET + 128
PLAYER_2_OFFSET = PLAYER_1_OFFSET + 128
PLAYER_3_OFFSET = PLAYER_2_OFFSET + 128
 
 
.proc main
        lda #80                 ; horizontální pozice prvního hráče
        sta HPOSP0              ; uložit do řídicího registru HPOSP0 na čipu GTIA
 
        lda #100                ; horizontální pozice druhého hráče
        sta HPOSP1              ; uložit do řídicího registru HPOSP1 na čipu GTIA
 
        lda #120                ; horizontální pozice třetího hráče
        sta HPOSP2              ; uložit do řídicího registru HPOSP2 na čipu GTIA
 
        lda #140                ; horizontální pozice čtvrtého hráče
        sta HPOSP3              ; uložit do řídicího registru HPOSP3 na čipu GTIA
 
        lda #HUE_GREEN<<4 + 12  ; barva prvního hráče (odstín+intenzita)
        sta PCOLR0              ; uložit do řídicího registru PCOLR0 na čipu GTIA
 
        lda #HUE_YELLOW<<4 + 12 ; barva druhého hráče (odstín+intenzita)
        sta PCOLR1              ; uložit do řídicího registru PCOLR1 na čipu GTIA
 
        lda #HUE_MAGENTA<<4 + 12 ; barva třetího hráče (odstín+intenzita)
        sta PCOLR2              ; uložit do řídicího registru PCOLR2 na čipu GTIA
 
        lda #HUE_CYAN<<4 + 12   ; barva čtvrtého hráče (odstín+intenzita)
        sta PCOLR3              ; uložit do řídicího registru PCOLR3 na čipu GTIA
 
        lda #$ff                ; bitová maska všech hráčů
        sta GRAFP0              ; uložit do řídicího registru GRAFP0 na čipu GTIA
        sta GRAFP1              ; uložit do řídicího registru GRAFP1 na čipu GTIA
        sta GRAFP2              ; uložit do řídicího registru GRAFP2 na čipu GTIA
        sta GRAFP3              ; uložit do řídicího registru GRAFP3 na čipu GTIA
 
        lda #3                  ; bitové pole: povolení hráčů i střel
        sta GRACTL              ; uložit do řídicího registru GRACTL na čipu GTIA
 
        lda #0                  ; priorita hráčů a pozadí
        sta GPRIOR              ; uložit do řídicího registru GPRIOR na čipu GTIA
 
        lda #152                ; paměťová stránka číslo 152
        sta PMBASE
 
        addr = 152*256
        ldx #8                  ; začneme na hodnotě o 1 vyšší
next_line:
        lda sprite-1, x         ; načíst
        sta addr+PLAYER_0_OFFSET+50, x  ; uložit byte - první hráč
        sta addr+PLAYER_1_OFFSET+50, x  ; uložit byte - druhý hráč
        sta addr+PLAYER_2_OFFSET+50, x  ; uložit byte - třetí hráč
        sta addr+PLAYER_3_OFFSET+50, x  ; uložit byte - čtvrtý hráč
        dex                     ; snížit offset + nastavit příznaky
        bne next_line           ; další byte spritu
 
        lda #46                 ; povolení PMG DMA
        sta SDMCTL
 
        lda #80                 ; výchozí pozice prvního hráče
loop:
        jsr wait                ; počkáme určitou dobu
        sec
        adc #0
        sta HPOSP0              ; změna pozice prvního hráče
        jmp loop
 
.endproc
 
 
.proc wait
        ldy #50
wait1:                          ; vnější čekací smyčka
        ldx #0
wait2:                          ; vnitřní čekací smyčka
        dex                     ; počitadlo vnitřní smyčky
        bne wait2
        dey                     ; počitadlo vnější smyčky
        bne wait1
        rts                     ; návrat ze subrutiny
.endproc
 
 
; data
sprite:   .byte 24, 60, 126, 219, 255, 36, 90, 165
 
end:
 
 
.segment "EXEHDR"
.word   $ffff                   ; uvodni sekvence bajtu v souboru XEX
.word   main                    ; zacatek kodoveho segmentu
.word   end - 1                 ; konec kodoveho segmentu
 
 
.segment "AUTOSTRT"             ; segment s pocatecni adresou
.word   RUNAD                   ; naplni se pouze adresy RUNAD a RUNAD+1
.word   RUNAD+1
.word   main                    ; adresa vstupniho bodu do programu
 
; finito

Čekání na konec vykreslování snímku

Zpomalení posunu hráče lze ovšem realizovat i jinak. Můžeme například čekat na dokončení vykreslování snímku. To lze realizovat buď přímo (ukážeme si to při programování čipu ANTIC), nebo můžeme čekat na jeden „tik“ vnitřních hodin. Jedná se o bajt uložený v nulté stránce paměti, který je automaticky zvyšován každých 1/60 nebo 1/50 sekundy operačním systémem (podle použité televizní normy). Samotná realizace takto pojaté čekací smyčky je vlastně jednoduchá – čekáme na změnu hodnoty přečtené z adresy RTCLOK+2:

.proc   _wait_vsync
        ldx     RTCLOK+2        ; čekání na konec snímku
@wt:    cpx     RTCLOK+2
        beq     @wt
        rts
.endproc

Poznámka: tento podprogram „ničí“ pouze index registr X, na což je ovšem opět zapotřebí myslet při jeho volání.

Úplný zdrojový kód dnešního druhého demonstračního příkladu

Nová podoba demonstračního příkladu, který posune prvního hráče každé dva snímky obrazovky (rychlost 25 nebo 30 pixelů za sekundu), vypadá takto:

; ---------------------------------------------------------------------
; Initializace PMG, povolení PMG, nastavení pozice, bitmapy a barvy všech
; objektů. Posun prvního hráče s čekáním na další snímek.
; ---------------------------------------------------------------------
 
.include "atari.inc"
 
.CODE
 
PLAYER_0_OFFSET = 512
PLAYER_1_OFFSET = PLAYER_0_OFFSET + 128
PLAYER_2_OFFSET = PLAYER_1_OFFSET + 128
PLAYER_3_OFFSET = PLAYER_2_OFFSET + 128
 
 
.proc main
        lda #80                 ; horizontální pozice prvního hráče
        sta HPOSP0              ; uložit do řídicího registru HPOSP0 na čipu GTIA
 
        lda #100                ; horizontální pozice druhého hráče
        sta HPOSP1              ; uložit do řídicího registru HPOSP1 na čipu GTIA
 
        lda #120                ; horizontální pozice třetího hráče
        sta HPOSP2              ; uložit do řídicího registru HPOSP2 na čipu GTIA
 
        lda #140                ; horizontální pozice čtvrtého hráče
        sta HPOSP3              ; uložit do řídicího registru HPOSP3 na čipu GTIA
 
        lda #HUE_GREEN<<4 + 12  ; barva prvního hráče (odstín+intenzita)
        sta PCOLR0              ; uložit do řídicího registru PCOLR0 na čipu GTIA
 
        lda #HUE_YELLOW<<4 + 12 ; barva druhého hráče (odstín+intenzita)
        sta PCOLR1              ; uložit do řídicího registru PCOLR1 na čipu GTIA
 
        lda #HUE_MAGENTA<<4 + 12 ; barva třetího hráče (odstín+intenzita)
        sta PCOLR2              ; uložit do řídicího registru PCOLR2 na čipu GTIA
 
        lda #HUE_CYAN<<4 + 12   ; barva čtvrtého hráče (odstín+intenzita)
        sta PCOLR3              ; uložit do řídicího registru PCOLR3 na čipu GTIA
 
        lda #$ff                ; bitová maska všech hráčů
        sta GRAFP0              ; uložit do řídicího registru GRAFP0 na čipu GTIA
        sta GRAFP1              ; uložit do řídicího registru GRAFP1 na čipu GTIA
        sta GRAFP2              ; uložit do řídicího registru GRAFP2 na čipu GTIA
        sta GRAFP3              ; uložit do řídicího registru GRAFP3 na čipu GTIA
 
        lda #3                  ; bitové pole: povolení hráčů i střel
        sta GRACTL              ; uložit do řídicího registru GRACTL na čipu GTIA
 
        lda #0                  ; priorita hráčů a pozadí
        sta GPRIOR              ; uložit do řídicího registru GPRIOR na čipu GTIA
 
        lda #152                ; paměťová stránka číslo 152
        sta PMBASE
 
        addr = 152*256
        ldx #8                  ; začneme na hodnotě o 1 vyšší
next_line:
        lda sprite-1, x         ; načíst
        sta addr+PLAYER_0_OFFSET+50, x  ; uložit byte - první hráč
        sta addr+PLAYER_1_OFFSET+50, x  ; uložit byte - druhý hráč
        sta addr+PLAYER_2_OFFSET+50, x  ; uložit byte - třetí hráč
        sta addr+PLAYER_3_OFFSET+50, x  ; uložit byte - čtvrtý hráč
        dex                     ; snížit offset + nastavit příznaky
        bne next_line           ; další byte spritu
 
        lda #46                 ; povolení PMG DMA
        sta SDMCTL
 
        lda #80                 ; výchozí pozice prvního hráče
loop:
        jsr _wait_vsync
        jsr _wait_vsync
        jsr _wait_vsync
 
        sec
        adc #0
        sta HPOSP0              ; změna pozice prvního hráče
        jmp loop
 
.endproc
 
 
.proc   _wait_vsync
        ldx     RTCLOK+2        ; čekání na konec snímku
@wt:    cpx     RTCLOK+2
        beq     @wt
        rts
.endproc
 
 
; data
sprite:   .byte 24, 60, 126, 219, 255, 36, 90, 165
 
end:
 
 
.segment "EXEHDR"
.word   $ffff                   ; uvodni sekvence bajtu v souboru XEX
.word   main                    ; zacatek kodoveho segmentu
.word   end - 1                 ; konec kodoveho segmentu
 
 
.segment "AUTOSTRT"             ; segment s pocatecni adresou
.word   RUNAD                   ; naplni se pouze adresy RUNAD a RUNAD+1
.word   RUNAD+1
.word   main                    ; adresa vstupniho bodu do programu
 
; finito

Posun hráče pomocí joysticku

V další fázi vylepšování příkladu s PMG budeme prvního hráče ovládat pomocí joysticku. Prozatím dokážeme hráčem pohybovat doleva a doprava, takže se omezíme pouze na tyto dva směry. Můžeme se pokusit naprogramovat první variantu programové smyčky, ve které na základě náklonu joysticku zvýšíme nebo naopak snížíme hodnotu index registru X, který obsahuje horizontální pozici hráče. Vysokoúrovňová varianta vypadá takto:

        ldx #80                 ; výchozí pozice prvního hráče
loop:
        if joystick vlevo  -> dex
        if joystick vpravo -> inx
        stx HPOSP0              ; změna pozice prvního hráče
        jmp loop

Nyní musíme dopsat realizaci podmínek. Stav prvního joysticku je uložen v hardwarovém registru STICK0, přičemž náklon joysticku je zakódován následovně (binární zápis ukazuje, že je v kódech určitá logika – každý směr je zakódován jedním znegovaným bitem):

  Decimálně                   Binárně
 
       14                       1110
        |                         |
    10  | 6                 1010  | 0110
      \ |/                      \ |/
  11-- 15 ---7           1011-- 1111 --0111
      / |\                      / |\
     9  | 5                 1001  | 0101
        |                         |
       13                       1101

My tedy budeme rozpoznávat pouze kódy 11 a 7. Realizace posunu hráče je vlastně velmi jednoduchá a omezuje se na dvojici instrukcí CMP+BNE (test na hodnotu a skok, pokud je hodnota odlišná od hodnoty porovnávané):

        ldx #80                 ; výchozí pozice prvního hráče
loop:
        jsr _wait_vsync
        jsr _wait_vsync
 
        lda STICK0              ; čtení joysticku
        cmp #11                 ; je nakloněn doleva?
        bne not_left
        dex                     ; posun hráče doleva
not_left:
        cmp #7                  ; je nakloněn doprava?
        bne not_right
        inx                     ; posun hráče doprava
not_right:
        stx HPOSP0              ; změna pozice prvního hráče
        jmp loop

Poznámka: sice to není vidět a assembler nás na to upozorní, ovšem příklad nebude funkční, protože obsah registru X je „zničen“ v subrutině _wait_vsync. Musíme tedy najít jiné řešení (a v rámci tréninku předpokládejme, že není možné použít ani akumulátor, ani registr Y).

Nové užitečné instrukce: přesuny dat mezi registry

V souvislosti s rostoucí komplexností programů se začínají využívat všechny pracovní registry mikroprocesoru MOS 6502. Musíme se tedy seznámit s instrukcemi určenými pro přenos hodnot mezi těmito registry. Tyto instrukce (je jich oficiálně pouze šest) začínají znakem T a obsahují svůj význam přímo v mnemotechnické zkratce instrukce (nemají tedy žádné parametry – zapomeňte na univerzální MOV, u kterého není zřejmé, co je zdrojem a co cílem):

#	Instrukce	Plné jméno	Popis
40	TAX	transfer accumulator to X	přesun hodnoty z akumulátoru do index registru X
41	TAY	transfer accumulator to Y	přesun hodnoty z akumulátoru do index registru Y
42	TXA	transfer X to accumulator	přesun hodnoty z index registru X do akumulátoru
43	TYA	transfer Y to accumulator	přesun hodnoty z index registru Y do akumulátoru
44	TSX	transfer stack pointer to X	přesun ukazatele vrcholu zásobníku do index registru X
45	TXS	transfer X to stack pointer	přesun hodnoty z index registru X do ukazatele vrcholu zásobníku

Poznámka: jak je pro MOS 6502 (a pro mnohé další osmibitové mikroprocesory) typické, není instrukční sada plně ortogonální, což například znamená, že neexistuje přímá instrukce určená pro přesun hodnoty z index registru X do index registru Y (nebo naopak). A přesuny hodnoty ukazatele vrcholu zásobníku se provádí pouze s index registrem X. O to je programování zajímavější.

Korektní realizace posunu hráče pomocí joysticku

Se znalostí instrukcí pro přesuny dat můžeme celou smyčku realizující posun hráče s využitím joysticku upravit. Před voláním subrutiny _wait_vsync uložíme obsah index registru X do akumulátoru a poté ho opět obnovíme (TXA+TAX). Nemusíme se tedy starat o zásobník ani o uložení do operační paměti:

        ldx #80                 ; výchozí pozice prvního hráče
loop:
        txa                     ; uložení obsahu X do akumulátoru
        jsr _wait_vsync
        jsr _wait_vsync
        tax                     ; obnovení obsahu X z akumulátoru

        lda STICK0              ; čtení joysticku
        cmp #11                 ; je nakloněn doleva?
        bne not_left
        dex                     ; posun hráče doleva
not_left:
        cmp #7                  ; je nakloněn doprava?
        bne not_right
        inx                     ; posun hráče doprava
not_right:
        stx HPOSP0              ; změna pozice prvního hráče
        jmp loop

Poznámka: říkal někdo, že tři registry nestačí?

Úplný zdrojový kód dnešního třetího demonstračního příkladu

Výše uvedenou programovou smyčku můžeme bez dalších úprav přidat do nové verze demonstračního příkladu, jehož úplný zdrojový kód vypadá následovně:

; ---------------------------------------------------------------------
; Ovládání PMG joystickem.
; ---------------------------------------------------------------------
 
.include "atari.inc"
 
.CODE
 
PLAYER_0_OFFSET = 512
PLAYER_1_OFFSET = PLAYER_0_OFFSET + 128
PLAYER_2_OFFSET = PLAYER_1_OFFSET + 128
PLAYER_3_OFFSET = PLAYER_2_OFFSET + 128
 
 
.proc main
        lda #80                 ; horizontální pozice prvního hráče
        sta HPOSP0              ; uložit do řídicího registru HPOSP0 na čipu GTIA
 
        lda #100                ; horizontální pozice druhého hráče
        sta HPOSP1              ; uložit do řídicího registru HPOSP1 na čipu GTIA
 
        lda #120                ; horizontální pozice třetího hráče
        sta HPOSP2              ; uložit do řídicího registru HPOSP2 na čipu GTIA
 
        lda #140                ; horizontální pozice čtvrtého hráče
        sta HPOSP3              ; uložit do řídicího registru HPOSP3 na čipu GTIA
 
        lda #HUE_GREEN<<4 + 12  ; barva prvního hráče (odstín+intenzita)
        sta PCOLR0              ; uložit do řídicího registru PCOLR0 na čipu GTIA
 
        lda #HUE_YELLOW<<4 + 12 ; barva druhého hráče (odstín+intenzita)
        sta PCOLR1              ; uložit do řídicího registru PCOLR1 na čipu GTIA
 
        lda #HUE_MAGENTA<<4 + 12 ; barva třetího hráče (odstín+intenzita)
        sta PCOLR2              ; uložit do řídicího registru PCOLR2 na čipu GTIA
 
        lda #HUE_CYAN<<4 + 12   ; barva čtvrtého hráče (odstín+intenzita)
        sta PCOLR3              ; uložit do řídicího registru PCOLR3 na čipu GTIA
 
        lda #$ff                ; bitová maska všech hráčů
        sta GRAFP0              ; uložit do řídicího registru GRAFP0 na čipu GTIA
        sta GRAFP1              ; uložit do řídicího registru GRAFP1 na čipu GTIA
        sta GRAFP2              ; uložit do řídicího registru GRAFP2 na čipu GTIA
        sta GRAFP3              ; uložit do řídicího registru GRAFP3 na čipu GTIA
 
        lda #3                  ; bitové pole: povolení hráčů i střel
        sta GRACTL              ; uložit do řídicího registru GRACTL na čipu GTIA
 
        lda #0                  ; priorita hráčů a pozadí
        sta GPRIOR              ; uložit do řídicího registru GPRIOR na čipu GTIA
 
        lda #152                ; paměťová stránka číslo 152
        sta PMBASE
 
        addr = 152*256
        ldx #8                  ; začneme na hodnotě o 1 vyšší
next_line:
        lda sprite-1, x         ; načíst
        sta addr+PLAYER_0_OFFSET+50, x  ; uložit byte - první hráč
        sta addr+PLAYER_1_OFFSET+50, x  ; uložit byte - druhý hráč
        sta addr+PLAYER_2_OFFSET+50, x  ; uložit byte - třetí hráč
        sta addr+PLAYER_3_OFFSET+50, x  ; uložit byte - čtvrtý hráč
        dex                     ; snížit offset + nastavit příznaky
        bne next_line           ; další byte spritu
 
        lda #46                 ; povolení PMG DMA
        sta SDMCTL
 
        ldx #80                 ; výchozí pozice prvního hráče
loop:
        txa                     ; uložení obsahu X do akumulátoru
        jsr _wait_vsync
        jsr _wait_vsync
        tax                     ; obnovení obsahu X z akumulátoru
 
        lda STICK0              ; čtení joysticku
        cmp #11                 ; je nakloněn doleva?
        bne not_left
        dex                     ; posun hráče doleva
not_left:
        cmp #7                  ; je nakloněn doprava?
        bne not_right
        inx                     ; posun hráče doprava
not_right:
        stx HPOSP0              ; změna pozice prvního hráče
        jmp loop
 
.endproc
 
 
.proc   _wait_vsync
        ldx     RTCLOK+2        ; čekání na konec snímku
@wt:    cpx     RTCLOK+2
        beq     @wt
        rts
.endproc
 
 
; data
sprite:   .byte 24, 60, 126, 219, 255, 36, 90, 165
 
end:
 
 
.segment "EXEHDR"
.word   $ffff                   ; uvodni sekvence bajtu v souboru XEX
.word   main                    ; zacatek kodoveho segmentu
.word   end - 1                 ; konec kodoveho segmentu
 
 
.segment "AUTOSTRT"             ; segment s pocatecni adresou
.word   RUNAD                   ; naplni se pouze adresy RUNAD a RUNAD+1
.word   RUNAD+1
.word   main                    ; adresa vstupniho bodu do programu
 
; finito

Zobrazení všech čtyř střel společně s hráči

Připomeňme si, že kromě čtyř hráčů o šířce osmi pixelů a výšce 128 nebo 256 pixelů je možné čipem GTIA ovládat i takzvané střely (missiles), které mají šířku pouhé dva pixely. Tvary všech čtyř střel jsou uloženy v jediném bloku (128 nebo 256 bajtů), a to konkrétně od offsetu 384 v rámci adresového rozsahu 0..1024, který vyhradíme pro sprity:

PLAYER_0_OFFSET = 512
PLAYER_1_OFFSET = PLAYER_0_OFFSET + 128
PLAYER_2_OFFSET = PLAYER_1_OFFSET + 128
PLAYER_3_OFFSET = PLAYER_2_OFFSET + 128
MISSILES_OFFSET = 384

Řídit je možné horizontální pozice všech čtyř střel, a to nezávisle na hráčích a nezávisle na ostatních střelách:

Registr	Režim	Význam
HPOSM0	W	horizontální pozice střely číslo 0
HPOSM1	W	horizontální pozice střely číslo 1
HPOSM2	W	horizontální pozice střely číslo 2
HPOSM3	W	horizontální pozice střely číslo 3

Ovšem barva střel je závislá na barvě hráčů (nebo naopak), což je patrné i z následujícího screenshotu:

Poznámka: první hráč má stejnou barvu jako první střela, dtto pro druhého, třetího a čtvrtého hráče.

Úplný zdrojový kód dnešního čtvrtého demonstračního příkladu

Další úprava demonstračního příkladu spočívá v přidání všech čtyř střel na obrazovku. Povšimněte si, že každá střela je skutečně široká pouze dva pixely a tudíž každé střele odpovídají jen dva bity z bitmapy 8×128 nebo 8×256 pixelů. Navíc je patrné, že střely mají stejnou barvu jako odpovídající hráči:

; ---------------------------------------------------------------------
; Ovládání PMG joystickem.
; ---------------------------------------------------------------------
 
.include "atari.inc"
 
.CODE
 
PLAYER_0_OFFSET = 512
PLAYER_1_OFFSET = PLAYER_0_OFFSET + 128
PLAYER_2_OFFSET = PLAYER_1_OFFSET + 128
PLAYER_3_OFFSET = PLAYER_2_OFFSET + 128
MISSILES_OFFSET = 384
 
 
.proc main
        lda #80                 ; horizontální pozice prvního hráče
        sta HPOSP0              ; uložit do řídicího registru HPOSP0 na čipu GTIA
 
        lda #95                 ; horizontální pozice druhého hráče
        sta HPOSP1              ; uložit do řídicího registru HPOSP1 na čipu GTIA
 
        lda #110                ; horizontální pozice třetího hráče
        sta HPOSP2              ; uložit do řídicího registru HPOSP2 na čipu GTIA
 
        lda #125                ; horizontální pozice čtvrtého hráče
        sta HPOSP3              ; uložit do řídicího registru HPOSP3 na čipu GTIA
 
        lda #140                ; horizontální pozice první střely
        sta HPOSM0              ; uložit do řídicího registru HPOSP0 na čipu GTIA
 
        lda #150                ; horizontální pozice druhé střely
        sta HPOSM1              ; uložit do řídicího registru HPOSP1 na čipu GTIA
 
        lda #160                ; horizontální pozice třetí střely
        sta HPOSM2              ; uložit do řídicího registru HPOSP2 na čipu GTIA
 
        lda #170                ; horizontální pozice čtvrté střely
        sta HPOSM3              ; uložit do řídicího registru HPOSP3 na čipu GTIA
 
        lda #HUE_GREEN<<4 + 12  ; barva prvního hráče (odstín+intenzita)
        sta PCOLR0              ; uložit do řídicího registru PCOLR0 na čipu GTIA
 
        lda #HUE_YELLOW<<4 + 12 ; barva druhého hráče (odstín+intenzita)
        sta PCOLR1              ; uložit do řídicího registru PCOLR1 na čipu GTIA
 
        lda #HUE_MAGENTA<<4 + 12 ; barva třetího hráče (odstín+intenzita)
        sta PCOLR2              ; uložit do řídicího registru PCOLR2 na čipu GTIA
 
        lda #HUE_CYAN<<4 + 12   ; barva čtvrtého hráče (odstín+intenzita)
        sta PCOLR3              ; uložit do řídicího registru PCOLR3 na čipu GTIA
 
        lda #$ff                ; bitová maska všech hráčů
        sta GRAFP0              ; uložit do řídicího registru GRAFP0 na čipu GTIA
        sta GRAFP1              ; uložit do řídicího registru GRAFP1 na čipu GTIA
        sta GRAFP2              ; uložit do řídicího registru GRAFP2 na čipu GTIA
        sta GRAFP3              ; uložit do řídicího registru GRAFP3 na čipu GTIA
 
        lda #3                  ; bitové pole: povolení hráčů i střel
        sta GRACTL              ; uložit do řídicího registru GRACTL na čipu GTIA
 
        lda #0                  ; priorita hráčů a pozadí
        sta GPRIOR              ; uložit do řídicího registru GPRIOR na čipu GTIA
 
        lda #152                ; paměťová stránka číslo 152
        sta PMBASE
 
        addr = 152*256
        ldx #8                  ; začneme na hodnotě o 1 vyšší
next_line:
        lda sprite-1, x         ; načíst
        sta addr+PLAYER_0_OFFSET+50, x  ; uložit byte - první hráč
        sta addr+PLAYER_1_OFFSET+50, x  ; uložit byte - druhý hráč
        sta addr+PLAYER_2_OFFSET+50, x  ; uložit byte - třetí hráč
        sta addr+PLAYER_3_OFFSET+50, x  ; uložit byte - čtvrtý hráč
        sta addr+MISSILES_OFFSET+50, x  ; uložit byte - střely
        dex                     ; snížit offset + nastavit příznaky
        bne next_line           ; další byte spritu
 
        lda #46                 ; povolení PMG DMA
        sta SDMCTL
 
        ldx #80                 ; výchozí pozice prvního hráče
loop:
        txa                     ; uložení obsahu X do akumulátoru
        jsr _wait_vsync
        jsr _wait_vsync
        tax                     ; obnovení obsahu X z akumulátoru
 
        lda STICK0              ; čtení joysticku
        cmp #11                 ; je nakloněn doleva?
        bne not_left
        dex                     ; posun hráče doleva
not_left:
        cmp #7                  ; je nakloněn doprava?
        bne not_right
        inx                     ; posun hráče doprava
not_right:
        stx HPOSP0              ; změna pozice prvního hráče
        jmp loop
 
.endproc
 
 
.proc   _wait_vsync
        ldx     RTCLOK+2        ; čekání na konec snímku
@wt:    cpx     RTCLOK+2
        beq     @wt
        rts
.endproc
 
 
; data
sprite:   .byte 24, 60, 126, 219, 255, 36, 90, 165
 
end:
 
 
.segment "EXEHDR"
.word   $ffff                   ; uvodni sekvence bajtu v souboru XEX
.word   main                    ; zacatek kodoveho segmentu
.word   end - 1                 ; konec kodoveho segmentu
 
 
.segment "AUTOSTRT"             ; segment s pocatecni adresou
.word   RUNAD                   ; naplni se pouze adresy RUNAD a RUNAD+1
.word   RUNAD+1
.word   main                    ; adresa vstupniho bodu do programu
 
; finito

Čtyři střely nebo pátý hráč?

Vzhledem k tomu, že střely mají šířku dvou pixelů a celkem je možné zobrazit čtyři střely, nabízí se otázka, jestli z nich nelze vytvořit „pátého hráče“. Prvním krokem k pátému hráči je horizontální posun střel takovým způsobem, aby od sebe byly posunuty přesně o dva pixely a současně byly uspořádány zleva doprava v pořadí M3+M2+M1+M0:

        lda #146                ; horizontální pozice první střely
        sta HPOSM0              ; uložit do řídicího registru HPOSP0 na čipu GTIA

        lda #144                ; horizontální pozice druhé střely
        sta HPOSM1              ; uložit do řídicího registru HPOSP1 na čipu GTIA

        lda #142                ; horizontální pozice třetí střely
        sta HPOSM2              ; uložit do řídicího registru HPOSP2 na čipu GTIA

        lda #140                ; horizontální pozice čtvrté střely
        sta HPOSM3              ; uložit do řídicího registru HPOSP3 na čipu GTIA

Výsledkem je „něco“, co se podobá duhovému pátému hráči:

Úplný zdrojový kód dnešního pátého demonstračního příkladu

Opět si pro úplnost ukažme úplný zdrojový kód dnešního pátého demonstračního příkladu, jenž vypadá následovně:

; ---------------------------------------------------------------------
; Ovládání PMG joystickem.
; ---------------------------------------------------------------------
 
.include "atari.inc"
 
.CODE
 
PLAYER_0_OFFSET = 512
PLAYER_1_OFFSET = PLAYER_0_OFFSET + 128
PLAYER_2_OFFSET = PLAYER_1_OFFSET + 128
PLAYER_3_OFFSET = PLAYER_2_OFFSET + 128
MISSILES_OFFSET = 384
 
 
.proc main
        lda #80                 ; horizontální pozice prvního hráče
        sta HPOSP0              ; uložit do řídicího registru HPOSP0 na čipu GTIA
 
        lda #95                 ; horizontální pozice druhého hráče
        sta HPOSP1              ; uložit do řídicího registru HPOSP1 na čipu GTIA
 
        lda #110                ; horizontální pozice třetího hráče
        sta HPOSP2              ; uložit do řídicího registru HPOSP2 na čipu GTIA
 
        lda #125                ; horizontální pozice čtvrtého hráče
        sta HPOSP3              ; uložit do řídicího registru HPOSP3 na čipu GTIA
 
        lda #146                ; horizontální pozice první střely
        sta HPOSM0              ; uložit do řídicího registru HPOSP0 na čipu GTIA
 
        lda #144                ; horizontální pozice druhé střely
        sta HPOSM1              ; uložit do řídicího registru HPOSP1 na čipu GTIA
 
        lda #142                ; horizontální pozice třetí střely
        sta HPOSM2              ; uložit do řídicího registru HPOSP2 na čipu GTIA
 
        lda #140                ; horizontální pozice čtvrté střely
        sta HPOSM3              ; uložit do řídicího registru HPOSP3 na čipu GTIA
 
        lda #HUE_GREEN<<4 + 12  ; barva prvního hráče (odstín+intenzita)
        sta PCOLR0              ; uložit do řídicího registru PCOLR0 na čipu GTIA
 
        lda #HUE_YELLOW<<4 + 12 ; barva druhého hráče (odstín+intenzita)
        sta PCOLR1              ; uložit do řídicího registru PCOLR1 na čipu GTIA
 
        lda #HUE_MAGENTA<<4 + 12 ; barva třetího hráče (odstín+intenzita)
        sta PCOLR2              ; uložit do řídicího registru PCOLR2 na čipu GTIA
 
        lda #HUE_CYAN<<4 + 12   ; barva čtvrtého hráče (odstín+intenzita)
        sta PCOLR3              ; uložit do řídicího registru PCOLR3 na čipu GTIA
 
        lda #$ff                ; bitová maska všech hráčů
        sta GRAFP0              ; uložit do řídicího registru GRAFP0 na čipu GTIA
        sta GRAFP1              ; uložit do řídicího registru GRAFP1 na čipu GTIA
        sta GRAFP2              ; uložit do řídicího registru GRAFP2 na čipu GTIA
        sta GRAFP3              ; uložit do řídicího registru GRAFP3 na čipu GTIA
 
        lda #3                  ; bitové pole: povolení hráčů i střel
        sta GRACTL              ; uložit do řídicího registru GRACTL na čipu GTIA
 
        lda #0                  ; priorita hráčů a pozadí
        sta GPRIOR              ; uložit do řídicího registru GPRIOR na čipu GTIA
 
        lda #152                ; paměťová stránka číslo 152
        sta PMBASE
 
        addr = 152*256
        ldx #8                  ; začneme na hodnotě o 1 vyšší
next_line:
        lda sprite-1, x         ; načíst
        sta addr+PLAYER_0_OFFSET+50, x  ; uložit byte - první hráč
        sta addr+PLAYER_1_OFFSET+50, x  ; uložit byte - druhý hráč
        sta addr+PLAYER_2_OFFSET+50, x  ; uložit byte - třetí hráč
        sta addr+PLAYER_3_OFFSET+50, x  ; uložit byte - čtvrtý hráč
        sta addr+MISSILES_OFFSET+50, x  ; uložit byte - střely
        dex                     ; snížit offset + nastavit příznaky
        bne next_line           ; další byte spritu
 
        lda #46                 ; povolení PMG DMA
        sta SDMCTL
 
        ldx #80                 ; výchozí pozice prvního hráče
loop:
        txa                     ; uložení obsahu X do akumulátoru
        jsr _wait_vsync
        jsr _wait_vsync
        tax                     ; obnovení obsahu X z akumulátoru
 
        lda STICK0              ; čtení joysticku
        cmp #11                 ; je nakloněn doleva?
        bne not_left
        dex                     ; posun hráče doleva
not_left:
        cmp #7                  ; je nakloněn doprava?
        bne not_right
        inx                     ; posun hráče doprava
not_right:
        stx HPOSP0              ; změna pozice prvního hráče
        jmp loop
 
.endproc
 
 
.proc   _wait_vsync
        ldx     RTCLOK+2        ; čekání na konec snímku
@wt:    cpx     RTCLOK+2
        beq     @wt
        rts
.endproc
 
 
; data
sprite:   .byte 24, 60, 126, 219, 255, 36, 90, 165
 
end:
 
 
.segment "EXEHDR"
.word   $ffff                   ; uvodni sekvence bajtu v souboru XEX
.word   main                    ; zacatek kodoveho segmentu
.word   end - 1                 ; konec kodoveho segmentu
 
 
.segment "AUTOSTRT"             ; segment s pocatecni adresou
.word   RUNAD                   ; naplni se pouze adresy RUNAD a RUNAD+1
.word   RUNAD+1
.word   main                    ; adresa vstupniho bodu do programu
 
; finito

Povolení pátého hráče

V tomto seriálu jsme se již několikrát setkali s řídicím registrem GPRIOR. Podle názvu se jedná o registr řídicí prioritu spritů a herního pole, ovšem k tomuto účelu slouží jen spodní čtyři bity. Šestý bit již známe – zapíná operaci OR barev spritů, pokud se překrývají. Ovšem zajímavý je i pátý bit, který zapíná „pátého hráče“:

        lda #16                 ; priorita hráčů a pozadí -> povolení pátého hráče
        sta GPRIOR              ; uložit do řídicího registru GPRIOR na čipu GTIA

Pátý hráč se sice skládá ze čtyř střel, ovšem bude mít jednotnou barvu zapisovanou do registru COLOR3 (POZOR: to je změna, toto je registr s více významy):

        lda #HUE_YELLOWRED<<4 + 8   ; barva pátého hráče (odstín+intenzita)
        sta COLOR3              ; uložit do řídicího registru COLPF3 na čipu GTIA

Výsledek bude vypadat takto:

Poznámka: ovšem stále platí, že horizontálním posunem střel můžeme pátého hráče „rozsekat“ na čtyři kousky, což se ostatně v některých hrách hodí pro různé efekty.

Úplný zdrojový kód dnešního šestého demonstračního příkladu

Dnešní předposlední demonstrační příklad vypadá takto:

; ---------------------------------------------------------------------
; Ovládání PMG joystickem.
; ---------------------------------------------------------------------
 
.include "atari.inc"
 
.CODE
 
PLAYER_0_OFFSET = 512
PLAYER_1_OFFSET = PLAYER_0_OFFSET + 128
PLAYER_2_OFFSET = PLAYER_1_OFFSET + 128
PLAYER_3_OFFSET = PLAYER_2_OFFSET + 128
MISSILES_OFFSET = 384
 
 
.proc main
        lda #80                 ; horizontální pozice prvního hráče
        sta HPOSP0              ; uložit do řídicího registru HPOSP0 na čipu GTIA
 
        lda #95                 ; horizontální pozice druhého hráče
        sta HPOSP1              ; uložit do řídicího registru HPOSP1 na čipu GTIA
 
        lda #110                ; horizontální pozice třetího hráče
        sta HPOSP2              ; uložit do řídicího registru HPOSP2 na čipu GTIA
 
        lda #125                ; horizontální pozice čtvrtého hráče
        sta HPOSP3              ; uložit do řídicího registru HPOSP3 na čipu GTIA
 
        lda #146                ; horizontální pozice první střely
        sta HPOSM0              ; uložit do řídicího registru HPOSP0 na čipu GTIA
 
        lda #144                ; horizontální pozice druhé střely
        sta HPOSM1              ; uložit do řídicího registru HPOSP1 na čipu GTIA
 
        lda #142                ; horizontální pozice třetí střely
        sta HPOSM2              ; uložit do řídicího registru HPOSP2 na čipu GTIA
 
        lda #140                ; horizontální pozice čtvrté střely
        sta HPOSM3              ; uložit do řídicího registru HPOSP3 na čipu GTIA
 
        lda #HUE_GREEN<<4 + 12  ; barva prvního hráče (odstín+intenzita)
        sta PCOLR0              ; uložit do řídicího registru PCOLR0 na čipu GTIA
 
        lda #HUE_YELLOW<<4 + 12 ; barva druhého hráče (odstín+intenzita)
        sta PCOLR1              ; uložit do řídicího registru PCOLR1 na čipu GTIA
 
        lda #HUE_MAGENTA<<4 + 12 ; barva třetího hráče (odstín+intenzita)
        sta PCOLR2              ; uložit do řídicího registru PCOLR2 na čipu GTIA
 
        lda #HUE_CYAN<<4 + 12   ; barva čtvrtého hráče (odstín+intenzita)
        sta PCOLR3              ; uložit do řídicího registru PCOLR3 na čipu GTIA
 
        lda #HUE_YELLOWRED<<4 + 8   ; barva pátého hráče (odstín+intenzita)
        sta COLOR3              ; uložit do řídicího registru COLPF3 na čipu GTIA
 
        lda #$ff                ; bitová maska všech hráčů
        sta GRAFP0              ; uložit do řídicího registru GRAFP0 na čipu GTIA
        sta GRAFP1              ; uložit do řídicího registru GRAFP1 na čipu GTIA
        sta GRAFP2              ; uložit do řídicího registru GRAFP2 na čipu GTIA
        sta GRAFP3              ; uložit do řídicího registru GRAFP3 na čipu GTIA
 
        lda #3                  ; bitové pole: povolení hráčů i střel
        sta GRACTL              ; uložit do řídicího registru GRACTL na čipu GTIA
 
        lda #16                 ; priorita hráčů a pozadí -> povolení pátého hráče
        sta GPRIOR              ; uložit do řídicího registru GPRIOR na čipu GTIA
 
        lda #152                ; paměťová stránka číslo 152
        sta PMBASE
 
        addr = 152*256
        ldx #8                  ; začneme na hodnotě o 1 vyšší
next_line:
        lda sprite-1, x         ; načíst
        sta addr+PLAYER_0_OFFSET+50, x  ; uložit byte - první hráč
        sta addr+PLAYER_1_OFFSET+50, x  ; uložit byte - druhý hráč
        sta addr+PLAYER_2_OFFSET+50, x  ; uložit byte - třetí hráč
        sta addr+PLAYER_3_OFFSET+50, x  ; uložit byte - čtvrtý hráč
        sta addr+MISSILES_OFFSET+50, x  ; uložit byte - střely
        dex                     ; snížit offset + nastavit příznaky
        bne next_line           ; další byte spritu
 
        lda #46                 ; povolení PMG DMA
        sta SDMCTL
 
        ldx #80                 ; výchozí pozice prvního hráče
loop:
        txa                     ; uložení obsahu X do akumulátoru
        jsr _wait_vsync
        jsr _wait_vsync
        tax                     ; obnovení obsahu X z akumulátoru
 
        lda STICK0              ; čtení joysticku
        cmp #11                 ; je nakloněn doleva?
        bne not_left
        dex                     ; posun hráče doleva
not_left:
        cmp #7                  ; je nakloněn doprava?
        bne not_right
        inx                     ; posun hráče doprava
not_right:
        stx HPOSP0              ; změna pozice prvního hráče
        jmp loop
 
.endproc
 
 
.proc   _wait_vsync
        ldx     RTCLOK+2        ; čekání na konec snímku
@wt:    cpx     RTCLOK+2
        beq     @wt
        rts
.endproc
 
 
; data
sprite:   .byte 24, 60, 126, 219, 255, 36, 90, 165
 
end:
 
 
.segment "EXEHDR"
.word   $ffff                   ; uvodni sekvence bajtu v souboru XEX
.word   main                    ; zacatek kodoveho segmentu
.word   end - 1                 ; konec kodoveho segmentu
 
 
.segment "AUTOSTRT"             ; segment s pocatecni adresou
.word   RUNAD                   ; naplni se pouze adresy RUNAD a RUNAD+1
.word   RUNAD+1
.word   main                    ; adresa vstupniho bodu do programu
 
; finito

Detekce stisku tlačítka joysticku, reakce na stisk tlačítka

V předchozím textu jsme si ukázali, jak lze zjistit náklon joysticku. Ještě nám zbývá detekce stisku tlačítka joysticku. To je snadné, protože stačí přečíst obsah registru STRIG0. Obsah tohoto registru je ovšem poněkud matoucí: jednička znamená, že tlačítko není stisknutu a nula naopak znamená detekci stisku. Snadno tedy můžeme realizovat například změnu barvy hráče stiskem tlačítka:

        lda STRIG0              ; 0=stisknuto (Z je nastaven)
        bne not_pressed         ; NE==NZ
 
        tya
        clc
        adc #16                 ; změna odstínu barvy, ne intenzity
        tay
        sty PCOLR0              ; modifikovat barvový registr
not_pressed:

Poznámka: povšimněte si, jak jsme se opět vyhnuli použití zásobníku – celý kód si stále vystačí s pouhými třemi pracovními registry!

Již naposledy si ukažme zdrojový kód:

; ---------------------------------------------------------------------
; Ovládání PMG joystickem.
; ---------------------------------------------------------------------
 
.include "atari.inc"
 
.CODE
 
PLAYER_0_OFFSET = 512
PLAYER_1_OFFSET = PLAYER_0_OFFSET + 128
PLAYER_2_OFFSET = PLAYER_1_OFFSET + 128
PLAYER_3_OFFSET = PLAYER_2_OFFSET + 128
MISSILES_OFFSET = 384
 
 
.proc main
        lda #80                 ; horizontální pozice prvního hráče
        sta HPOSP0              ; uložit do řídicího registru HPOSP0 na čipu GTIA
 
        lda #95                 ; horizontální pozice druhého hráče
        sta HPOSP1              ; uložit do řídicího registru HPOSP1 na čipu GTIA
 
        lda #110                ; horizontální pozice třetího hráče
        sta HPOSP2              ; uložit do řídicího registru HPOSP2 na čipu GTIA
 
        lda #125                ; horizontální pozice čtvrtého hráče
        sta HPOSP3              ; uložit do řídicího registru HPOSP3 na čipu GTIA
 
        lda #146                ; horizontální pozice první střely
        sta HPOSM0              ; uložit do řídicího registru HPOSP0 na čipu GTIA
 
        lda #144                ; horizontální pozice druhé střely
        sta HPOSM1              ; uložit do řídicího registru HPOSP1 na čipu GTIA
 
        lda #142                ; horizontální pozice třetí střely
        sta HPOSM2              ; uložit do řídicího registru HPOSP2 na čipu GTIA
 
        lda #140                ; horizontální pozice čtvrté střely
        sta HPOSM3              ; uložit do řídicího registru HPOSP3 na čipu GTIA
 
        lda #HUE_GREEN<<4 + 12  ; barva prvního hráče (odstín+intenzita)
        sta PCOLR0              ; uložit do řídicího registru PCOLR0 na čipu GTIA
 
        lda #HUE_YELLOW<<4 + 12 ; barva druhého hráče (odstín+intenzita)
        sta PCOLR1              ; uložit do řídicího registru PCOLR1 na čipu GTIA
 
        lda #HUE_MAGENTA<<4 + 12 ; barva třetího hráče (odstín+intenzita)
        sta PCOLR2              ; uložit do řídicího registru PCOLR2 na čipu GTIA
 
        lda #HUE_CYAN<<4 + 12   ; barva čtvrtého hráče (odstín+intenzita)
        sta PCOLR3              ; uložit do řídicího registru PCOLR3 na čipu GTIA
 
        lda #HUE_YELLOWRED<<4 + 8   ; barva pátého hráče (odstín+intenzita)
        sta COLOR3              ; uložit do řídicího registru COLPF3 na čipu GTIA
 
        lda #$ff                ; bitová maska všech hráčů
        sta GRAFP0              ; uložit do řídicího registru GRAFP0 na čipu GTIA
        sta GRAFP1              ; uložit do řídicího registru GRAFP1 na čipu GTIA
        sta GRAFP2              ; uložit do řídicího registru GRAFP2 na čipu GTIA
        sta GRAFP3              ; uložit do řídicího registru GRAFP3 na čipu GTIA
 
        lda #3                  ; bitové pole: povolení hráčů i střel
        sta GRACTL              ; uložit do řídicího registru GRACTL na čipu GTIA
 
        lda #16                 ; priorita hráčů a pozadí -> povolení pátého hráče
        sta GPRIOR              ; uložit do řídicího registru GPRIOR na čipu GTIA
 
        lda #152                ; paměťová stránka číslo 152
        sta PMBASE
 
        addr = 152*256
        ldx #8                  ; začneme na hodnotě o 1 vyšší
next_line:
        lda sprite-1, x         ; načíst
        sta addr+PLAYER_0_OFFSET+50, x  ; uložit byte - první hráč
        sta addr+PLAYER_1_OFFSET+50, x  ; uložit byte - druhý hráč
        sta addr+PLAYER_2_OFFSET+50, x  ; uložit byte - třetí hráč
        sta addr+PLAYER_3_OFFSET+50, x  ; uložit byte - čtvrtý hráč
        sta addr+MISSILES_OFFSET+50, x  ; uložit byte - střely
        dex                     ; snížit offset + nastavit příznaky
        bne next_line           ; další byte spritu
 
        lda #46                 ; povolení PMG DMA
        sta SDMCTL
 
        ldy #14                 ; barva prvního hráče
        ldx #80                 ; výchozí pozice prvního hráče
loop:
        txa                     ; uložení obsahu X do akumulátoru
        jsr _wait_vsync
        jsr _wait_vsync
        tax                     ; obnovení obsahu X z akumulátoru
 
        lda STICK0              ; čtení joysticku
        cmp #11                 ; je nakloněn doleva?
        bne not_left
        dex                     ; posun hráče doleva
not_left:
        cmp #7                  ; je nakloněn doprava?
        bne not_right
        inx                     ; posun hráče doprava
not_right:
        stx HPOSP0              ; změna pozice prvního hráče
 
        lda STRIG0              ; 0=stisknuto (Z je nastaven)
        bne not_pressed         ; NE==NZ
 
        tya
        clc
        adc #16                 ; změna odstínu barvy, ne intenzity
        tay
        sty PCOLR0              ; modifikovat barvový registr
not_pressed:
 
       jmp loop
 
.endproc
 
 
.proc   _wait_vsync
        ldx     RTCLOK+2        ; čekání na konec snímku
@wt:    cpx     RTCLOK+2
        beq     @wt
        rts
.endproc
 
 
; data
sprite:   .byte 24, 60, 126, 219, 255, 36, 90, 165
 
end:
 
 
.segment "EXEHDR"
.word   $ffff                   ; uvodni sekvence bajtu v souboru XEX
.word   main                    ; zacatek kodoveho segmentu
.word   end - 1                 ; konec kodoveho segmentu
 
 
.segment "AUTOSTRT"             ; segment s pocatecni adresou
.word   RUNAD                   ; naplni se pouze adresy RUNAD a RUNAD+1
.word   RUNAD+1
.word   main                    ; adresa vstupniho bodu do programu
 
; finito

Příloha A: Seznam všech doposud popsaných instrukcí mikroprocesoru MOS 6502

Všechny doposud popsané instrukce mikroprocesoru MOS 6502 jsou vypsány v následující tabulce (oproti minulému článku se seznam instrukcí rozšířil):

#	Instrukce	Plné jméno	Popis
1	ADC	add with carry	součet hodnoty s akumulátorem (včetně přetečení)
2	SBC	subtract with carry	odečtení hodnoty od akumulátoru (včetně výpůjčky)

3	AND	and with accumulator	logické AND s akumulátorem
4	ORA	or with accumulator	logické OR s akumulátorem
5	EOR	exclusive or with accumulator	logické XOR s akumulátorem

6	INC	increment	zvýšení hodnoty o 1 (kupodivu nelze s akumulátorem, ovšem s pamětí ano)
7	INX	increment X	zvýšení hodnoty index registru X o 1
8	INY	increment Y	zvýšení hodnoty index registru Y o 1
9	DEC	decrement	snížení hodnoty o 1 (opět nelze s akumulátorem)
10	DEX	decrement X	snížení hodnoty index registru X o 1
11	DEY	decrement Y	snížení hodnoty index registru Y o 1

12	CMP	compare with accumulator	odečtení hodnoty od akumulátoru bez zápisu výsledku
13	CPX	compare with X	odečtení hodnoty od index registru X bez zápisu výsledku
14	CPY	compare with Y	odečtení hodnoty od index registru Y bez zápisu výsledku
15	BIT	bit test	logické AND bez uložení výsledků (změní se jen příznakové bity)

16	ASL	arithmetic shift left	aritmetický posun doleva o jeden bit
17	LSR	logical shift right	logický posun doprava o jeden bit
18	ROL	rotate left	rotace doleva o jeden bit
19	ROR	rotate right	rotace doprava o jeden bit

20	JMP	jump	skok (existuje několik adresovacích režimů)
21	JSR	jump to subroutine	skok do podprogramu s uložením návratové adresy na zásobník
22	RTS	return from subroutine	návrat z podprogramu
23	RTI	return from interrupt	návrat z prerušovací rutiny

24	BCC	branch on carry clear	rozvětvení za podmínky C==0
25	BCS	branch on carry set	rozvětvení za podmínky C==1
26	BEQ	branch on equal (zero set)	rozvětvení za podmínky Z==1
27	BMI	branch on minus (negative set)	rozvětvení za podmínky N==1
28	BNE	branch on not equal (zero clear)	rozvětvení za podmínky Z==0
29	BPL	branch on plus (negative clear)	rozvětvení za podmínky N==0
30	BVC	branch on overflow clear	rozvětvení za podmínky O==0
31	BVS	branch on overflow set	rozvětvení za podmínky O==1

32	PHA	push accumulator on stack	uložení obsahu akumulátoru na zásobník
33	PLA	pull accumulator from stack	obnovení obsahu akumulátoru ze zásobníku

34	LDA	load accumulator	načtení hodnoty do akumulátoru
35	LDX	load X register	načtení hodnoty do index registru X
36	LDY	load Y register	načtení hodnoty do index registru Y
37	STA	store accumulator	uložení akumulátoru
38	STX	store X register	uložení index registru X
39	STY	store Y register	uložení index registru Y

40	TAX	transfer accumulator to X	přesun hodnoty z akumulátoru do index registru X
41	TAY	transfer accumulator to Y	přesun hodnoty z akumulátoru do index registru Y
42	TXA	transfer X to accumulator	přesun hodnoty z index registru X do akumulátoru
43	TYA	transfer Y to accumulator	přesun hodnoty z index registru Y do akumulátoru
44	TSX	transfer stack pointer to X	přesun ukazatele vrcholu zásobníku do index registru X
45	TXS	transfer X to stack pointer	přesun hodnoty z index registru X do ukazatele vrcholu zásobníku

Příloha B: Makefile pro překlad všech demonstračních příkladů

Všechny minule i dnes popsané demonstrační příklady, pro jejichž překlad je zapotřebí použít assembler ca65 a linker ld65, je možné přeložit s využitím souboru Makefile, jehož obsah je vypsán pod tímto odstavcem:

execs := dummy.xex print_a.xex \
         background_color_1.xex  background_color_2.xex \
         color_computation_1.xex color_computation_2.xex \
         subroutine_1.xex        subroutine_2.xex \
         hex_number_1.xex        hex_number_2.xex \
         hex_number_3.xex        hex_number_4.xex \
         hex_number_5.xex        hex_number_6.xex \
         hex_number_7.xex        hex_number_8.xex \
         hex_number_9.xex \
         fill_block_1.xex        fill_block_2.xex \
         fill_block_3.xex        fill_block_4.xex \
         fill_block_5.xex \
         pmg_01.xex              pmg_02.xex \
         pmg_03.xex              pmg_04.xex \
         pmg_05.xex              pmg_06.xex \
         pmg_07.xex              pmg_08.xex \
         pmg_09.xex              pmg_10.xex \
         pmg_11.xex              pmg_12.xex \
         pmg_stick_1.xex         pmg_stick_2.xex \
         pmg_stick_3.xex         pmg_stick_4.xex \
         pmg_stick_5.xex
 
all: $(execs)
 
clean:
        rm -f *.o
        rm -f *.xex
 
.PHONY: all clean
 
%.o: %.asm
        ca65 $< -t atari -o $@ -l $(basename $<)_list.asm --list-bytes 100
 
%.xex: %.o
        ld65 -C linker.cfg $< -o $@ -m $(basename $<).map

Výsledkem překladu jsou soubory s koncovkou .xex, které je možné přímo spustit v emulátoru osmibitových počítačů Atari.

Repositář s demonstračními příklady

Všechny demonstrační příklady, s nimiž jsme se v předchozích článcích i v článku dnešním seznámili a které jsou určeny pro překlad s využitím assembleru ca65, jsou dostupné, jak je zvykem, na GitHubu. V tabulce níže jsou uvedeny odkazy na jednotlivé zdrojové kódy příkladů psané v assembleru i „listingy“ vygenerované samotným assemblerem, ze kterých je patrné, jakým způsobem se jednotlivé příklady přeložily do výsledného XEX souboru:

#	Příklad	Stručný popis příkladu	Adresa
1	Makefile	definice cílů pro překlad všech demonstračních příkladů z této tabulky	https://github.com/tisnik/8bit-fame/blob/master/Atari800-ca65/Makefile
2	linker.cfg	konfigurační soubor pro linker	https://github.com/tisnik/8bit-fame/blob/master/Atari800-ca65/linker.cfg

3	dummy.asm	pouze nekonečná smyčka	https://github.com/tisnik/8bit-fame/blob/master/Atari800-ca65/dummy.asm
4	dummy_list.asm	„listing“ vygenerovaný assemblerem	https://github.com/tisnik/8bit-fame/blob/master/Atari800-ca65/dummy_list.asm
5	dummy_list.map	mapa paměti; soubor vytvořený linkerem	https://github.com/tisnik/8bit-fame/blob/master/Atari800-ca65/dummy.map

6	background_color₁.asm	změna barvy pozadí – základní varianta příkladu	https://github.com/tisnik/8bit-fame/blob/master/Atari800-ca65/background_color₁.asm
7	background_color₁_list.asm	„listing“ vygenerovaný assemblerem	https://github.com/tisnik/8bit-fame/blob/master/Atari800-ca65/background_color₁_list.asm
8	background_color₁.map	mapa paměti; soubor vytvořený linkerem	https://github.com/tisnik/8bit-fame/blob/master/Atari800-ca65/background_color₁.map

9	background_color₂.asm	změna barvy pozadí – využití předdefinovaných konstant	https://github.com/tisnik/8bit-fame/blob/master/Atari800-ca65/background_color₂.asm
10	background_color₂_list.asm	„listing“ vygenerovaný assemblerem	https://github.com/tisnik/8bit-fame/blob/master/Atari800-ca65/background_color₂_list.asm
11	background_color₂.map	mapa paměti; soubor vytvořený linkerem	https://github.com/tisnik/8bit-fame/blob/master/Atari800-ca65/background_color₂.map

12	print_a.asm	tisk znaku přímo do obrazové paměti	https://github.com/tisnik/8bit-fame/blob/master/Atari800-ca65/print_a.asm
13	print_a_list.asm	„listing“ vygenerovaný assemblerem	https://github.com/tisnik/8bit-fame/blob/master/Atari800-ca65/print_a_list.asm
14	print_a.map	mapa paměti; soubor vytvořený linkerem	https://github.com/tisnik/8bit-fame/blob/master/Atari800-ca65/print_a.map

15	color_computation₁.asm	výpočet barvy, varianta bez bitových posunů	https://github.com/tisnik/8bit-fame/blob/master/Atari800-ca65/color_computation₁.asm
16	color_computation₁_list.asm	„listing“ vygenerovaný assemblerem	https://github.com/tisnik/8bit-fame/blob/master/Atari800-ca65/color_computation₁_list.asm
17	color_computation₁.map	mapa paměti; soubor vytvořený linkerem	https://github.com/tisnik/8bit-fame/blob/master/Atari800-ca65/color_computation₁.map

18	color_computation₂.asm	výpočet barvy, varianta s bitovými posuny	https://github.com/tisnik/8bit-fame/blob/master/Atari800-ca65/color_computation₂.asm
19	color_computation₂_list.asm	„listing“ vygenerovaný assemblerem	https://github.com/tisnik/8bit-fame/blob/master/Atari800-ca65/color_computation₂_list.asm
20	color_computation₂.map	mapa paměti; soubor vytvořený linkerem	https://github.com/tisnik/8bit-fame/blob/master/Atari800-ca65/color_computation₂.map

21	subroutine₁.asm	skok do podprogramu bez předávání parametrů	https://github.com/tisnik/8bit-fame/blob/master/Atari800-ca65/subroutine₁.asm
22	subroutine₁_list.asm	„listing“ vygenerovaný assemblerem	https://github.com/tisnik/8bit-fame/blob/master/Atari800-ca65/subroutine₁_list.asm
23	subroutine₁.map	mapa paměti; soubor vytvořený linkerem	https://github.com/tisnik/8bit-fame/blob/master/Atari800-ca65/subroutine₁.map

24	subroutine₂.asm	skok do podprogramu s předáním parametru	https://github.com/tisnik/8bit-fame/blob/master/Atari800-ca65/subroutine₂.asm
25	subroutine₂_list.asm	„listing“ vygenerovaný assemblerem	https://github.com/tisnik/8bit-fame/blob/master/Atari800-ca65/subroutine₂_list.asm
26	subroutine₂.map	mapa paměti; soubor vytvořený linkerem	https://github.com/tisnik/8bit-fame/blob/master/Atari800-ca65/subroutine₂.map

27	hex_number₁.asm	tisk jedné hexadecimální číslice (nekorektní varianta)	https://github.com/tisnik/8bit-fame/blob/master/Atari800-ca65/hex_number₁.asm
28	hex_number₁_list.asm	„listing“ vygenerovaný assemblerem	https://github.com/tisnik/8bit-fame/blob/master/Atari800-ca65/hex_number₁_list.asm
29	hex_number₁.map	mapa paměti; soubor vytvořený linkerem	https://github.com/tisnik/8bit-fame/blob/master/Atari800-ca65/hex_number₁.map

30	hex_number₂.asm	tisk jedné hexadecimální číslice (korektní varianta)	https://github.com/tisnik/8bit-fame/blob/master/Atari800-ca65/hex_number₂.asm
31	hex_number₂_list.asm	„listing“ vygenerovaný assemblerem	https://github.com/tisnik/8bit-fame/blob/master/Atari800-ca65/hex_number₂_list.asm
32	hex_number₂.map	mapa paměti; soubor vytvořený linkerem	https://github.com/tisnik/8bit-fame/blob/master/Atari800-ca65/hex_number₂.map

33	hex_number₃.asm	tisk jedné hexadecimální číslice (korektní varianta po refaktoringu)	https://github.com/tisnik/8bit-fame/blob/master/Atari800-ca65/hex_number₃.asm
34	hex_number₃_list.asm	„listing“ vygenerovaný assemblerem	https://github.com/tisnik/8bit-fame/blob/master/Atari800-ca65/hex_number₃_list.asm
35	hex_number₃.map	mapa paměti; soubor vytvořený linkerem	https://github.com/tisnik/8bit-fame/blob/master/Atari800-ca65/hex_number₃.map

36	hex_number₄.asm	tisk jedné hexadecimální číslice, varianta postavená na makrech	https://github.com/tisnik/8bit-fame/blob/master/Atari800-ca65/hex_number₄.asm
37	hex_number₄_list.asm	„listing“ vygenerovaný assemblerem	https://github.com/tisnik/8bit-fame/blob/master/Atari800-ca65/hex_number₄_list.asm
38	hex_number₄.map	mapa paměti; soubor vytvořený linkerem	https://github.com/tisnik/8bit-fame/blob/master/Atari800-ca65/hex_number₄.map

39	hex_number₅.asm	tisk jedné hexadecimální číslice, varianta postavená na makrech, lokální automaticky generovaná návěští	https://github.com/tisnik/8bit-fame/blob/master/Atari800-ca65/hex_number₅.asm
40	hex_number₅_list.asm	„listing“ vygenerovaný assemblerem	https://github.com/tisnik/8bit-fame/blob/master/Atari800-ca65/hex_number₅_list.asm
41	hex_number₅.map	mapa paměti; soubor vytvořený linkerem	https://github.com/tisnik/8bit-fame/blob/master/Atari800-ca65/hex_number₅.map

42	hex_number₆.asm	příprava pro tisk dvouciferné hexadecimální hodnoty	https://github.com/tisnik/8bit-fame/blob/master/Atari800-ca65/hex_number₆.asm
43	hex_number₆_list.asm	„listing“ vygenerovaný assemblerem	https://github.com/tisnik/8bit-fame/blob/master/Atari800-ca65/hex_number₆_list.asm
44	hex_number₆.map	mapa paměti; soubor vytvořený linkerem	https://github.com/tisnik/8bit-fame/blob/master/Atari800-ca65/hex_number₆.map

45	hex_number₇.asm	realizace tisku dvouciferné hexadecimální hodnoty	https://github.com/tisnik/8bit-fame/blob/master/Atari800-ca65/hex_number₇.asm
46	hex_number₇_list.asm	„listing“ vygenerovaný assemblerem	https://github.com/tisnik/8bit-fame/blob/master/Atari800-ca65/hex_number₇_list.asm
47	hex_number₇.map	mapa paměti; soubor vytvořený linkerem	https://github.com/tisnik/8bit-fame/blob/master/Atari800-ca65/hex_number₇.map

48	hex_number₈.asm	makro pro logický posun doprava o zadaný počet bitů	https://github.com/tisnik/8bit-fame/blob/master/Atari800-ca65/hex_number₈.asm
49	hex_number₈_list.asm	„listing“ vygenerovaný assemblerem	https://github.com/tisnik/8bit-fame/blob/master/Atari800-ca65/hex_number₈_list.asm
50	hex_number₈.map	mapa paměti; soubor vytvořený linkerem	https://github.com/tisnik/8bit-fame/blob/master/Atari800-ca65/hex_number₈.map

51	hex_number₉.asm	čekání na stisk klávesy	https://github.com/tisnik/8bit-fame/blob/master/Atari800-ca65/hex_number₈.asm
52	hex_number₉_list.asm	„listing“ vygenerovaný assemblerem	https://github.com/tisnik/8bit-fame/blob/master/Atari800-ca65/hex_number₈_list.asm
53	hex_number₉.map	mapa paměti; soubor vytvořený linkerem	https://github.com/tisnik/8bit-fame/blob/master/Atari800-ca65/hex_number₈.map

54	fill_block₁.asm	vyplnění bloku, varianta se dvěma index registry	https://github.com/tisnik/8bit-fame/blob/master/Atari800-ca65/fill_block₁.asm
55	fill_block₁_list.asm	„listing“ vygenerovaný assemblerem	https://github.com/tisnik/8bit-fame/blob/master/Atari800-ca65/fill_block₁_list.asm
56	fill_block₁.map	mapa paměti; soubor vytvořený linkerem	https://github.com/tisnik/8bit-fame/blob/master/Atari800-ca65/fill_block₁.map

57	fill_block₂.asm	vyplnění bloku, nekorektní varianta využívající jeden index registr	https://github.com/tisnik/8bit-fame/blob/master/Atari800-ca65/fill_block₂.asm
58	fill_block₂_list.asm	„listing“ vygenerovaný assemblerem	https://github.com/tisnik/8bit-fame/blob/master/Atari800-ca65/fill_block₂_list.asm
59	fill_block₂.map	mapa paměti; soubor vytvořený linkerem	https://github.com/tisnik/8bit-fame/blob/master/Atari800-ca65/fill_block₂.map

60	fill_block₃.asm	vyplnění bloku, korektní varianta využívající jeden index registr	https://github.com/tisnik/8bit-fame/blob/master/Atari800-ca65/fill_block₃.asm
61	fill_block₃_list.asm	„listing“ vygenerovaný assemblerem	https://github.com/tisnik/8bit-fame/blob/master/Atari800-ca65/fill_block₃_list.asm
62	fill_block₃.map	mapa paměti; soubor vytvořený linkerem	https://github.com/tisnik/8bit-fame/blob/master/Atari800-ca65/fill_block₃.map

63	fill_block₄.asm	vyplnění bloku delšího než 256 bajtů	https://github.com/tisnik/8bit-fame/blob/master/Atari800-ca65/fill_block₄.asm
64	fill_block₄_list.asm	„listing“ vygenerovaný assemblerem	https://github.com/tisnik/8bit-fame/blob/master/Atari800-ca65/fill_block₄_list.asm
65	fill_block₄.map	mapa paměti; soubor vytvořený linkerem	https://github.com/tisnik/8bit-fame/blob/master/Atari800-ca65/fill_block₄.map

66	fill_block₅.asm	vyplnění bloku, čítání směrem nahoru	https://github.com/tisnik/8bit-fame/blob/master/Atari800-ca65/fill_block₅.asm
67	fill_block₅_list.asm	„listing“ vygenerovaný assemblerem	https://github.com/tisnik/8bit-fame/blob/master/Atari800-ca65/fill_block₅_list.asm
68	fill_block₅.map	mapa paměti; soubor vytvořený linkerem	https://github.com/tisnik/8bit-fame/blob/master/Atari800-ca65/fill_block₅.map

69	pmg₀₁.asm	inicializace PMG, povolení PMG, nastavení pozice a tvaru prvního hráče	https://github.com/tisnik/8bit-fame/blob/master/Atari800-ca65/pmg₀₁.asm
70	pmg₀₁_list.asm	„listing“ vygenerovaný assemblerem	https://github.com/tisnik/8bit-fame/blob/master/Atari800-ca65/pmg₀₁_list.asm
71	pmg₀₁.map	mapa paměti; soubor vytvořený linkerem	https://github.com/tisnik/8bit-fame/blob/master/Atari800-ca65/pmg₀₁.map

72	pmg₀₂.asm	nastavení pozice, tvaru a barvy prvního hráče	https://github.com/tisnik/8bit-fame/blob/master/Atari800-ca65/pmg₀₂.asm
73	pmg₀₂_list.asm	„listing“ vygenerovaný assemblerem	https://github.com/tisnik/8bit-fame/blob/master/Atari800-ca65/pmg₀₂_list.asm
74	pmg₀₂.map	mapa paměti; soubor vytvořený linkerem	https://github.com/tisnik/8bit-fame/blob/master/Atari800-ca65/pmg₀₂.map

75	pmg₀₃.asm	vliv zákazu DMA na zobrazení PMG	https://github.com/tisnik/8bit-fame/blob/master/Atari800-ca65/pmg₀₃.asm
76	pmg₀₃_list.asm	„listing“ vygenerovaný assemblerem	https://github.com/tisnik/8bit-fame/blob/master/Atari800-ca65/pmg₀₃_list.asm
77	pmg₀₃.map	mapa paměti; soubor vytvořený linkerem	https://github.com/tisnik/8bit-fame/blob/master/Atari800-ca65/pmg₀₃.map

78	pmg₀₄.asm	postupná změna horizontální velikosti hráče	https://github.com/tisnik/8bit-fame/blob/master/Atari800-ca65/pmg₀₄.asm
79	pmg₀₄_list.asm	„listing“ vygenerovaný assemblerem	https://github.com/tisnik/8bit-fame/blob/master/Atari800-ca65/pmg₀₄_list.asm
80	pmg₀₄.map	mapa paměti; soubor vytvořený linkerem	https://github.com/tisnik/8bit-fame/blob/master/Atari800-ca65/pmg₀₄.map

81	pmg₀₅.asm	odlišná bitová maska tvaru hráče	https://github.com/tisnik/8bit-fame/blob/master/Atari800-ca65/pmg₀₅.asm
82	pmg₀₅_list.asm	„listing“ vygenerovaný assemblerem	https://github.com/tisnik/8bit-fame/blob/master/Atari800-ca65/pmg₀₅_list.asm
83	pmg₀₅.map	mapa paměti; soubor vytvořený linkerem	https://github.com/tisnik/8bit-fame/blob/master/Atari800-ca65/pmg₀₅.map

84	pmg₀₆.asm	inicializace a zobrazení dvou hráčů, kteří se překrývají	https://github.com/tisnik/8bit-fame/blob/master/Atari800-ca65/pmg₀₆.asm
84	pmg₀₆_list.asm	„listing“ vygenerovaný assemblerem	https://github.com/tisnik/8bit-fame/blob/master/Atari800-ca65/pmg₀₆_list.asm
86	pmg₀₆.map	mapa paměti; soubor vytvořený linkerem	https://github.com/tisnik/8bit-fame/blob/master/Atari800-ca65/pmg₀₆.map

87	pmg₀₇.asm	naivní způsob nastavení bitmapy prvního hráče	https://github.com/tisnik/8bit-fame/blob/master/Atari800-ca65/pmg₀₇.asm
88	pmg₀₇_list.asm	„listing“ vygenerovaný assemblerem	https://github.com/tisnik/8bit-fame/blob/master/Atari800-ca65/pmg₀₇_list.asm
89	pmg₀₇.map	mapa paměti; soubor vytvořený linkerem	https://github.com/tisnik/8bit-fame/blob/master/Atari800-ca65/pmg₀₇.map

90	pmg₀₈.asm	elegantnější způsob nastavení bitmapy prvního hráče	https://github.com/tisnik/8bit-fame/blob/master/Atari800-ca65/pmg₀₈.asm
91	pmg₀₈_list.asm	„listing“ vygenerovaný assemblerem	https://github.com/tisnik/8bit-fame/blob/master/Atari800-ca65/pmg₀₈_list.asm
92	pmg₀₈.map	mapa paměti; soubor vytvořený linkerem	https://github.com/tisnik/8bit-fame/blob/master/Atari800-ca65/pmg₀₈.map

93	pmg₀₉.asm	zobrazení všech čtyř hráčů, změna priority zobrazení	https://github.com/tisnik/8bit-fame/blob/master/Atari800-ca65/pmg₀₉.asm
94	pmg₀₉_list.asm	„listing“ vygenerovaný assemblerem	https://github.com/tisnik/8bit-fame/blob/master/Atari800-ca65/pmg₀₉_list.asm
95	pmg₀₉.map	mapa paměti; soubor vytvořený linkerem	https://github.com/tisnik/8bit-fame/blob/master/Atari800-ca65/pmg₀₉.map

96	pmg₁₀.asm	nastavení bitmap všech čtyř hráčů	https://github.com/tisnik/8bit-fame/blob/master/Atari800-ca65/pmg₁₀.asm
97	pmg₁₀_list.asm	„listing“ vygenerovaný assemblerem	https://github.com/tisnik/8bit-fame/blob/master/Atari800-ca65/pmg₁₀_list.asm
98	pmg₁₀.map	mapa paměti; soubor vytvořený linkerem	https://github.com/tisnik/8bit-fame/blob/master/Atari800-ca65/pmg₁₀.map

99	pmg_stick₁.asm	ovládání prvního hráče joystickem	https://github.com/tisnik/8bit-fame/blob/master/Atari800-ca65/pmg_stick₁.asm
100	pmg_stick₁_list.asm	„listing“ vygenerovaný assemblerem	https://github.com/tisnik/8bit-fame/blob/master/Atari800-ca65/pmg_stick₁_list.asm
101	pmg_stick₁.map	mapa paměti; soubor vytvořený linkerem	https://github.com/tisnik/8bit-fame/blob/master/Atari800-ca65/pmg_stick₁.map

102	pmg_stick₂.asm	zobrazení všech čtyř střel	https://github.com/tisnik/8bit-fame/blob/master/Atari800-ca65/pmg_stick₂.asm
103	pmg_stick₂_list.asm	„listing“ vygenerovaný assemblerem	https://github.com/tisnik/8bit-fame/blob/master/Atari800-ca65/pmg_stick₂_list.asm
104	pmg_stick₂.map	mapa paměti; soubor vytvořený linkerem	https://github.com/tisnik/8bit-fame/blob/master/Atari800-ca65/pmg_stick₂.map

105	pmg_stick₃.asm	střely zdánlivě tvoří pátého hráče (ovšem stále jsou samostatné)	https://github.com/tisnik/8bit-fame/blob/master/Atari800-ca65/pmg_stick₃.asm
106	pmg_stick₃_list.asm	„listing“ vygenerovaný assemblerem	https://github.com/tisnik/8bit-fame/blob/master/Atari800-ca65/pmg_stick₃_list.asm
107	pmg_stick₃.map	mapa paměti; soubor vytvořený linkerem	https://github.com/tisnik/8bit-fame/blob/master/Atari800-ca65/pmg_stick₃.map

108	pmg_stick₄.asm	korektní zobrazení pátého hráče	https://github.com/tisnik/8bit-fame/blob/master/Atari800-ca65/pmg_stick₄.asm
109	pmg_stick₄_list.asm	„listing“ vygenerovaný assemblerem	https://github.com/tisnik/8bit-fame/blob/master/Atari800-ca65/pmg_stick₄_list.asm
110	pmg_stick₄.map	mapa paměti; soubor vytvořený linkerem	https://github.com/tisnik/8bit-fame/blob/master/Atari800-ca65/pmg_stick₄.map

111	pmg_stick₅.asm	detekce stisku tlačítka joysticku, změna barvy prvního hráče	https://github.com/tisnik/8bit-fame/blob/master/Atari800-ca65/pmg_stick₅.asm
112	pmg_stick₅_list.asm	„listing“ vygenerovaný assemblerem	https://github.com/tisnik/8bit-fame/blob/master/Atari800-ca65/pmg_stick₅_list.asm
113	pmg_stick₅.map	mapa paměti; soubor vytvořený linkerem	https://github.com/tisnik/8bit-fame/blob/master/Atari800-ca65/pmg_stick₅.map

114	chars.bas	tisk všech znaků na obrazovku (varianta naprogramovaná v BASICu)	https://github.com/tisnik/8bit-fame/blob/master/Atari800-ca65/chars.bas